DOS批处理命令从文本文件读取一些信息

Question

我正在尝试使用Windows命令行从文本文件中读取一些信息，并将其保存到一个变量中，就像“set info =1234”

下面是txt文件的内容，实际上我只需要修订号和它的位置始终是相同的第 5 行，从第 11 列到第 15 列。在示例中它是 1234，我想知道是否有一种方法可以将它保存到 Dos 命令行中的变量中。

多谢！

svninfo.txt：

Path: .
URL: https://www.abc.com
Repository Root: https://www.abc.com/svn
Repository UUID: 12345678-8b61-fa43-97dc-123456789
Revision: 1234
Node Kind: directory
Schedule: normal
Last Changed Author: abc
Last Changed Rev: 1234
Last Changed Date: 2010-04-01 18:19:54 -0700 (Thu, 01 Apr 2010)

Answer 1

这是一个单行版本：

for /f "tokens=2" %%i in ('findstr Revision: input.txt') do set revision=%%i

1. findstr 用于过滤文件。它将打印“input.txt:Revision: 1234”
2. 然后“tokens=2”意味着我们对第二个令牌“1234”感兴趣。默认情况下用于空白处的中断。

Answer 2

以下代码片段显示了如何执行此操作：

@echo off
setlocal enableextensions enabledelayedexpansion
set revision=
for /f "delims=" %%a in (input.txt) do (
    set line=%%a
    if "x!line:~0,10!"=="xRevision: " (
        set revision=!line:~10!
    )
)
echo !revision!
endlocal

其输出为所需的 1234。

我在每个脚本中使用 setlocal 来确保以已知的方式处理变量。 for 语句处理输入文件中的每一行（delims 位阻止该行被标记为单独的单词）。

!line:~ 位是子字符串，其中 !line:~0,10! 是前十个字符，!line:~10!是其余的。

因此，基本上，它会检查每一行是否以 "Revision: " 开头，如果是，则提取该行的其余部分供以后使用。

Answer 3

使用 for 命令解析文件：

for /f "skip=4 tokens=2" %%l in (svninfo.txt) do (
    set revision=%%l
    goto gotrev
)

:gotrev
echo revision is %revision%

Answer 4

如果您有可以使用 GNU 工具，例如 gawk

@echo off
for /F %%a in ('gawk -F":" "$1~/Revision/{print $2}" file') do (
        set var=%%a
)
echo %var%

Answer 5

知道如何熟练地使用 CMD 脚本固然很棒，但使用 PowerShell 就更好了。这是一种方法：

$revision = (( gc .\svninfo.txt | ? { $_.StartsWith( 'Revision: ' ) } ) -split ' ')[1]

发生了什么？

$revision 是一个变量

gc 是 Get-Content，又名类型。文件中的每一行都成为序列（管道）中的一个字符串。

? 是 Where-Object。它根据条件过滤管道中的对象。

{} 分隔脚本块

$_ 是管道中的当前对象。

的对象[1] 索引

-split 调用 .NET 中的 String.Split()，为您提供数组中