使用TCL超时

Question

TCL 有没有办法将一段代码包含在超时块中？我的意思是，即使执行未完成，该块也会在特定超时后退出。 例如：-

timeout (interval) {
#wait for socket connection here

}

如果在间隔时间内没有建立连接，则块退出。

谢谢和问候， 安贾利

Answer 1

安贾利，
您正在寻找 vwait。

这是一个示例：等待五秒钟以连接到服务器套接字，否则关闭套接字并继续运行脚本：

# Initialise the state
after 5000 set state timeout
set server [socket -server accept 12345]
proc accept {args} {
   global state connectionInfo
   set state accepted
   set connectionInfo $args
}

# Wait for something to happen
vwait state

# Clean up events that could have happened
close $server
after cancel set state timeout

# Do something based on how the vwait finished...
switch $state {
   timeout {
      puts "no connection on port 12345"
   }
   accepted {
      puts "connection: $connectionInfo"
      puts [lindex $connectionInfo 0] "Hello there!"
   }
}

编辑
您需要使用 非阻塞 I/O< 与 UART 设备进行通信/a>.

Answer 2

我知道这是一个老问题，每隔几年我都会被同样的问题绊倒。我想提供 vwait 的替代方案，因为实际上没有必要，尽管有一些重要的警告尚未指出。这是专门针对串行 i/o 期间的超时，如原始问题所示。这是摘录。我知道完整的代码更好，但无论如何，所有 I/O 对于您的设备来说都是唯一的。

set port /dev/ttyUSB0
set TIMEOUT 1000

### Important: this MUST be a global variable, even if
### it's only used in this subroutine 
global waitFlag

### for timeouts to work, need non-blocking i/o on the port
if {[catch {open $port "RDWR"} fh]} {
  puts stderr "Cannot open $port"}
  return "error"
  }
fconfigure $fh -mode 38400,n,8,1 -buffering none -blocking 0

### In this example, remote device responds with "<OK>" when
### "<RS>" is sent, though it may take a few read operations
### to get the full string. Your protocol may vary.

puts -nonewline $fh "<RS>"
flush $fh

set waitFlag 1
### create a timeout: after a while, flag will change value
set timeout [after $TIMEOUT {set waitFlag 0}]

set response ""
set n -1
while {$n == -1} {
  ### 10ms delay between successive reads, no point going faster than
  ### your serial i/o. Fine tune for speed and size of packets.
  after 10
  append response [read $fh]
  ### keep reading until the closing ">" arrives ...
  set n [string first > $response]
  ### ... or the waitFlag changes to indicate timeout
  ### Important: without an "update", the delayed change in waitFlag
  ### will not propagate back.
  update
  if { $waitFlag == 0 } {break}
  }
close $fh

### Important: a successful read needs to cancel the pending timeout
### otherwise it may hang around and time out unexpectedly on the next
### communication.
if {$waitFlag == 0} { return "timeout" }\
else                { after cancel $timeout; return $response }