在运行时向查询添加计算字段

Question

我正在使用 Delphi 中的查询获取数据，并且希望在运行之前向查询添加计算字段。计算字段使用代码和查询中的值，因此我不能只在 SQL 中计算它。

我知道我可以附加一个 OnCalcFields 事件来实际进行计算，但问题是添加计算字段后查询中没有其他字段...

我做了一些挖掘，发现所有创建了字段定义，但仅创建了实际字段

if DefaultFields then
    CreateFields

指定了默认字段

procedure TDataSet.DoInternalOpen;
begin
    FDefaultFields := FieldCount = 0;
    ...
end;

这表明如果您添加字段，您只会获得您添加的字段。

我想要查询中的所有字段以及我添加的字段。

这是可能的还是我必须添加我正在使用的所有字段？

Answer 1

没有什么可以阻止您首先在代码中创建所有字段，
然后添加您的计算字段。

您可以使用“黑客类型”来使用受保护的 CreateFields:

type
  THackQuery = class(TADOQuery)
  end;
[...]
  MyQuery.FieldDefs.Update;
  THackQuery(MyQuery).CreateFields;

或借用 CreateFields: 的一些代码，

  MyQuery.FieldDefs.Update;
  // create all defaults fields
  for I := 0 to MyQuery.FieldDefList.Count - 1 do
    with MyQuery.FieldDefList[I] do
      if (DataType <> ftUnknown) and not (DataType in ObjectFieldTypes) and
        not ((faHiddenCol in Attributes) and not MyQuery.FIeldDefs.HiddenFields) then
        CreateField(Self, nil, MyQuery.FieldDefList.Strings[I]);

然后创建您的计算字段：

  MyQueryMyField := TStringField.Create(MyQuery);
  with MyQueryMyField do
  begin
    Name := 'MyQueryMyField';
    FieldKind := fkCalculated;
    FieldName := 'MyField';
    Size := 10;
    DataSet := MyQuery;
  end;

Answer 2

Delphi 现在可以选择组合自动生成字段和计算字段： Data.DB.TFieldOptions.AutoCreateMode 类型的枚举 TFieldsAutoCreationMode 。这样您就可以在运行时添加计算字段。弗朗索瓦在他的回答中写道如何在运行时添加字段。

TFieldsAutoCreationMode 的不同模式：

• acExclusive

  当根本没有持久字段时，就会创建自动字段。这是默认模式。

• acCombineCompulated

  当数据集没有持久字段或仅存在计算持久字段时，将创建自动字段。这是在设计时创建持久计算字段并让数据集创建自动数据字段的便捷方法。

• acCombineAlways

  当没有持久字段时，将创建数据库字段的自动字段。

Answer 3

除了计算字段之外，您还需要添加所有字段。

添加字段后，您必须添加数据集中所需的所有字段。

Delphi 将其称为持久字段与动态字段。所有字段都是持久的或动态的。不幸的是，你不能混合两者。

另一件需要注意的事情是，从文档中可以看出

持久字段组件列表是
存储在您的应用程序中，并且不
即使结构发生变化
数据集底层的数据库是
改变了。

因此，请小心，如果您稍后向表中添加其他字段，则需要将新字段添加到组件中。删除字段也是如此。

如果您确实不想要持久字段，还有另一种解决方案。在任何应显示计算字段的网格或控件上，您可以自定义绘制它。例如，许多网格控件都有 OnCustomDraw 事件。您可以在那里进行计算。

Answer 4

如果您知道要在运行时计算的字段名称，则可以使用类似的东西。

var
 initing:boolean;

procedure TSampleForm.dsSampleAfterOpen(
  DataSet: TDataSet);
var
 i:integer;
 dmp:tfield;
begin
if not initing then
 try
  initing:=true;
  dataset.active:=false;
  dataset.FieldDefs.Update;
  for i:=0 to dataset.FieldDefs.Count-1 do
  begin
   dmp:=DataSet.FieldDefs.Items[i].FieldClass.Create(self);
   dmp.FieldName:=DataSet.FieldDefs.Items[i].DisplayName;
   dmp.DataSet:=dataset;
   if (dmp.fieldname='txtState') or (dmp.FieldName='txtOldState') then
   begin
     dmp.Calculated:=true;
     dmp.DisplayWidth:=255;
     dmp.size:=255;
   end;
  end;
  dataset.active:=true;
 finally
  initing:=false;
 end;
end;

procedure TSampleForm.dsSampleAfterClose(
  DataSet: TDataSet);
var
 i:integer;
 dmp:TField;
begin
if not initing then
begin
 for i:=DataSet.FieldCount-1 downto 0 do
 begin
  dmp:=pointer(DataSet.Fields.Fields[i]);
  DataSet.Fields.Fields[i].DataSet:=nil;
  freeandnil(dmp);
 end;
 DataSet.FieldDefs.Clear;
end;
end;

procedure TSampleForm.dsSampleCalcFields(
  DataSet: TDataSet);
var
 tmpdurum,tmpOldDurum:integer;
begin
  if not initing then
    begin
      tmpDurum := dataset.FieldByName( 'state' ).AsInteger;
      tmpOldDurum:= dataset.FieldByName( 'oldstate' ).AsInteger;
      dataset.FieldByName( 'txtState' ).AsString := State2Text(tmpDurum);
      dataset.FieldByName( 'txtOldState' ).AsString := State2Text(tmpOldDurum);
    end;
end;

procedure TSampleForm.btnOpenClick(Sender: TObject);
begin
 if dsSample.Active then
   dsSample.Close;
 dsSample.SQL.text:='select id,state,oldstate,"" as txtState,"" as txtOldState from states where active=1';
 dsSample.Open;
end;

Answer 5

    //assume we have an fdquery named  FDQuery1
    //we write this code in AfterOpen section

笔记：
这个方法有问题
计算字段放置在最后一个字段的位置
要解决这个问题，在查询中添加一个附加字段就足够了，例如将值零视为最终字段
像这样：

select * , 0 as myfield from mytable


procedure Tform1.FDQuery1AfterOpen(DataSet: TDataSet);
var
 i : Integer;
 aField : TField;
begin
    FDQuery1.Close;
    for i := 0 to FDQuery1.FieldDefs.Count - 1 do begin
     aField := FDQuery1.FieldDefs [ i ].CreateField ( fdQuery1 );
    end;
    aField.DataSet := fdQuery1;
    with aField do
    begin
      Name := 'myField';
      FieldKind := fkCalculated;
      FieldName := 'myField';
      Size := 10;
      DataSet := FDQuery1;
    end;
    fdQuery1.FieldDefs.Update;
    fdQuery1.AfterOpen:=nil;
    fdQuery1.Open;
    ShowMessage(FDQuery1.FieldByname('myField').AsString);
end;

现在你可以为 myField 编写 onClacField 方法