交叉表查询

Question

我有一个包含以下列的项目表

ProjectID, ProjectDescription

和一个包含以下列的列表数据表。

ProjectID ListType Date Memo

每个项目在 ListType 表中都有许多列表类型条目。

我想要做的是运行一个查询，该查询将返回类似这样的内容

ProjectID, ProjectDescription, ListType1, ListType1.date, Listtype1.Memo, ListType2, ListType2.date, ListType.Memo

再次强调，每个项目都连接到许多列表类型数据。 我使用的是 Microsoft SQL 2000。因此 Pivot 关键字不起作用

Answer 1

您需要做的是创建动态 SQL 并为每个 ListType 构建附加的 CASE 语句。我必须为工作做类似的事情，他们需要有关事件的某些信息。事件将作为逗号分隔列表传递，然后构建 case 语句。

我有一个存储过程，它从逗号分隔的列表创建一个表

CREATE PROCEDURE [dbo].[ListToTable]
    @vcList     VARCHAR(8000),
    @vcDelimiter    VARCHAR(8000),
    @TableName      SYSNAME,
    @ColumnName SYSNAME
AS
    SET NOCOUNT ON

    DECLARE @iPosStart  INT,
        @iPosEnd    INT,
        @iLenDelim  INT,
        @iExit      INT,
        @vcStr      varchar(8000),
        @vcSql      varchar(8000)

    SET @iPosStart = 1
    SET @iPosEnd = 1
    SET @iLenDelim = LEN(@vcDelimiter)

    SET @vcSql = 'INSERT ' + @TableName + ' (' + @ColumnName + ') VALUES ('''

    SET @iExit = 0

    WHILE @iExit = 0
    BEGIN
        SET @iPosEnd = CHARINDEX(@vcDelimiter, @vcList, @iPosStart)

        IF @iPosEnd <= 0
        BEGIN
            SET @iPosEnd = LEN(@vcList) + 1
            SET @iExit = 1
        END

        SET @vcStr = SUBSTRING(@vcList, @iPosStart, @iPosEnd - @iPosStart)

        EXEC(@vcSql + @vcStr + ''')')

        SET @iPosStart = @iPosEnd + @iLenDelim
    END

    RETURN 0

然后这是动态 SQL

DECLARE @Events VARCHAR(8000) = 'Event1,Event2,... Eventn'

CREATE TABLE #Events
    (
     EventName VARCHAR(MAX)
    )

EXEC [ListToTable] 
    @Events
   ,','
   ,'#Events'
   ,'EventName'

DECLARE @strCASE VARCHAR(MAX)
SET @strCase = ''

DECLARE Events_Cursor CURSOR 
FOR
SELECT EventName FROM [#Events] 

OPEN Events_Cursor
DECLARE @EventName VARCHAR(MAX)

FETCH NEXT FROM Events_Cursor INTO @EventName
WHILE ( @@FETCH_STATUS <> -1 ) 
    BEGIN
        IF ( @@FETCH_STATUS <> -2 ) 
            SET @strCase = @strCase + ',CASE WHEN [EventOpportunityProduct].[Name] = ''' + @EventName + ''' THEN EventOppertunityLineItem.[Trial_Status__c] ELSE NULL END [' + @EventName + ']'
        FETCH NEXT FROM Events_Cursor INTO @EventName
    END
CLOSE Events_Cursor
DEALLOCATE Events_Cursor

然后将 @strCASE 添加到您的 SELECT 语句中。

DECLARE @strSQL VARCHAR(MAX)
SET @strSQL = 'SELECT
    Field1
    ,Field2
    ' + @strCASE + '
   FROM Table'

EXEC (@strSQL)