如何在 Flex 应用程序边界内保持拖动的 TitleWindow

Question

我在 FB4 中使用 PopupManager 来显示自定义对话框。

    popwin = new TitleWindow(); 
    popwin.addElement(myCustomDialog);
    PopUpManager.addPopUp(popwin,this,false);
    PopUpManager.centerPopUp(popwin);

当弹出的TitleWindow的灰色标题栏位于Flex应用程序矩形边界之外时，可以拖动弹出的TitleWindow并松开它，然后无法再次抓取弹出窗口。也可以向下拖动 TitleWindow，使其在 Flex 应用程序矩形底部边缘下方完全不可见。当 Flex 应用程序边界小于整个浏览器窗口并且用户工作速度很快时，发生这种情况的可能性就会增加。是否有一个简单的设置可以防止这种情况发生，或者程序员必须在拖动操作期间拦截该行为？

谢谢 蒂姆

Answer 1

嘿，据我所知，没有一个简单的设置可以防止这种情况发生。您所需要做的就是观察它每次移动并确保它保持在一定的范围内。如果您愿意，您可以将该事件处理程序抽象到某个控制器类中。

这是一个基本示例：

<?xml version="1.0" encoding="utf-8"?>
<s:Application 
    xmlns:fx="http://ns.adobe.com/mxml/2009"
    xmlns:s="library://ns.adobe.com/flex/spark"
    xmlns:mx="library://ns.adobe.com/flex/mx"
    creationComplete="creationCompleteHandler()">

    <fx:Script>
        <![CDATA[
            import flash.geom.Rectangle;
            import mx.core.FlexGlobals;
            import mx.core.UIComponent;
            import mx.events.MoveEvent;
            import mx.managers.PopUpManager;
            import spark.components.TitleWindow;

            protected function creationCompleteHandler():void
            {
                var window:TitleWindow = new TitleWindow();
                PopUpManager.addPopUp(window, this, false);
                PopUpManager.centerPopUp(window);
                window.addEventListener(MoveEvent.MOVE, window_moveHandler);
            }

            protected function window_moveHandler(event:MoveEvent):void
            {
                var window:UIComponent = event.currentTarget as UIComponent;
                var application:UIComponent = FlexGlobals.topLevelApplication as UIComponent;
                var bounds:Rectangle = new Rectangle(0, 0, application.width, application.height);
                var windowBounds:Rectangle = window.getBounds(application);
                var x:Number;
                var y:Number;
                if (windowBounds.left <= bounds.left)
                    x = bounds.left;
                else if (windowBounds.right >= bounds.right)
                    x = bounds.right - window.width;
                else
                    x = window.x;
                if (windowBounds.top <= bounds.top)
                    y = bounds.top;
                else if (windowBounds.bottom >= bounds.bottom)
                    y = bounds.bottom - window.height;
                else
                    y = window.y;
                window.move(x, y);
            }

        ]]>
    </fx:Script>

</s:Application>

希望有所帮助，
槊

Answer 2

只需创建类并覆盖移动事件

包 SmartComponants
{
导入spark.components.TitleWindow；

public class SmartTitleWindow extends TitleWindow
{
    public function SmartTitleWindow()
    {
        super();
    }
        private static const MIN_VISIBLE:int = 50;

        public override function move(x:Number, y:Number):void
        {
            var maxX:Number = stage.stageWidth - MIN_VISIBLE;
            var maxY:Number = stage.stageHeight - MIN_VISIBLE;

            if (x < 0)
                x = 0;
            else if (x > maxX)
                x = maxX;

            if (y < 0)
                y = 0;
            else if (y > maxY)
                y = maxY;

            super.move(x, y);
        }
    }

}