如何安全地处理可选参数

Question

我正在编写一个过程来在输出文件中创建标头。

目前它需要一个可选参数，这是标题的可能注释。

我最终将其编码为单个可选参数

proc dump_header { test description {comment = ""}}

，但想知道如何使用 args 实现相同的效果

proc dump_header { test description args }

很容易检查 args 是否为单个空白参数（$args ==“”），但无法应对好吧，如果传递多个参数 - 而且我无论如何都需要否定检查。

Answer 1

您的过程定义不正确（您会收到错误消息参数说明符“comment =”“”中的字段太多）。应该是：

proc dump_header { test description {comment ""}} {
    puts $comment
}

如果您想使用args，您可以检查它的llength：

proc dump_header {test desc args} {
    switch -exact [llength $args] {
        0 {puts "no comment"}
        1 {puts "the comment is: $args"}
        default {
            puts "the comment is: [lindex $args 0]"
            puts "the other args are: [lrange $args 1 end]"
        }
    }
}

您可能还想在列表中传递名称-值对：

proc dump_header {test desc options} {
    # following will error if $options is an odd-length list
    array set opts $options

    if {[info exists opts(comment)]} {
        puts "the comment is: $opts(comment)"
    }
    puts "here are all the options given:"
    parray opts
}
dump_header "test" "description" {comment "a comment" arg1 foo arg2 bar}

有些人更喜欢组合args 和名称-值对（a la Tk）

proc dump_header {test desc args} {
    # following will error if $args is an odd-length list
    array set opts $args
    if {[info exists opts(-comment)]} {
        puts "the comment is: $opts(-comment)"
    }
    parray opts
}
dump_header "test" "description" -comment "a comment" -arg1 foo -arg2 bar

Answer 2

我使用 tcllib 的 cmdline 库来进行选项解析。

这是 cmdline 文档中的示例：

set options {
    {a          "set the atime only"}
    {m          "set the mtime only"}
    {c          "do not create non-existent files"}
    {r.arg  ""  "use time from ref_file"}
    {t.arg  -1  "use specified time"}
}
set usage ": MyCommandName \[options] filename ...\noptions:"
array set params [::cmdline::getoptions argv $options $usage]

if {  $params(a) } { set set_atime "true" }
set has_t [expr {$params(t) != -1}]
set has_r [expr {[string length $params(r)] > 0}]
if {$has_t && $has_r} {
    return -code error "Cannot specify both -r and -t"
} elseif {$has_t} {
    ...
}

因此，在您的情况下，您只需使用 args 代替上面示例中的 argv 即可。

Answer 3

应该明确指出，args 是 Tcl 中的一个特殊词，当在参数列表末尾使用时，它包含所有剩余参数的列表。如果没有给出 args，则不会产生错误（与任何其他变量名称不同，它被视为必需参数）。

我一直在寻找一种具有类似于 python 的 kwargs （可选键值对参数）的功能的方法，并且效果很好的方法是（类似于 Glenn 的最后一个示例）：

proc my_proc {positional_required1 {positional_optional1 "a_string"} args} {
    # Two optional arguments can be given: "opt1" and "opt2"
    if {![string equal $args ""]} {
        # If one or more args is given, parse them or assign defaults.
        array set opts $args
        if {[info exists opts(opt1)]} { set opt1 $opts(opt1) } else { set opt1 0 } 
        if {[info exists opts(op2)]} { set opt2 $opts(opt2) } else { set opt2 -1 }
    } else {
        # If no args are given, assign default values. 
        set op1 0
        set op2 -1
    }   
    # DO STUFF HERE
}

调用：

my_proc "positional_required1_argument" 
# OR
my_proc "positional_required1_argument" "a_string"
# OR
my_proc "positional_required1_argument" "a_string" opt1 7
# OR
my_proc "positional_required1_argument" "a_string" opt1 7 opt2 50
# etc.

并且可以这样 潜在的缺点（正如我目前已经实现的那样）是，如果用户传递未经批准的键值选项，则不会出现错误。