设置脚本尝试挂载网络驱动器时的过期时间

Question

下面的启动脚本在我的 macbook 中安装网络驱动器：

try
  tell application "Finder"
     mount volume "afp://iMac-01._afpovertcp._tcp.local/Backup%20HD"
  end tell
end try

对于我来说，此脚本有两个问题：

• 如果我不在网络驱动器所在的本地网络中，则脚本需要很长时间才能尝试连接有了它，并使我的 MacBook 初始化缓慢。那么，如何设置脚本尝试连接网络驱动器的最长时间？

• 如果无法连接网络驱动器，则会弹出一条警告消息。如何忽略此消息？即，让它不出现。

我之前从未制作过苹果脚本，所以如果可能的话，请帮助我修改原始脚本。

提前致谢。

Answer 1

使用“带超时”

try
    with timeout of x seconds
        tell application "Finder"
            mount volume "afp://iMac-01._afpovertcp._tcp.local/Backup%20HD"
        end tell
    end timeout
end try

Answer 2

回答你的问题：
1：按照 mcgrailm 的规定使用超时；但是尝试只写

with timeout of 2 second --no plural
    <your code here>
end timeout

2：弹出的对话框是一个查找器弹出窗口，因此您的脚本看不到它，“尝试错误”永远不会被调用，因为错误永远不会返回到脚本，所以如果您想自动化单击“确定”，然后此代码将起作用。此代码将在超时秒数后单击按钮。

try
    <your code here>
on error
    tell application "System Events"
        keystroke return
    end tell
end try 

我还包含了我在家使用的相同想法的版本，此脚本会检查网络，然后尝试使用 shell 安装来安装卷。我最初使用带有超时功能的查找器“安装卷”，并且代码也作为内联注释存在，但我不喜欢在错误时弹出对话框；即使只有一秒钟，所以我转向 shell 脚本。

--------------------------------------------------------------------------------------
--"Basic Drive Mounter.app"
try
    set IP_address to "xxx.xxx.xxx.xxx"

    set IP_Valid to true

    try
        do shell script ("ping -c 2 " & IP_address)
    on error
        set IP_Valid to false
    end try

    if IP_Valid then
        tell application "Finder"
            if disk "work" exists then
            else

                try
                    do shell script "mkdir /Volumes/work"
                end try

                do shell script "mount_afp afp://xxx.xxx.xxx.xxx/work /Volumes/work/"

                -->>finder mount volume version
                --with timeout of 2 second
                --  mount volume "afp://xxx.xxx.xxx.xxx/work"
                --end timeout
                --<<finder mount volume version
            end if
        end tell
    end if
on error
    return 0

    -->>finder mount volume version
    --on error finder returns an error dialog which needs to be closed to go back and  retry
    --tell application "System Events"
    --  keystroke return
    --end tell
    --<<finder mount volume version
end try    
--------------------------------------------------------------------------------------