终止来自 TIdTCPServer 的非活动套接字连接

Question

我们有一个应用程序，它使用 Delphi 2007 附带的 Indy 10.1.1 组件来侦听传入的 TCP 请求。

有时，我们会收到并非来自客户端应用程序的传入连接。通常，会发生以下两种情况之一：1) 在接收到任何数据之前，连接被客户端终止，或者 2) 收到我们不期望的数据，并且我们手动终止连接。

但是，我们收到的连接没有收到任何数据，并且似乎一直持续到客户端从其一端终止连接为止。

如果在指定时间后没有收到数据，是否有办法终止与服务器的此类连接？

Answer 1

在 OnExecute 事件处理程序中，跟踪从客户端接收到最后一次有效数据的时间。使用连接的 ReadTimeout 属性，您可以定期使挂起的读取操作超时，以便您可以检查客户端是否有一段时间没有发送数据，如果是，则断开连接。

Answer 2

将其保存为killthread.pas

unit killthread;

interface

uses
  Classes, IdTCPServer, IdTCPClient, IdContext, Types, SyncObjs;

type
  TKillThread = class(TThread)
  private
    FContext: TIdContext;
    FInterval: DWORD;
    FEvent: TEvent;
  protected
    procedure Execute; override;
  public
    constructor Create(AContext: TIdContext; AInterval: DWORD); overload;
    destructor Destroy; override;
    procedure Reset;
    procedure Stop;
  end;

implementation

{ TKillThread }

constructor TKillThread.Create(AContext: TIdContext; AInterval: DWORD);
begin
  FContext := AContext;
  FInterval := AInterval;
  FEvent := TEvent.Create(nil, False, False, '');
  inherited Create(False);
end;

destructor TKillThread.Destroy;
begin
  FEvent.Free;
  inherited Destroy;
end;

procedure TKillThread.Reset;
begin
  FEvent.SetEvent;
end;

procedure TKillThread.Stop;
begin
  Terminate;
  FEvent.SetEvent;
  WaitFor;
end;

procedure TKillThread.Execute;
begin
  while not Terminated do
  begin
    if FEvent.WaitFor(FInterval) = wrTimeout then
    begin
      FContext.Connection.Disconnect;
      Exit;
    end;
  end;
end;

end.

然后在服务器端执行此操作：

procedure TYourTCPServer.OnConnect(AContext: TIdContext);
begin
  AContext.Data := TKillThread.Create(AContext, 120000);
end;

procedure TYourTCPServer.OnDisconnect(AContext: TIdContext);
begin
  TKillThread(AContext.Data).Stop;
end;

procedure TYourTCPServer.OnExecute(AContext: TIdContext);
begin
  if AContext.Connection.Connected then
  begin
    TKillThread(AContext.Data).Reset;
    // your code here
  end;
end;

Answer 3

我有类似的问题，我用的是delphi7+Indy9。

和我的解决方案：
在 TIdTCPServer 事件 onConnect 中，我确实喜欢这个，

procedure Tf_main.ServerHostConnect(AThread: TIdPeerThread);
begin
  //code something

  //mean AThread will do Disconnected  if Client no activity ( send receive ) on interval...) 
  AThread.Connection.ReadTimeout := 300000;  //5 minutes..

  //code something
end;

也许在 Indy10 上你可以做类似的事情

Answer 4

您应该能够调用(TIdTCPConnection).Disconnect。