如何在 Perl 中递归读取目录？

Question

我想递归地读出一个目录，以使用 Template::Toolkit 打印 HTML 页面中的数据结构。 但我一直在思考如何以易于阅读的形式保存路径和文件。

我的想法是这样开始的

sub list_dirs{

     my ($rootPath) = @_;
     my (@paths);

     $rootPath .= '/' if($rootPath !~ /\/$/);

     for my $eachFile (glob($path.'*'))
     {

         if(-d $eachFile)
         {
              push (@paths, $eachFile);

              &list_dirs($eachFile);
          }
          else
          {
              push (@files, $eachFile);
          }
     }

 return @paths;
}

我该如何解决这个问题？

Answer 1

这应该可以解决问题

 use strict;
 use warnings;
 use File::Find qw(finddepth);
 my @files;
 finddepth(sub {
      return if($_ eq '.' || $_ eq '..');
      push @files, $File::Find::name;
 }, '/my/dir/to/search');

Answer 2

您应该始终使用严格和警告来帮助您调试代码。例如，Perl 会警告您未声明@files。但您的函数的真正问题在于，您在每次递归调用 list_dirs 时声明了一个词法变量 @paths，并且在递归步骤之后不将返回值推回。

push @paths, list_dir($eachFile)

如果您不想安装额外的模块，以下解决方案可能会帮助您：

use strict;
use warnings;
use File::Find qw(find);

sub list_dirs {
        my @dirs = @_;
        my @files;
        find({ wanted => sub { push @files, $_ } , no_chdir => 1 }, @dirs);
        return @files;
}

Answer 3

mdom 的答案解释了您最初的尝试是如何误入歧途的。我还建议您考虑使用 File::Find 更友好的替代方案。 CPAN 有多种选择。这是一个。

use strict;
use warnings;
use File::Find::Rule;
my @paths = File::Find::Rule->in(@ARGV);

另请参阅此处：

• SO 答案 提供CPAN
  File::Find 的替代方案。

• 关于目录迭代器的SO问题。

这是递归解决方案的重写。注意事项：使用严格； 使用警告；以及使用作用域块为子例程创建静态变量。

use strict;
use warnings;

print $_, "\n" for dir_listing(@ARGV);

{
    my @paths;
    sub dir_listing {
        my ($root) = @_;
        $root .= '/' unless $root =~ /\/$/;
        for my $f (glob "$root*"){
            push @paths, $f;
            dir_listing($f) if -d $f;
        }
        return @paths;
    }
}

Answer 4

我认为您的代码中的以下行有问题

for my $eachFile (glob($path.'*'))

您将 $path 变量更改为 $rootpath。

它将正确存储路径。

Answer 5

我使用这个脚本从我的 USB Pendrive 中删除隐藏文件（由 Mac OS X 创建），我通常用它在车里听音乐，以及任何以“.mp3”结尾的文件，即使它以“._”开头”，将被列入汽车音响清单。

#!/bin/perl

use strict;
use warnings;

use File::Find qw(find);

sub list_dirs {
        my @dirs = @_;
        my @files;
        find({ wanted => sub { push @files, $_ } , no_chdir => 1 }, @dirs);
        return @files;
}

if ( ! @ARGV || !$ARGV[0] ) {
  print "** Invalid dir!\n";
  exit ;
}


if ( $ARGV[0] !~ /\/Volumes\/\w/s ) {
  print "** Dir should be at /Volume/... > $ARGV[0]\n";
  exit ;
}

my @paths = list_dirs($ARGV[0]) ;

foreach my $file (@paths) {
  my ($filename) = ( $file =~ /([^\\\/]+)$/s ) ;

  if ($filename =~ /^\._/s ) {
    unlink $file ;
    print "rm> $file\n" ;
  }
}

Answer 6

您可以使用此方法作为分隔特定文件类型的递归文件搜索，

my @files;
push @files, list_dir($outputDir);

sub list_dir {
        my @dirs = @_;
        my @files;
        find({ wanted => sub { push @files, glob "\"$_/*.txt\"" } , no_chdir => 1 }, @dirs);
        return @files;
}