德尔福中的sprintf？

Question

有谁知道 Delphi 的 C/C++ printf 的 100% 克隆吗？ 是的，我知道 System.Format 函数，但它可以处理一些事情有点不同。

例如，如果要将 3 格式化为“003”，则在 C 中需要“%03d”，但在 Delphi 中需要“%.3d”。

我有一个用 Delphi 编写的应用程序，它必须能够使用 C 格式字符串格式化数字，那么您知道这方面的代码片段/库吗？

提前致谢！

Answer 1

您可以使用 Windows.pas 中的 wsprintf() 函数。不幸的是这个函数没有在 Windows.pas 中正确声明，所以这里是一个重新声明：

function wsprintf(Output: PChar; Format: PChar): Integer; cdecl; varargs;
  external user32 name {$IFDEF UNICODE}'wsprintfW'{$ELSE}'wsprintfA'{$ENDIF};

procedure TForm1.FormCreate(Sender: TObject);
var
  S: String;
begin
  SetLength(S, 1024); // wsprintf can work only with max. 1024 characters
  SetLength(S, wsprintf(PChar(S), '%s %03d', 'Hallo', 3));
end;

Answer 2

如果你想让这个函数看起来对用户来说对 Delphi 更友好，你可以使用以下代码：

function _FormatC(const Format: string): string; cdecl;
const
  StackSlotSize = SizeOf(Pointer);
var
  Args: va_list;
  Buffer: array[0..1024] of Char;
begin
  // va_start(Args, Format)
  Args := va_list(PAnsiChar(@Format) + ((SizeOf(Format) + StackSlotSize - 1) and not (StackSlotSize - 1)));
  SetString(Result, Buffer, wvsprintf(Buffer, PChar(Format), Args));
end;

const // allows us to use "varargs" in Delphi
  FormatC: function(const Format: string): string; cdecl varargs = _FormatC;


procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage(FormatC('%s %03d', 'Hallo', 3));
end;

Answer 3

不建议使用 (ws)printf 因为它们容易出现缓冲区溢出，最好使用安全变体（例如 StringCchPrintF)。它已经在 J​​edi Apilib (JwaStrSafe) 中声明。

Answer 4

好吧，我刚刚找到了这个：

function sprintf(S: PAnsiChar; const Format: PAnsiChar): Integer;
    cdecl; varargs; external 'msvcrt.dll';

它只是使用 msvcrt.dll 中的原始 sprintf 函数，然后可以像这样使用它：

procedure TForm1.Button1Click(Sender: TObject);
var s: AnsiString;
begin
  SetLength(s, 99);
  sprintf(PAnsiChar(s), '%d - %d', 1, 2);
  ShowMessage(S);
end;

我不知道这是否是最好的解决方案，因为它需要这个外部dll 并且您必须手动设置字符串的长度，这使得它容易出现缓冲区溢出，但至少它可以工作......有更好的想法吗？

Answer 5

则更干净的方法，无需不必要的类型转换

function sprintf(CharBuf: PChar; const Format: PAnsiChar): Integer;
cdecl; varargs; external 'msvcrt.dll';

procedure TForm1.Button1Click(Sender: TObject);
var CharBuf: PChar; 
begin
  CharBuf:=StrAlloc (99);
  sprintf(CharBuf, 'two numbers %d - %d', 1, 2);
  ShowMessage(CharBuf);
  StrDispose(CharBuf);
end;

如果您碰巧为 Windows CE 应用程序进行交叉编译， 。使用 coredll.dll 而不是 msvcrt.dll