awk '{print $2,",",$1}'在 Emacs Lisp 中？

Question

有时，我使用 AWK 提取和/或反转数据文件中的列。

awk '{print $2,",",$1}' filename.txt

我如何使用 Emacs Lisp 做同样的事情？

(defun awk (filename col1 &optional col2 col3 col4 col5)
  "Given a filename and at least once column, print out the column(s)
values in the order in which the columns are specified."
...
)
;; Test awk
(awk "filename.txt" 1); Only column 1
(awk "filename.txt" 2 1); Column 2 followed by column 1
(awk "filename.txt" 3 2 1); Columns 3,2 then 1

示例 filename.txt：

a   b  c
1   2  5

示例输出：

b , a
2 , 1

Answer 1

您打算如何使用这个？您打算将其用作命令行脚本吗？在这种情况下，您需要像 hello world 问题 那样打包它。

或者，您是否计划以交互方式使用它，在这种情况下您可能希望在新缓冲区中输出...

此代码完成了基础知识。您需要更新它以匹配您的使用模型。

(defun awk (filename &rest cols)
  "Given a filename and at least once column, print out the column(s) values
in the order in which the columns are specified."
  (let* ((buf (find-file-noselect filename)))
    (with-current-buffer buf
      (while (< (point) (point-max))
        (let ((things (split-string (buffer-substring (line-beginning-position) (line-end-position))))
              (c cols)
              comma)
          (while c
            (if comma
                (print ", "))
            (print (nth (1- (car c)) things))
            (setq comma t)
            (setq c (cdr c)))
          (print "\n")
          (forward-line))))
    (kill-buffer buf)))

Answer 2

我采用了 Trey 的解决方案并生成了一个从 Unix shell 运行的脚本。它不接受命令行参数，因为我不确定如何将 command-line-args-left 结果转换为正确的参数。

#!/usr/bin/emacs --script

;; ./awk.el; # Change the last line of this file to contain the desired values.
;;
(defun awk (filename &rest cols)
  "Given a filename and at least once column, print out the column(s) values
in the order in which the columns are specified."
  (let* ((buf (find-file-noselect filename)))
    (with-current-buffer buf
      (while (< (point) (point-max))
        (let ((things (split-string (buffer-substring (line-beginning-position) 
                          (line-end-position))))
              (c cols)
              comma)
          (while c
            (if comma
                (princ ", "))
            (princ (nth (1- (car c)) things))
            (setq comma t)
            (setq c (cdr c)))
            (princ "\n")
          (forward-line))))
    (kill-buffer buf)))

(awk "/tmp/foo.txt" 2 1)

Answer 3

使用 dash.el 和 s.el：

(defun print-columns (s &rest is)
  (s-join "\n"
          (--map (s-join ", "
                         (-select-by-indices is (cons it (s-split " " it t))))
                 (s-lines s))))

(print-columns "a  b c\n1  2 3" 3 2 1 0) ; output:
;; c, b, a, a  b c
;; 3, 2, 1, 1  2 3

默认情况下，awk 将文本视为记录序列（以换行符分隔），每个记录都是一系列字段（用空格分隔）。因此，在上面的示例中，c 是记录ab c 的一个字段。函数 print-columns 接收文本，用换行符分隔 s-lines，从每条记录中选择某些字段，用逗号将它们与 s-join，用换行符连接结果。最重要的功能是 dash 的 -select-by-indices，通过索引从列表中选取元素，并以与索引列表相同的顺序返回：

(-select-by-indices '(2 1 0) '(a b c d e)) ; => (c b a)