检测 RichEdit 中 URL 的点击

Question

我正在尝试更新 RichEdit，以便它检测 URL 并允许单击它在浏览器中打开。检测 URL 很容易，我只需使用 http://www.scalabium.com/faq 中的以下代码/dct0146.htm

mask := SendMessage(MNote.Handle, EM_GETEVENTMASK, 0, 0);
  SendMessage(MNote.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK);
  SendMessage(MNote.Handle, EM_AUTOURLDETECT, Integer(True), 0); 

但第二部分对我不起作用。他们提供了以下代码来捕获 EN_LINK 消息并对其进行处理：

type
  TForm1 = class(TForm)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;
...

procedure TForm1.WndProc(var Message: TMessage);
var
  p: TENLink;
  strURL: string;
begin
  if (Message.Msg = WM_NOTIFY) then
  begin
    if (PNMHDR(Message.LParam).code = EN_LINK) then
    begin
      p := TENLink(Pointer(TWMNotify(Message).NMHdr)^);
      if (p.msg = WM_LBUTTONDOWN) then
      begin
        SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@(p.chrg)));
        strURL := RichEdit1.SelText;
        ShellExecute(Handle, 'open', PChar(strURL), 0, 0, SW_SHOWNORMAL);
      end
    end
  end;

  inherited;
end;

当我运行该程序时，检测到 URL，但单击它不会执行任何操作。使用调试我发现当我单击 URL 时 Message.Msg = WM_NOTIFY 不正确。然后我尝试覆盖 TRichEdit 的 WndProc，但结果是相同的。有什么建议吗？

Answer 1

对 RichEdit 的 WindowProc 属性进行子类化并查找 CN_NOTIFY 消息，例如：

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    PrevRichEditWndProc: TWndMethod;
    procedure RichEditWndProc(var Message: TMessage);
    procedure SetRichEditMasks;
  end; 

procedure TForm1.FormCreate(Sender: TObject);
begin
  PrevRichEditWndProc := RichEdit1.WindowProc;
  RichEdit1.WindowProc := RichEditWndProc;
  SetRichEditMasks;
end;

procedure TForm1.SetRichEditMasks;
var
  mask: Longint;
begin
  mask := SendMessage(RichEdit1.Handle, EM_GETEVENTMASK, 0, 0); 
  SendMessage(RichEdit1.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK); 
  SendMessage(RichEdit1.Handle, EM_AUTOURLDETECT, 1, 0);  
end;

procedure TForm1.RichEditWndProc(var Message: TMessage); 
begin 
  PrevRichEditWndProc(Message);
  case Message.Msg of
    CN_NOTIFY:
      begin
        if (TWMNotify(Message).NMHdr^.code = EN_LINK) then
        begin
          with PENLink(Message.LParam)^ do
          begin
            if (msg = WM_LBUTTONDOWN) then
            begin 
              SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@chrg)); 
              ShellExecute(Handle, 'open', PChar(RichEdit1.SelText), 0, 0, SW_SHOWNORMAL); 
            end;
          end;
        end;
      end;
    CM_RECREATEWND:
      begin
        SetRichEditMasks;
      end;
  end; 
end;

Answer 2

对我来说，只有显示的文本与底层超链接的文本相同时它才有效。

我认为我的问题是底层超链接具有属性 CFE_HIDDEN，因此无法由 EM_EXSETSEL 选择。

例如，如果我（在 WORD 中）创建一个网址为 http://www.rubbish.com 的链接，但它显示文本 RUBBISH，虽然所选文本的 chrg 是 11-33，即 22 个字符 - 与 URL 长度相同，但该方法返回的实际文本是 RUBBISH。

但是，我发现如果我使用 WM_GETTEXT，则会返回整个链接：

HYPERLINK "http://www.rubbish.com" RUBBISH

我可以从中提取基于 chrg 的 URL。

感觉有点笨拙……但确实有效。 :-)

Answer 3

您是否尝试过使用精简的应用程序来确保程序中的其他内容不会导致问题？我按照 Delphi 2009 中该网站的步骤操作，单击 URL 效果很好。