在 Perl 中，如何从库导入哈希？

Question

我有一个文件 revs.pm：

my %vers = ( foo => "bar" );

另一个文件如 importer.pl：

use revs;

如何从 importer.pl 访问 %vers ？

Answer 1

创建适当的模块并将 my 关键字更改为 我们的：

# revs.pm
package revs;

our %vers = ( foo => "bar" );

1; # Perl modules need to return a boolean "true" value.

# importer.pl
use revs;

print $revs::vers{foo} . "\n";

Answer 2

另一种传统方法是在 package，并导出变量：

package revs;
use strict;
use warnings;
require Exporter;
our @ISA    = qw(Exporter);
our @EXPORT = qw(%vers);
our %vers   = (foo=>'bar');
1;

这避免了在从 importer.pl 引用变量时必须使用包名称：

use strict;
use warnings;
use Data::Dumper;
use revs;
print Dumper(\%vers);

一个缺点是您必须确保变量名称是唯一的，以避免名称冲突。

Answer 3

或者，您可以不将程序的某些部分与
全局变量。考虑一下当您在一个模块中使用此哈希时会发生什么：

package Foo;
use MyApp::Versions qw(%versions); # i'm going to pretend that you didn't call the module "revs".

some_function {
    while(my ($k, $v) = each %versions){
       return if $some_condition;
    }
}

然后在其他某个模块中：

package Bar;
use MyApp::Versions qw(%versions);

some_other_function {
    while(my ($k, $v) = each %versions){
       print "$k => $v\n";
    }
}

然后使用这两个模块：

use Foo;
use Bar;

some_other_function;
some_function;
some_other_function;

根据 $some_condition，some_other_function 会产生不同的结果
每次调用时都会得到结果。祝调试愉快。 （这是
更多的是每个问题而不是全局状态问题；但通过暴露
在内部实现中，您允许调用者执行以下操作
你不是故意的，这很容易破坏你的程序。）

当你改变硬编码时，重写 Foo 和 Bar 也是一件痛苦的事情
例如，哈希到按需数据库查找。

所以真正的解决方案是设计一个合适的 API，并将其导出
而不是整个变量：

package MyApp::Versions;
use strict;
use Carp qw(confess);
use Sub::Exporter -setup => {
    exports => ['get_component_version'],
};

my %component_versions = ( foo => 42 ); # yes, "my", not "our".

sub get_component_version {
    my ($component) = @_;
    return $component_versions{$component} ||
        confess "No component $component!"
}

1;

现在你的模块更容易使用：

package Foo;
use MyApp::Versions qw(get_component_version);

sub some_function {
    die 'your foo is too old'
        unless get_component_version('foo') >= 69;

    return FooComponent->oh_hai;
}

现在 some_function 不能搞乱 some_other_function，当你
更改 get_component_version 的实现，其余的
程序不会关心。