在 Grails / Groovy 中拦截或重命名方法调用

Question

我正在尝试拦截 Grails 应用程序中的方法调用（域类的 afterInsert()）。在我的插件的 doWithDynamicMethods 关闭中，我有：

for (dc in application.domainClasses) {
    // What I'm basically doing is renaming method A to B
    // and creating a new method A with its own business logic
    // and a call to B() at the end

    def domainClass = dc.getClazz()
    def oldAfterInsert = domainClass.metaClass.afterInsert
    domainClass.metaClass."afterInsert_old" = oldAfterInsert

    dc.metaClass.afterInsert = {
        // New afterInsert() logic here

        // Call the old after insert
        delegate.afterInsert_old()
    }

}

但后来我得到了这个错误：

No signature of method: static com.example.afterInsert_old() is applicable for argument types: () values: []

我也尝试用 dc.metaClass."afterInsert_old".invoke(delegate, new Object[0]) 调用它，但后来我得到：

Caused by: groovy.lang.MissingMethodException: No signature of method: groovy.lang.ExpandoMetaClass$ExpandoMetaProperty.invoke() is applicable for argument types: (com.example.DomainName, [Ljava.lang.Object;) values: [com.example.DomainName : 115, []]

什么是我做错了吗？如何调用不带参数的方法？

我了解 AOP，也见过 Grails Audit Logging 插件作为示例。然而，据我所知，它的作用是添加新的用户创建的方法，并在正确的时间触发。我想自动注入我的代码，以便用户不必担心任何事情，并且我不想破坏他原来的 afterInsert() （或任何方法）实现。

另外，我想对公开的服务方法执行相同的操作，以便为它们注入安全性。然而，据我所知，由于 BeanWrapper 以及服务总是重新加载，它无法工作。有人可以向我更好地解释一下吗？

提前致谢。

Answer 1

我认为您不需要重命名旧方法。您可以像这个示例：

for (dc in application.domainClasses) {
    // What I'm basically doing is renaming method A to B
    // and creating a new method A with its own business logic
    // and a call to B() at the end
    def domainClass = dc.getClazz()
    def savedAfterInsert = domainClass.metaClass.getMetaMethod('afterInsert', [] as Class[])
    domainClass.metaClass.afterInsert = {
        // New afterInsert() logic here

        // Call the old after insert
        savedAfterInsert.invoke(delegate)
    }

}

只要确保 getMetaMethod 返回正确的方法即可。