如何在 Perl 中终止带有警报的系统命令？

Question

我正在 Windows 上运行以下代码片段。服务器从客户端读取数据后开始持续监听。我想在一段时间后终止这个命令。

如果我在 main.pl 中使用 alarm() 函数调用，然后它终止整个 Perl 程序（这里是 main.pl），所以我称之为 system 命令，将其放置在单独的 Perl 文件中 并使用 alarm.pl) >系统命令。

但通过这种方式，我既无法在原始 Perl 文件中也无法在调用的 Perl 文件中获取此 system() 调用的输出。

有人可以让我知道终止 system() 调用的方法或以我上面使用的方式获取输出吗？

main.pl

my @output = system("alarm.pl");
print"one iperf completed\n";

open FILE, ">display.txt" or die $!; 
print FILE @output_1; 
close FILE;

Alarm.pl

alarm 30;
my @output_1 = readpipe("adb shell cd /data/app; ./iperf -u -s -p 5001");

open FILE, ">display.txt" or die $!; 
print FILE @output_1; 
close FILE;

在这两种情况下，display.txt 始终为空。

Answer 1

这里有几个单独的问题。

首先，为了防止警报杀死您的脚本，您需要处理 ALRM 信号。请参阅警报文档。您不需要为此使用两个脚本。

其次，system 不捕获输出。如果您想这样做，您需要反引号变体之一或管道。 Stackoverflow 上已经有答案了。

第三，如果 alarm.pl 在 display.txt 中放入任何内容，则当您以写入方式重新打开文件时，您会在 main.pl 中丢弃它模式。您只需在一处创建该文件。当你去掉额外的脚本时，你就不会遇到这个问题了。

我最近在alarm和system方面遇到了一些问题，但是切换到 IPC::System::Simple 修复了这个问题。

祝你好运， ：）

Answer 2

我到底在想什么？您不需要后台进程来执行此任务。您只需按照 perldoc -f Alarm 函数并将时间敏感的代码包装在 eval 块中。

my $command = "adb shell cd /data/app; ./iperf -u -s -p 5001";
my @output;
eval {
    local $SIG{ALRM} = sub { die "Timeout\n" };
    alarm 30;
    @output = `$command`;
    alarm 0;
};
if ($@) {
    warn "$command timed out.\n";
} else {
    print "$command successful. Output was:\n", @output;
}

在 eval 块内，您可以以常规方式捕获输出（使用反引号或 qx() 或 readpipe）。但如果调用超时，则不会有任何输出。

如果您不需要输出（或者不介意一起破解某些进程间通信），一个几乎白痴的替代方案是设置警报并在子进程中运行 system 调用

$command = "adb shell cd /data/app; ./iperf -u -s -p 5001";
if (($pid = fork()) == 0) {
    # child process
    $SIG{ALRM} = sub { die "Timeout\n" }; # handling SIGALRM in child is optional
    alarm 30;
    my $c = system($command);
    alarm 0;
    exit $c >> 8;  # if you want to capture the exit status
}
# parent
waitpid $pid, 0;

waitpid 将在孩子的 system 命令完成时返回，或当孩子的闹钟响起并且杀死了孩子。 $? 将保存系统调用的退出代码，或者未处理的 SIGALRM 的其他代码（在我的系统上为 142），如果您的 SIGALRM 处理程序调用 die，则为 255。罢工>

Answer 3

需要：

• 运行系统命令并获取其输出
• x 秒后系统命令超时
• 杀死系统命令进程和所有子进程

我遇到了一个类似的问题， exec，我想出了这个解决方案。它是作为模拟“反引号”子例程实现的。

use Error qw(:try);

$SIG{ALRM} = sub {
    my $sig_name = shift;
    die "Timeout by signal [$sig_name]\n";
};

# example
my $command = "vmstat 1 1000000";
my $output = backtick( 
                 command => $command, 
                 timeout => 60, 
                 verbose => 0 
             );

sub backtick {

    my %arg = (
        command => undef,
        timeout => 900,
        verbose => 1,
        @_,
    );

    my @output;

    defined( my $pid = open( KID, "-|" ) )
        or die "Can't fork: $!\n";

    if ($pid) {

        # parent

        # print "parent: child pid [$pid]\n" if $arg{verbose};

        try {
            alarm( $arg{timeout} );
            while (<KID>) {
                chomp;
                push @output, $_;
            }

            alarm(0);
        }
        catch Error with {
            my $err = shift;
            print $err->{-text} . "\n";

            print "Killing child process [$pid] ...\n" if $arg{verbose};
            kill -9, $pid;
            print "Killed\n" if $arg{verbose};

            alarm(0);
        }
        finally {};
    }
    else {

        # child

        # set the child process to be a group leader, so that
        # kill -9 will kill it and all its descendents
        setpgrp( 0, 0 );

        # print "child: pid [$pid]\n" if $arg{verbose};
        exec $arg{command};
        exit;
    }

    wantarray ? @output : join( "\n", @output );
}

Answer 4

如果“timeout -n”在您的系统上已经很常见，则可以使用“timeout -n”来包装您的命令。