组件如何在设计时确定项目目录

Question

我编写了一个组件，它应该存储一些与项目目录相关的信息。每次更改组件的属性时，它都应该写入一个文件。那么组件如何在设计时确定当前项目目录呢？

提前致谢

编辑：
我想在每次更改组件的属性时生成一个 delphi 源文件，以便在编译代码时始终获得最新版本。将其视为一种代码生成器。

目前，我设置了应存储源的完整路径和文件名，但我更喜欢项目的相对路径（或包含我的组件的表单/数据模块），以便更轻松地在不同的开发人员计算机上复制项目。

Answer 1

感谢您的提示。开放工具 API 是可行的方法，并且可以在设计时从表单上的组件使用开放工具 API。

这是我的解决方案：

我需要两个单元，一个用于组件，另一个用于注册组件和使用开放工具 API 的代码。

这是组件单元：

unit TestLabels;

interface

uses
  SysUtils, Classes, Windows, Controls, StdCtrls;

type
  TTestLabel = class(TLabel)
  private
    FTestProperty: Boolean;
    procedure SetTestProperty(const Value: Boolean);
    procedure Changed;
  published
    property TestProperty: Boolean read FTestProperty write SetTestProperty;
  end;

var
  OnGetUnitPath: TFunc;

implementation

{ TTestLabel }

procedure TTestLabel.Changed;
begin
  if not (csDesigning in ComponentState) then
     Exit; // I only need the path at designtime

  if csLoading in ComponentState then
     Exit; // at this moment you retrieve the unit path which was current before

  if not Assigned(OnGetUnitPath) then
    Exit;

  // only for demonstration
  Caption := OnGetUnitPath;
  MessageBox(0, PChar(ExtractFilePath(OnGetUnitPath)), 'Path of current unit', 0);
end;

procedure TTestLabel.SetTestProperty(const Value: Boolean);
begin
  if FTestProperty  Value then
  begin
    FTestProperty := Value;
    Changed;
  end;
end;

end.

这是注册组件和调用 Open Tools API 的单元：

unit TestLabelsReg;

interface

uses
  SysUtils, Classes, Controls, StdCtrls, TestLabels;

procedure register;

implementation

uses
  ToolsAPI;

function GetCurrentUnitPath: String;
var
  ModuleServices: IOTAModuleServices;
  Module: IOTAModule;
  SourceEditor: IOTASourceEditor;
  idx: integer;

begin
  Result := '';
  SourceEditor := nil;

  if SysUtils.Supports(BorlandIDEServices, IOTAModuleServices,
    ModuleServices) then
  begin
    Module := ModuleServices.CurrentModule;

    if System.Assigned(Module) then
    begin
      idx := Module.GetModuleFileCount - 1;

      // Iterate over modules till we find a source editor or list exhausted
      while (idx >= 0) and not SysUtils.Supports(Module.GetModuleFileEditor(idx), IOTASourceEditor, SourceEditor) do
        System.Dec(idx);

      // Success if list wasn't ehausted.
      if idx >= 0 then
        Result := ExtractFilePath(SourceEditor.FileName);
    end;

  end;

end;

procedure register;
begin
  RegisterComponents('Samples', [TTestLabel]);
  TestLabels.OnGetUnitPath := GetCurrentUnitPath;
end;

end.

Answer 2

从delphi 7开始，ToolsAPI单元定义了一个getActiveProject函数，它返回当前项目的IOTAProject接口。

IOTAProject 的 fileName 属性返回项目主源文件（通常是 .dpr 文件）的完整路径。

因此，在许多情况下，可以使用简单的指令，例如：（

if csDesigning in componentState then
    appFolderPath := extractFilePath( getActiveProject.fileName ) 
else
    appFolderPath := extractFilePath( application.exeName );

并且不需要像上面亨氏的示例那样使用两个单位）

Answer 3

组件无法访问您的源路径，因为组件被放置在您的应用程序中并作为应用程序的一部分在 Delphi IDE 之外运行。

如果您想访问项目路径，或者自动化 IDE 内的任何流程；你必须使用 OpenTools API 编写一个 IDE 专家，而不是一个组件。

Answer 4

我认为不可以。您可以很容易地确定 EXE 运行的目录，但设计时的组件是作为 IDE 的一部分运行的。我怀疑组件是否有办法通过 IDE 访问项目信息。

Answer 5

请参阅

http://www.gexperts.org/otafaq.html#project

，然后

www.href.com/pub/sw/ProjectOptions.html

可能有帮助

Answer 6

我有一个有点不同的目标：如何知道项目 exe 在设计时的位置，以便应用程序在运行时可以与设计时功能共享一些文件。

因此，我结合了两个最佳答案，并创建了以下要在应用程序中使用的函数：

unit MyUtils;

interface

function GetProjectTargetPath: string;

var

  _GetProjectTargetPath: TFunc<string>;

...
implementation

function GetProjectTargetPath: string;
begin
  Result := '';
  if Assigned(_GetProjectTargetPath) then
    Result := _GetProjectTargetPath;
  if Result <> '' then
    Result := IncludeTrailingPathDelimiter(Result);
end;

然后在组件注册单元中（我将其分开并仅链接到设计时包）：

unit MyUtils;

...
implementation

function GetProjectTargetPath: String;
begin
  Result := ExtractFilePath( GetActiveProject.ProjectOptions.TargetName );
end;

procedure Register;
begin
  ...
  MyUtils._GetProjectTargetPath := GetProjectTargetPath;
end;

从而避免实际单元依赖于 ToolsAPI 。

MyUtils.GetProjectTargetPath 在运行时返回一个空字符串，实际上对应于应用程序的 exe 目录。