弹出菜单点击源自哪个组件

Question

将弹出菜单附加到表单上的多个组件（按钮，还有 TCharts 等），我想知道首先右键单击哪个组件来启动弹出菜单。

click 方法的 Sender 参数仅指向 TMenuItem，它是弹出菜单（或父菜单项）的父级。

如何获取原始组件？

Answer 1

您的意思是 PopupMenu1.PopupComponent 吗？

Answer 2

在 PopupMenu 的 TMenuItem 的单击事件中获取调用者组件：

Caller := ((Sender as TMenuItem).GetParentMenu as TPopupMenu).PopupComponent;

您可以通过分配给多个列表框并解决导出到文件功能的 PopupMenu 示例，

procedure TForm1.mniExportFileClick(Sender: TObject);
var Caller: TObject;
begin  
  if SaveTextFileDialog1.Execute then
  begin
    Caller := ((Sender as TMenuItem).GetParentMenu as TPopupMenu).PopupComponent;
    (Caller as TListBox).Items.
      SaveToFile(SaveTextFileDialog1.FileName,
        StandardEncodingFromName(
          SaveTextFileDialog1.Encodings[SaveTextFileDialog1.EncodingIndex]));
  end;
end; 

Answer 3

作为最后的手段，您可以使用 TPopupMenu.OnPopup 中的 Mouse.CursorPos 在表单上查找此组件。但可能有更好/更简单的方法。

Answer 4

PopUpMenu.PopupComponent 表示最后响应鼠标右键显示弹出菜单的组件

Answer 5

我有一堆面板，我想让用户右键单击这些面板中的任何一个并执行“删除文件”操作。
因此，我有一个与所有这些面板关联的弹出菜单。
这就是我如何找出哪个面板被右键单击：（

注意：我添加了很多注释来清楚地解释它是如何工作的。但是如果您不喜欢它，您可以将代码压缩为 2 行（请参阅第二个过程） ）。

因此，如果您为该弹出菜单分配了操作：

procedure Tfrm.actDelExecute(Sender: TObject);
VAR
  PopMenu: TPopupMenu;
  MenuItem: TMenuItem;
  PopupComponent: TComponent;
begin
 { Find the menuitem associated to this action }
 MenuItem:= TAction(Sender).ActionComponent as TMenuItem;  { This will crash and burn if we call this from a pop-up menu, not from an action! But we always use actions, so.... }

 { Was this action called by keyboard shortcut? Note: in theory there should be no keyboard shortcuts for this action if the action can be applyed to multiple panels. We can call this action ONLY by selecting (right click) a panel! }
 if MenuItem = NIL then
  begin
   MsgError('This action should not be called by keyboard shortcuts!');
   EXIT;
  end;

 { Find to which pop-up menu this menuitem belongs to }
 PopMenu:= (MenuItem.GetParentMenu as TPopupMenu);

 { Find on which component the user right clicks }
 PopupComponent := PopMenu.PopupComponent;

 { Finally, access that component }
 (PopupComponent as TMonFrame).Delete(FALSE);
end;

如果您只有一个简单的弹出菜单（未分配操作）：

procedure Tfrm.actDelHddExecute(Sender: TObject);
VAR PopupComponent: TComponent;
begin
 PopupComponent := ((Sender as TMenuItem).GetParentMenu as TPopupMenu).PopupComponent;
 (PopupComponent as TMonFrame).Delete(TRUE);
end;

您可以放置​​所有代码在返回 TPanel 的单个函数中并像这样调用它：

procedure Tfrm.actDelWallExecute(Sender: TObject);
begin
 if GetPanelFromPopUp(Sender) <> NIL
 then GetPanelFromPopUp(Sender).Delete(FALSE);
end;

Answer 6

对于 Firemonkey 框架，相同函数的工作方式如下，以 PopupMenu 为例，该菜单分配给多个列表框并解决导出到文件功能：

procedure TForm1.mniExportFileClick(Sender: TObject);
var Caller: TPopupMenu;
begin
  Caller := (((Sender as TMenuItem).parent) as TContent).parent as TPopupMenu;
  (Caller.PopupComponent as TListBox).Items.SaveToFile(...);
end;