如何在MSHTML中设置整个HTML？

Question

如何在MSHTML中设置整个HTML？

我正在尝试使用此作业：

   (Document as IHTMLDocument3).documentElement.innerHTML := 'abc';  

但出现错误：

“目标元素对此无效 操作”

我也尝试过使用，

(Document as IHTMLDocument2).write 

但这种形式只将 HTML 添加到正文部分，我需要替换所有 HTML 源。
有人知道我该怎么做吗？

提前致谢。

Answer 1

这是我的一些旧代码，看看它是否对你有帮助：

type
  THackMemoryStream = class(TMemoryStream);

procedure Clear(const Document: IHTMLDocument2);
begin
  Document.write(PSafeArray(VarArrayAsPSafeArray(VarArrayOf([WideString('')]))));
  Document.close;
end;

procedure LoadFromStream(const Document: IHTMLDocument2; Stream: TStream);
var
  Persist: IPersistStreamInit;
begin
  Clear(Document);
  Persist := (Document as IDispatch) as IPersistStreamInit;
  OleCheck(Persist.InitNew);
  OleCheck(Persist.Load(TStreamAdapter.Create(Stream)));
end;

procedure SetHtml(const Document: IHTMLDocument2; const Html: WideString);
var
  Stream: TMemoryStream;
begin
  Stream := TMemoryStream.Create;
  try
    THackMemoryStream(Stream).SetPointer(PWideChar(Html), (Length(Html) + 1) * SizeOf(WideChar));
    Stream.Seek(0, soFromBeginning);
    LoadFromStream(Document, Stream);
  finally
    Stream.Free;
  end;
end;

Answer 2

作为替代方案，您还可以使用 TEmbededWB，它是 Web 浏览器的扩展包装器，并且具有一些功能提供此功能的易于使用的方法。