如何通过常用的 System.IO 类访问网络驱动器？

Question

我的软件处理对文件的多个操作，现在我已经使用 System.IO 类完成了相关函数的编写。

我现在需要添加对网络驱动器的支持。使用映射效果很好（虽然 Directory.GetFiles 有点低，我不知道为什么），但我现在希望能够直接处理诸如 \\192.168.0.10\共享文件夹\MyDrive。除了将驱动器安装到可用驱动器号、使用新生成的路径然后卸载之外，还有其他方法可以处理此类路径吗？

Answer 1

您可以直接在路径中使用 UNC 路径（以 \\ 开头）。但是，您必须考虑此连接的凭据，这可能是棘手的部分。

有几种方法：

1. 如果远程系统位于同一域中或者域之间存在信任关系，并且您的程序运行的用户具有适当的访问权限，则它将“正常工作”。

2. 您可以 shell 执行并执行 net use 命令（通过 Windows net.exe 程序），以使用特定的用户名和密码建立连接。请注意，连接可供用户会话中运行的任何程序使用，而不仅仅是您的应用程序。完成后，使用 /DELETE 命令删除连接。典型的语法是：net use \\computername\sharename password /USER:domain\username。

3. 您可以 P/Invoke WNetAddConnection2 来完成与 net use 相同的操作，而无需使用 net.exe。通过将 NULL 作为 lpLocalName 传递，不会分配驱动器盘符，但用户名和密码将应用于通过 UNC 路径进行的后续访问。 WNetCancelConnection2 函数可用于断开连接。

4. 您可以使用 LOGON32_LOGON_NEW_CREDENTIALS 标志 P/Invoke LogonUser，然后进行模拟，以向您的线程添加其他远程凭据。与#2 和#3 不同，对用户整个会话的影响会更加有限。 （实际上，很少这样做，有利于众所周知的 WNetAddConnection2 解决方案。）

以下是如何从 VB.NET 调用 WNetAddConnection2 的示例。

Private Sub Test()
    Dim nr As New NETRESOURCE
    nr.dwType = RESOURCETYPE_DISK
    nr.lpRemoteName = "\\computer\share"
    If WNetAddConnection2(nr, "password", "user", 0) <> NO_ERROR Then
        Throw New Exception("WNetAddConnection2 failed.")
    End If
    'Code to use connection here.'
    If WNetCancelConnection2("\\computer\share", 0, True) <> NO_ERROR Then
        Throw New Exception("WNetCancelConnection2 failed.")
    End If
End Sub

<StructLayout(LayoutKind.Sequential)> _
Private Structure NETRESOURCE
    Public dwScope As UInteger
    Public dwType As UInteger
    Public dwDisplayType As UInteger
    Public dwUsage As UInteger
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpLocalName As String
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpRemoteName As String
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpComment As String
    <MarshalAs(UnmanagedType.LPTStr)> _
    Public lpProvider As String
End Structure

Private Const NO_ERROR As UInteger = 0
Private Const RESOURCETYPE_DISK As UInteger = 1

<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Private Shared Function WNetAddConnection2(ByRef lpNetResource As NETRESOURCE, <[In](), MarshalAs(UnmanagedType.LPTStr)> ByVal lpPassword As String, <[In](), MarshalAs(UnmanagedType.LPTStr)> ByVal lpUserName As String, ByVal dwFlags As UInteger) As UInteger
End Function

<DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Private Shared Function WNetCancelConnection2(<[In](), MarshalAs(UnmanagedType.LPTStr)> ByVal lpName As String, ByVal dwFlags As UInteger, <MarshalAs(UnmanagedType.Bool)> ByVal fForce As Boolean) As UInteger
End Function

Answer 2

使用普通的 UNC 路径（例如您提到的路径）非常适合我。例如：

string[] dirs = Directory.GetDirectories(@"\\192.168.1.116\");

工作得很好。如果没有，您可能遇到安全问题或其他问题。在这种情况下，您必须考虑冒充来解决这个问题。有关模拟的更多信息，请查看此。

Answer 3

您发布的 UNC 路径 (\\192.168.0.10\Shared Folder\MyDrive) 很奇怪。没有“驱动器”，这样的共享表现为目录。您可以使用Directory.GetFiles(@"\\192.168.0.10\共享文件夹")。