如何获取有关计算机的信息？ [32位或64位]

Question

如何获取有关 Windows 操作系统类型的信息？是32位还是64位？我如何以编程方式获取此信息？

Answer 1

function IsWin64: Boolean;
var
  IsWow64Process : function(hProcess : THandle; var Wow64Process : BOOL): BOOL; stdcall;
  Wow64Process : BOOL;
begin
  Result := False;
  IsWow64Process := GetProcAddress(GetModuleHandle(Kernel32), 'IsWow64Process');
  if Assigned(IsWow64Process) then begin
    if IsWow64Process(GetCurrentProcess, Wow64Process) then begin
      Result := Wow64Process;
    end;
  end;
end;

Answer 2

您需要使用 GetProcAddress() 来检查 IsWow64Process() 函数在运行时，如下所示：

function Is64BitWindows: boolean;
type
  TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL;
    stdcall;
var
  DLLHandle: THandle;
  pIsWow64Process: TIsWow64Process;
  IsWow64: BOOL;
begin
  Result := False;
  DllHandle := LoadLibrary('kernel32.dll');
  if DLLHandle <> 0 then begin
    pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process');
    Result := Assigned(pIsWow64Process)
      and pIsWow64Process(GetCurrentProcess, IsWow64) and IsWow64;
    FreeLibrary(DLLHandle);
  end;
end;

因为该函数仅在具有 64 位风格的 Windows 版本上可用。将其声明为外部会阻止您的应用程序在 Windows 2000 或 Windows XP SP2 之前的版本上运行。

编辑：

Chris 发布了关于出于性能原因缓存结果的评论。对于这个特定的 API 函数来说，这可能不是必需的，因为 kernel32.dll 将始终存在（我无法想象没有它的程序会加载），但对于其他函数来说，事情可能是不同的。因此，这里有一个缓存函数结果的版本：

function Is64BitWindows: boolean;
type
  TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL;
    stdcall;
var
  DLLHandle: THandle;
  pIsWow64Process: TIsWow64Process;
const
  WasCalled: BOOL = False;
  IsWow64: BOOL = False;
begin
  if not WasCalled then begin
    DllHandle := LoadLibrary('kernel32.dll');
    if DLLHandle <> 0 then begin
      pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process');
      if Assigned(pIsWow64Process) then
        pIsWow64Process(GetCurrentProcess, IsWow64);
      WasCalled := True;
      FreeLibrary(DLLHandle);
    end;
  end;
  Result := IsWow64;
end;

缓存此函数结果是安全的，因为 API 函数要么存在，要么不存在，并且其结果在同一 Windows 安装上无法更改。从多个线程同时调用此函数甚至是安全的，因为发现 WasCalled 为 False 的两个线程都会调用该函数，将相同的结果写入相同的内存位置，然后才将 WasCalled 设置为 True。

Answer 3

如果 a) 您使用的是 Windows，并且 b) 您可以访问注册表，则 HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion 应该提供信息。

Answer 4

function TForm2.Arch: string;
begin
if TOSVersion.Architecture=arIntelX86 then
   Result := '32-bit' Else  Result := '64-bit'
end;

Answer 5

除了 IsWow64Process 之外，您可能会对 GetNativeSystemInfo API 函数（它在 Windows 单元中定义）感兴趣，以了解有关您所使用的 CPU 的更多信息（或者您可以使用程序集和 CPUID ）。

Answer 6

对于delphi XE+

Uses System.SysUtils

Function IsWin64Or32: string;
Begin
   if Pos( '64-bit', TOSVersion.ToString ) > 0 then
     Result := '64-bit'
   Else
     Result := '32-bit';
End;

示例

lbl1.Caption := IsWin64Or32;

Answer 7

我不知道如何在Delphi中调用Win32函数。

但如果你编写32位程序，你可以调用Win32 API IsWow64Process来知道你是否在64位操作系统中。

当然，如果你写的是64位的exe，那么它只能在64位Windows上运行，所以就不用问了。

Answer 8

//尚未测试，但你可以尝试这个

is64 := (Environment.GetEnvironmentVariable('ProgramW6432') <> '');