更改复选框状态而不调用 OnClick 事件

Question

我想知道当我更改 CheckBox 的状态时

CheckBox->Checked=false;

它会调用 CheckBoxOnClick Event ，如何避免它？

Answer 1

有时

需要更改 TCheckBox 组件的状态，但无需操作 OnClick 事件。这个任务可以这样解决：

{设置一个已检查}

yourCheckBox.Perform(BM_SETCHECK, 1, 0);

{设置一个未检查}

yourCheckBox.Perform(BM_SETCHECK, 0, 0);

Answer 2

CheckBox.State := cbUnchecked; 在 Delphi 中工作，这不会触发 onClickEvent AFAIK

Answer 3

在较新的 Delphi 版本中，您可以使用类帮助器来添加此功能：

CheckBox.SetCheckedWithoutClick(False);

通过对 VCL TCheckBox 使用以下类帮助器：

TCheckBoxHelper = class helper for TCheckBox
    procedure SetCheckedWithoutClick(AChecked: Boolean);
end;

procedure TCheckBoxHelper.SetCheckedWithoutClick(AChecked: Boolean);
begin
    ClicksDisabled := True;
    try
        Checked := AChecked;
    finally
        ClicksDisabled := False;
    end;
end;

只是为了完整性：FMX TCheckBox 的行为类似（触发OnChange）。您可以使用以下类帮助器来解决此问题：

TCheckBoxHelper = class helper for TCheckBox
    procedure SetCheckedWithoutClick(AChecked: Boolean);
end;

procedure TCheckBoxHelper.SetCheckedWithoutClick(AChecked: Boolean);
var
    BckEvent: TNotifyEvent;
begin
    BckEvent := OnChange;
    OnChange := nil;
    try
        IsChecked := AChecked;
    finally
        OnChange := BckEvent;
    end;
end;

免责声明：谢谢 dummzeuch 的原始想法。请注意有关类助手的常见提示。

Answer 4

您可以用类似的内容包围 onClick 事件代码，

if myFlag then
  begin
    ...event code...
  end;

如果您不想执行它，请将 myFlag 设置为 false，并在复选框状态更改后将其设置回 true。

Answer 5

另一种选择是使用插入器类更改受保护的 ClicksDisable 属性，如下所示：

type
  THackCheckBox = class(TCustomCheckBox)
  end;

procedure TCheckBox_SetCheckedNoOnClick(_Chk: TCustomCheckBox; _Checked: boolean);
var
  Chk: THackCheckBox;
begin
  Chk := THackCheckBox(_Chk);
  Chk.ClicksDisabled := true;
  try
    Chk.Checked := _Checked;
  finally
    Chk.ClicksDisabled := false;
  end;
end;

Answer 6

我希望有一个按钮解决方案，但您可以将当前事件存储在 TNotifyEvent var 中，然后将 Checkbox.OnChecked 设置为 nil，然后恢复它。

Answer 7

尝试这样：

Checkbox.OnClick := nil;
try
  Checkbox.Checked := yourFlag;
finally
  Checkbox.OnClick := CheckboxClick;
end;

Answer 8

使用 focus 属性来确定控件是否已被单击或选中的内容是否已在控件外部更新。

如果 tcheckbox.focused 那么

 run the content of the method

else

skip the content 

Answer 9

其他一些更简单的解决方案不是避免 OnClick 事件，而是修改事件处理程序，使其不响应，除非 DataSet.State 位于 dsEdit 或 dsInsert 中，由用户触发的 TDBCheckBox 单击启动，例如：

procedure TForm1.chkSelectClick(Sender: TObject);
begin
  if chkSelect.Checked = True then
    if DataSource1.DataSet.State in [dsEdit,dsInsert] then
      begin
        { your event handler }
      end;
end;

Answer 10

简单的解决方案是将 onclick 代码放在 onmouseup 事件中；