动态加载 SWF 会导致先前加载的 SWF 行为异常

Question

我在使用 Flash 和 Flex 时遇到了一个非常奇怪的问题。在某些情况下，如果同时加载了另一个 SWF，则在运行时（使用 Loader）加载的 SWF 中的影片剪辑似乎无法实例化。这是重现错误的程序的完整代码。它是使用 mxmlc 编译的，通过 Ensemble Tofino：

package 
{
    import flash.display.*;
    import flash.events.*;
    import flash.net.*;
    import flash.system.*;

    public class DynamicLoading extends Sprite
    {
        private var testAppDomain:ApplicationDomain;

        public function DynamicLoading()
        {
            var request:URLRequest = new URLRequest("http://localhost/content/test.swf");
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onTestLoadComplete);
            loader.load(request);
        }

        private function onTestLoadComplete(e:Event):void
        {
            var loaderInfo:LoaderInfo = LoaderInfo(e.target);
            testAppDomain = loaderInfo.applicationDomain;

            // To get the error, uncomment these lines...
            //var request:URLRequest = new URLRequest("http://localhost/content/tiny.swf");
            //var loader:Loader = new Loader();
            //loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onTinyLoadComplete);
            //loader.load(request);

            // ...and comment this one:
            onTinyLoadComplete();
        }

        private function onTinyLoadComplete(e:Event = null):void
        {
            var spriteClass:Class = Class(testAppDomain.getDefinition("TopSymbol"));
            var sprite:Sprite = Sprite(new spriteClass());

            sprite.x = sprite.y = 200;

            addChild(sprite);
        }
    }
}

第二个加载操作注释为如上所示，代码有效。但是，如果第二个加载操作未注释，并且 onTinyLoadComplete 在加载第二个 SWF 之后运行 onTinyLoadComplete，则包含 new spriteClass() 的行将失败，并出现以下异常：

TypeError: Error #1034: Type Coercion failed: cannot convert flash.display::MovieClip@2dc8ba1 to SubSymbol.
    at flash.display::Sprite/constructChildren()
    at flash.display::Sprite()
    at flash.display::MovieClip()
    at TopSymbol()
    at DynamicLoading/onTinyLoadComplete()[C:\Users\...\TestFlash\DynamicLoading.as:38]

test.swf 和tiny.swf 是在 Flash CS4 中创建的。 test.swf 包含两个符号，均导出为 ActionScript，一个称为 TopSymbol，另一个称为 SubSymbol。 SubSymbol 包含一个简单的图形（涂鸦），而 TopSymbol 包含 SubSymbol 的单个实例。 tiny.swf 不包含任何内容；它是发布一个新的空 ActionScript 3 项目的结果。

如果我修改 test.swf 以便不为 ActionScript 导出 SubSymbol，则错误就会消失，但在我们的实际项目中，我们需要能够动态加载包含其他导出的精灵类作为子级的精灵类。

关于造成这种情况的原因或如何解决它有什么想法吗？

编辑： 有几个人建议tiny.swf 可能包含一个与test.swf 或父级(DynamicLoading.swf) 中的类同名的类。 事实并非如此。正如我上面所说，我自己通过简单地发布一个全新的空 Flash CS4 项目来创建tiny.swf。以下是在 tiny.swf 上运行时 swfdump -D 的完整输出：

[HEADER]        File version: 10
[HEADER]        File is zlib compressed. Ratio: 41%
[HEADER]        File size: 1343
[HEADER]        Frame rate: 30.000000
[HEADER]        Frame count: 1
[HEADER]        Movie width: 550.00
[HEADER]        Movie height: 400.00
[045]         4 FILEATTRIBUTES as3 symbolclass
[04d]      1284 METADATA
[009]         3 SETBACKGROUNDCOLOR (ff/ff/ff)
[056]        11 SCENEDESCRIPTION
[001]         0 SHOWFRAME 1 (00:00:00,000)
[000]         0 END

Answer 1

当加载两个 swf 时，我看到过奇怪的行为。当两个 swf 具有同一类的不同版本时，就会出现问题。检查以确保 TopSymbol 中的 SubSymbol 实例与直接加载的 SubSymbol 相同。

Answer 2

由于有多个同名类，这看起来确实是个问题。由于只要没有加载tiny.swf，代码就可以工作，所以我倾向于认为这是我们的罪魁祸首。确保图书馆确实是空的。

Answer 3

根据 Adobe的文档，如果要直接访问加载的SWF中的符号类（例如TopSymbol），则应该在加载上下文中指定当前应用程序域。所以对我来说，更大的问题是为什么你的第一个例子第二次加载被注释掉了。我唯一的猜测是，complete 事件可能在 Loader 当前应用程序域的上下文中执行。

尝试将 test.swf 显式加载到当前应用程序域中，如下所示：

var context:LoaderContext = new LoaderContext();
context.securityDomain = SecurityDomain.currentDomain;
context.applicationDomain = ApplicationDomain.currentDomain;

var request:URLRequest = new URLRequest("http://localhost/content/test.swf");
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onTestLoadComplete);
loader.load(request, context);

编辑：

由于您希望确保动态加载的 SWF 加载到单独的应用程序域中，因此您可能需要显式创建自己的每次加载的 ApplicationDomain 对象。我不知道 Loader 默认情况下使用什么作为其应用程序域。尝试这样的事情：

public class DynamicLoading extends Sprite
{
    private var testAppDomain:ApplicationDomain;
    private var tinyAppDomain:ApplicationDomain;

    public function DynamicLoading()
    {
        testAppDomain = new ApplicationDomain();
        var context:LoaderContext = new LoaderContext(false, testAppDomain);
        var request:URLRequest = new URLRequest("http://localhost/content/test.swf");
        var loader:Loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onTestLoadComplete);
        loader.load(request, context);
    }

    private function onTestLoadComplete(e:Event):void
    {
        tinyAppDomain = new ApplicationDomain();
        var context:LoaderContext = new LoaderContext(false, tinyAppDomain);
        var request:URLRequest = new URLRequest("http://localhost/content/tiny.swf");
        var loader:Loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onTinyLoadComplete);
        loader.load(request, context);
    }

    private function onTinyLoadComplete(e:Event = null):void
    {
        var spriteClass:Class = Class(testAppDomain.getDefinition("TopSymbol"));
        var sprite:Sprite = Sprite(new spriteClass());

        sprite.x = sprite.y = 200;

        addChild(sprite);
    }
}    

Answer 4

为了排除 Adob​​e 加载类中的许多错误，我肯定会使用 greensock LoaderMax 库......
http://www.greensock.com/loadermax/
简单、免费+强大。