浏览目录的最佳方式是什么？

Question

下面的两个例子都可以吗，还是第二个例子风格不好？

情况 1：留在顶层目录并使用 catdir 访问子目录

#!/usr/bin/env perl
use warnings; use strict;

my $dir = 'my_dir_with_subdir';
my ( $count, $dh );

use File::Spec::Functions;
$count = 0;

opendir $dh, $dir or die $!;
while ( defined( my $file = readdir $dh ) ) {
    next if $file =~ /^\.{1,2}$/;
    my $sub_dir = catdir $dir, $file;
    if ( -d $sub_dir ) {
        opendir my $dh, $sub_dir or die $!;
        while ( defined( my $file = readdir $dh ) ) {
            next if $file =~ /^\.{1,2}$/;
            $count++;
        }
        closedir $dh or die $!;
    }
    else {
        $count++;
    }
}

closedir $dh or die $!;
print "$count\n";

情况 2：更改为子目录并在退出前恢复顶层目录

use Cwd;
my $old = cwd;
$count = 0;
opendir $dh, $dir or die $!;
chdir $dir or die $!;
while ( defined( my $file = readdir $dh ) ) {
    next if $file =~ /^\.{1,2}$/;
    if ( -d $file ) {
        opendir my $dh, $file or die $!;
        chdir $file or die $!;
        while ( defined( my $file = readdir $dh ) ) {
            next if $file =~ /^\.{1,2}$/;
            $count++;
        }
        closedir $dh or die $!;
        chdir $dir;
    }
    else {
        $count++;
    }
}
closedir $dh or die $!;
chdir $old or die $!;
print "$count\n";

Answer 1

您的问题是您是否应该更改到正在浏览的目录或保留在顶级目录中。

答案是：这取决于。

例如，考虑文件::查找。默认行为确实是更改目录。但是，该模块还提供了 no_chdir 选项如果这是不可取的。

就您的示例而言，File::Find 可能不合适，因为您不想递归遍历所有子目录，而只想递归一个子目录。这是基于 File::Slurp::read_dir 的脚本变体。

#!/usr/bin/perl

use strict; use warnings;

use File::Slurp;
use File::Spec::Functions qw( catfile );

my ($dir) = @ARGV;

my $contents = read_dir $dir;
my $count = 0;

for my $entry ( @$contents ) {
    my $path = catfile $dir, $entry;
    -f $path and ++ $count and next;
    -d _ and $count += () = read_dir $path;
}

print "$count\n";

Answer 2

对于您的示例，最好更改为子目录，并且不要在最后更改回原始目录。这是因为每个进程都有自己的“当前目录”，因此您的 perl 脚本正在更改其自己的当前目录这一事实并不意味着 shell 的当前目录已更改；相反，它会更改 shell 的当前目录。保持不变。

如果这是一个更大脚本的一部分，那就会有所不同；我的一般偏好是不更改目录，只是为了减少对脚本中任何点当前目录的混淆。

Answer 3

使用 File::Find，正如您已经建议的那样:)

使用模块来解决这样的问题几乎总是比自己推出更好，除非您真的想了解步行目录...