用于多对多和多个条件的 CF9 HQL 语句

Question

我有以下设置：

Listing.cfc

component persistent="true"
{
    property name="ListingId" column="ListingId" type="numeric" ormtype="int" fieldtype="id" generator="identity"; 
        ...
    property name="Features" type="array" hint="Array of features" singularname="Feature" fieldtype="many-to-many" cfc="Feature" linktable="Listing_Feature" FKColumn="ListingId" inversejoincolumn="FeatureId";    
} 

Feature.cfc

component persistent="true" table="Feature" schema="dbo" output="false"
{
    property name="FeatureId" column="FeatureId" type="numeric" ormtype="int" fieldtype="id" generator="identity"; 
    property name="FeatureDescription" column="FeatureDescription" type="string" ormtype="string";
    ...    
    /*property name="Listings" fieldtype="many-to-many" cfc="Listing" linktable="Listing_Feature" fkcolumn="FeatureId" inversejoincolumn="ListingId" lazy="true" cascade="all" orderby="GroupOrder";*/

} 

我可以使用以下方法选择具有特定功能的所有列表：

<cfset matchingListings = ormExecuteQuery("from Listing l left join l.Features as feature where feature.FeatureId = :feature",{feature = 110}) />

这很好，但是，我希望能够选择具有多个功能的所有列表（例如列表既有“洗碗机”又有“车库”）

经过几个小时的谷歌搜索和查看休眠文档后未能找到不会给我错误的解决方案。我的猜测是，解决方案非常简单，我只是想太多了......有人有什么建议吗？

Answer 1

我不认为这是最有效的方法，但是，它确实产生了我想要的结果

<cfset matchingListings = ormExecuteQuery("Select l.ListingId from Listing l
  left join l.Features as featureone left join l.Features as featuretwo
  left join l.Features as featurethree 
  where featureone.FeatureId = 108
    and featuretwo.FeatureId = 110
    and featurethree.FeatureId = 113") />

这只会给我提供具有我正在寻找的所有功能的列表，但是，它做了很多加入和查找在 hibernate SQL 日志正在生成：

select listing0_.ListingId as col_0_0_ 
from dbo.Listing listing0_ 
left outer join Listing_Feature features1_ on listing0_.ListingId=features1_.ListingId 
left outer join dbo.Feature feature2_ on features1_.FeatureId=feature2_.FeatureId
left outer join Listing_Feature features3_ on listing0_.ListingId=features3_.ListingId 
left outer join dbo.Feature feature4_ on features3_.FeatureId=feature4_.FeatureId 
left outer join Listing_Feature features5_ on listing0_.ListingId=features5_.ListingId 
left outer join dbo.Feature feature6_ on features5_.FeatureId=feature6_.FeatureId 
where 1=1 
and feature2_.FeatureId=108 
and feature4_.FeatureId=110 
and feature6_.FeatureId=113

似乎必须有一种更有效的方法在 HQL 中执行此操作

---

cf-orm-dev 邮件列表上的 Jon Messer 给了我我认为发布此问题的最正确的解决方案这里为大家提供：

“据我所知，ORMExecuteQuery 不处理列表参数，所以如果你想参数化它们并返回对象，你必须做类似的事情

<cfset featureIds = [javaCast('int',108), javaCast('int',110), javaCast('int',113)] >

<cfset q = ormGetSession().createQuery("
    select l.ListingId 
    from Listing l 
        join l.features as f 
    where f.FeatureId in (:features)
    group by l.ListingId
    having count(*) = #arrayLen(featureIds)#
") /> 

<cfset q.setParameterList('features', featureIds) /> 

<cfset matchingListings = q.list() />

”

谢谢乔恩！

Answer 2

这应该可行：

<cfset featurelist = "110,113,125"/>
<cfset matchingListings = ormExecuteQuery("from Listing l left join l.Features as feature where feature.FeatureId IN (#featurelist#)")/>

如果您想使用绑定参数，您将必须做一些额外的工作，因为 hibernate 这次不喜欢 ColdFusion 列表和/或数组作为绑定参数。您可以在此处找到一些额外信息