在ANTLR中，如何指定具体的重复次数？

Question

我使用 ANTLR 指定包含不能超过 254 个字符的行（不包括行结尾）的文件格式。我如何在语法中对其进行编码，缺少这样做：

line : CHAR? CHAR? CHAR? CHAR? ... (254 times)

Answer 1

这可以通过使用语义谓词来处理。

首先以这样的方式写你的语法，无论你的行有多长。示例如下：

grammar Test;

parse
  :  line* EOF
  ;

line
  :  Char+ (LineBreak | EOF)
  |  LineBreak // empty line!
  ;

LineBreak : '\r'? '\n' | '\r' ;
Char      : ~('\r' | '\n') ;

然后将“谓词”添加到 line 规则中：

grammar Test;

@parser::members {
    public static void main(String[] args) throws Exception {
        String source = "abcde\nfghij\nklm\nnopqrst";
        ANTLRStringStream in = new ANTLRStringStream(source);
        TestLexer lexer = new TestLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        TestParser parser = new TestParser(tokens);
        parser.parse();
    }  
}

parse
  :  line* EOF
  ;

line
  :  (c+=Char)+ {$c.size()<=5}? (LineBreak | EOF)
  |  LineBreak // empty line!
  ;

LineBreak : '\r'? '\n' | '\r' ;
Char      : ~('\r' | '\n') ;

c+=Char 将构造一个包含所有内容的 ArrayList行中的字符。当 ArrayList 的大小超过 5 时，{$c.size()<=5}? 会引发异常。

我还在解析器，这样你就可以自己测试它：

// *nix/MacOSX
java -cp antlr-3.2.jar org.antlr.Tool Test.g
javac -cp antlr-3.2.jar *.java
java -cp .:antlr-3.2.jar TestParser

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Test.g
javac -cp antlr-3.2.jar *.java
java -cp .;antlr-3.2.jar TestParser

它将输出：

line 0:-1 rule line failed predicate: {$c.size()<=5}?

HTH