如何在 Perl 中自动释放 RAII 风格的资源？

Question

假设我有一个必须释放的资源（例如文件句柄或网络套接字）：

open my $fh, "<", "filename" or die "Couldn't open filename: $!";
process($fh);
close $fh or die "Couldn't close filename: $!";

假设进程可能会死亡。然后代码块提前退出，并且 $fh 不会关闭。

我可以明确地检查错误：

open my $fh, "<", "filename" or die "Couldn't open filename: $!";
eval {process($fh)};
my $saved_error = $@;
close $fh or die "Couldn't close filename: $!";
die $saved_error if $saved_error;

但众所周知，这种代码很难正确执行，并且当您添加更多资源时只会变得更加复杂。

在 C++ 中，我将使用 RAII 创建一个拥有资源的对象，并且其析构函数将释放它。这样，我不必记住释放资源，并且一旦 RAII 对象超出范围，即使抛出异常，资源清理也会正确进行。不幸的是，在 Perl 中，DESTROY 方法不适合此目的，因为无法保证何时调用它。

有没有一种 Perlish 方法可以确保即使在出现异常的情况下也能像这样自动释放资源？或者显式错误检查是唯一的选择吗？

Answer 1

我认为这就是 Scope::Guard 的目的。

#!/usr/bin/perl

use strict; use warnings;
use Scope::Guard;

my $filename = 'file.test';

open my $fh, '>', $filename
    or die "Couldn't open '$filename': $!";

{
    my $sg = Scope::Guard->new(
        sub {
            close $fh or die "Could not close";
            warn "file closed properly\n";
        }
    );

    process($fh);
}

sub process { die "cannot process\n" }

然而，正如 @Philip 在评论中指出的那样，Scope::Guard 使用了 DESTROY 方法，这对于何时运行作用域退出代码产生了一些不确定性。 Hook::Scope 和 Sub::ScopeFinalizer 等模块看起来也不错，尽管我从未使用过它们。

我确实喜欢 Try::Tiny ，因为它干净的界面和纯粹的简单性，它会帮助您以正确的方式处理异常：

#!/usr/bin/perl

use strict; use warnings;
use Try::Tiny;

my $filename = 'file.test';

open my $fh, '>', $filename
    or die "Couldn't open '$filename': $!";

try {
    process($fh);
}
catch {
    warn $_;
}
finally {
    close $fh
        and warn "file closed properly\n";
};

sub process { die "cannot process\n" }

Answer 2

我的模块 Scope::OnExit 正是用于此目的。

Answer 3

词法文件句柄的好处是，当它们超出范围时，它们会被关闭（并释放）。所以你可以这样做：

{
    # bare block creates new scope
    open my $fh, "<", "filename" or die "Couldn't open filename: $!";
    eval { process($fh) };

    # handle exceptions here

    close $fh or die "Couldn't close filename: $!";
}

# $fh is now out of scope and goes away automagically.