我什么时候应该嵌套 PL/SQL BEGIN...END 块？

Question

当看起来正确时，我一直在某种程度上随意地将 BEGIN...END 块中的代码小节分组。大多数情况下，当我正在处理较长的存储过程并且在某个位置需要临时变量时，我将仅为该部分代码声明它。当我想要识别和处理特定代码段引发的异常时，我也会这样做。

还有其他原因为什么应该在过程、函数或另一个较大的 PL/SQL 块中嵌套块吗？

Answer 1

当你想像这样在本地处理异常时：

begin
   for emp_rec in (select * from emp) loop
      begin
         my_proc (emp_rec);
      exception
         when some_exception then
            log_error('Failed to process employee '||emp_rec.empno);
      end;
   end loop;
end;

在这个例子中，异常被处理，然后我们继续处理下一个员工。

另一个用途是声明具有有限范围的局部变量，如下所示：

declare
    l_var1 integer;
    -- lots of variables
begin
   -- lots of lines of code
   ...
   for emp_rec in (select * from emp) loop
      declare
         l_localvar integer := 0;
      begin
         -- Use l_localvar
         ...
      end
   end loop;

end;

请注意，想要这样做通常表明您的程序太大并且应该分解：

declare
   l_var1 integer;
   -- lots of variables
   ...
   procedure local_proc (emp_rec emp%rowtype):
      l_localvar integer := 0;
   begin
      -- Use l_localvar
      ...
   end
begin
   -- lots of lines of code
   ...
   for emp_rec in (select * from emp) loop
      local_proc (emp_rec);
   end loop;

end; 

Answer 2

当我想要创建特定于仅存在于块中的数据的过程时，我倾向于嵌套块。这是一个人为的示例：

BEGIN
  FOR customer IN customers LOOP
    DECLARE

      PROCEDURE create_invoice(description VARCHAR2, amount NUMBER) IS
      BEGIN
        some_complicated_customer_package.create_invoice(
            customer_id => customer.customer_id,
            description => description,
            amount => amount
          );
      END;

    BEGIN

      /* All three calls are being applied to the current customer,
         even if we're not explicitly passing customer_id.
       */
      create_invoice('Telephone bill',  150.00);
      create_invoice('Internet bill',   550.75);
      create_invoice('Television bill', 560.45);

    END;
  END LOOP;
END;

当然，通常没有必要，但是当可以从多个位置调用过程时，它确实非常方便。

Answer 3

具有嵌套 BEGIN/END 块的原因之一是能够处理代码的特定本地部分的异常，并且在处理异常时可能继续处理。