根据父级将 NHibernate 实体映射到多个表

Question

我正在创建一个域模型，其中实体通常（但并非总是）具有 ActionLog 类型的成员。

ActionLog 是一个简单的类，它允许对实例上执行的操作进行审计跟踪。每个操作都记录为 ActionLogEntry 实例。

ActionLog 的实现（大约）如下：

public class ActionLog
{   
    public IEnumerable<ActionLogEntry> Entries
    {
        get { return EntriesCollection; }
    }

    protected ICollection<ActionLogEntry> EntriesCollection { get; set; }

    public void AddAction(string action)
    {
        // Append to entries collection.
    }
}

我想要的是在我的实体中重用此类，并根据记录的类将条目映射到不同的表。例如：

public class Customer
{
    public ActionLog Actions { get; protected set; }
}

public class Order
{
    public ActionLog Actions { get; protected set; }
}

这种设计在应用程序中适合我，但是我看不到一种清晰的方法来将此场景映射到带有 NHibernate 的数据库。

我通常使用 Fluent NHibernate 进行配置，但我很乐意接受更通用的 HBM xml 中的答案。

Answer 1

我遇到了同样的问题，并且关于发布同样的问题希望得到答案 - 但我在 FreeNode 上的 NH IRC 频道的帮助下找到了解决方案。

我的场景有一个文档。各种事物都会有文档 - 例如报告、项目等。Report.Documents 和 Item.Documents 之间的唯一区别是文档具有对其所有者的引用，并且映射到不同的表。

这种情况的解决方案大多是通过.Net来完成的。不过，我认为使用 XML 映射不可能实现此解决方案。

文档类：

Public Class Document
    Public Overridable Property DocumentId As Integer
    Public Overridable Property Directory As String
    Public Overridable Property Name As String
    Public Overridable Property Title As String
    Public Overridable Property Revision As String
    Public Overridable Property Description As String
    Public Overridable Property Owner As String
    Public Overridable Property UploadedBy As String
    Public Overridable Property CreationDate As Date
    Public Overridable Property UploadDate As Date
    Public Overridable Property Size As Int64
    Public Overridable Property Categories As String
End Class

然后我们为每个附加文档类型继承该类：

Public Class ReportDocument
    Inherits Document
    Public Overridable Property Report As Report
End Class

Public Class ItemDocument
    Inherits Document
    Public Overridable Property Item As Item
End Class

这就是“魔法”发生的地方。我们将创建一个通用映射，要求所使用的对象继承 Document 类。这样，Fluent NHibernate 仍然可以找到继承自 Document 的对象上的所有属性。

Public Class GenericDocumentMapping(Of T As Document)
    Inherits ClassMap(Of T)
    Public Sub New()
        Id(Function(x) x.DocumentId)
        Map(Function(x) x.Directory)
        Map(Function(x) x.Name)
        Map(Function(x) x.Title).Not.Nullable()
        Map(Function(x) x.Revision)
        Map(Function(x) x.Description)
        Map(Function(x) x.Owner)
        Map(Function(x) x.UploadedBy)
        Map(Function(x) x.CreationDate).Not.Nullable()
        Map(Function(x) x.UploadDate).Not.Nullable()
        Map(Function(x) x.Size)
        Map(Function(x) x.Categories)
    End Sub
End Class

您会注意到，此类没有对其映射到的表的引用，也没有每个不同版本将使用的父对象的引用。现在，我们对每个特殊类型使用此通用映射，并指定表并映射我们在创建的每个类类型中创建的父对象。

Public Class ReportDocumentMapping
    Inherits GenericDocumentMapping(Of ReportDocument)
    Public Sub New()
        MyBase.New()
        References(Function(x) x.Item).Column("ReportID")
        Table("ReportDocuments")
    End Sub
End Class

Public Class ItemDocumentMapping
    Inherits GenericDocumentMapping(Of ItemDocument)
    Public Sub New()
        MyBase.New()
        References(Function(x) x.Item).Column("ItemID")
        Table("ItemDocuments")
    End Sub
End Class

我觉得这个方法减少了很多代码。现在，如果您想对文档类型进行彻底更改，您只需修改 Document 类和 GenericDocumentMapping 类。

在我的情况下 - 我也只是将文档映射到特定的表。这与其他方法的完成方式相同 - 从 GenericDocumentMapping 继承并指定表。唯一的区别是我不引用父对象。

Public Class DocumentMapping
    Inherits GenericDocumentMapping(Of Document)
    Public Sub New()
        MyBase.New()
        Table("Documents")
    End Sub
End Class

Answer 2

您可以使用 join 将其映射到多个表