XPath“之前的兄弟姐妹”

Question

我正在尝试使用 XPath 1.0（或者可能使用 Regex）选择元素 (a)，这些元素位于特定元素 (b) 的同级元素 (b) 后面，但仅位于另一个 b 元素之前。

<img><b>First</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/first-href">First Href</a> - 19:30<br>
<img><b>Second</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/second-href">Second Href</a> - 19:30<br>
<img>&nbsp;&nbsp;<a href="/third-href">Third Href</a> - 19:30<br>

我试图让样本尽可能接近现实世界。因此，在这种情况下，当我处于元素状态时，

<b>First</b>

我需要选择

<a href="/first-href">First Href</a> 

，而当我处于元素状态时，

<b>Second</b> 

我需要选择

<a href="/second-href">Second Href</a> 
<a href="/third-href">Third Href</a>

知道如何实现这一目标吗？谢谢你！

Answer 1

动态创建此 XPath：

following-sibling::a[preceding-sibling::b[1][.='xxxx']]

其中“xxxx”替换为当前 的文本。

这是假设所有元素实际上都是兄弟元素。如果不是，您可以尝试使用 preceding 和 following 轴，或者编写一个更具体的、更类似于文档结构的 XPath。

在 XSLT 中您还可以使用：

following-sibling::a[
  generate-id(preceding-sibling::b[1]) = generate-id(current())
]

Answer 2

这是一个只有单个 XPath 表达式的解决方案。

使用两个节点集 $ns1 和 $ns2 的交集凯斯公式：

  $ns1[count(. | $ns2) = count($ns2)]

我们只需将 $ns1 替换为当前 节点之后的 同级节点集，并且我们将 $ns2 替换为 的节点集 兄弟节点位于下一个 节点之前。

这是使用此转换的完整转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="/">
   <xsl:apply-templates select="*/b"/>
  </xsl:template>

  <xsl:template match="b">
    At: <xsl:value-of select="."/>

    <xsl:variable name="vNextB" select="following-sibling::b[1]"/>

    <xsl:variable name="vA-sAfterCurrentB" select="following-sibling::a"/>

    <xsl:variable name="vA-sBeforeNextB" select=
    "$vNextB/preceding-sibling::a
    |
     $vA-sAfterCurrentB[not($vNextB)]
    "/>

    <xsl:copy-of select=
     "$vA-sAfterCurrentB
              [count(.| $vA-sBeforeNextB)
              =
               count($vA-sBeforeNextB)
               ]
    "/>
  </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
    <img/>
    <b>First</b>
    <br />  
    <img/>  
    <a href="/first-href">First Href</a> - 19:30
    <br />
    <img/>
    <b>Second</b>
    <br />
    <img/>  
    <a href="/second-href">Second Href</a> - 19:30
    <br />
    <img/> 
    <a href="/third-href">Third Href</a> - 19:30
    <br />
</t>

生成正确的结果：

   At: First <a href="/first-href">First Href</a>
    At: Second <a href="/second-href">Second Href</a>
<a href="/third-href">Third Href</a>