选择在关闭的 SCTP 套接字上返回 0

Question

这与问题相关： SCTP with Multihoming as a TCP 的直接替换

我有一个简单的回显客户端/并发服务器应用程序，它使用 TCP 运行得非常好。我可以通过管道将文件传输到客户端上的标准输入，客户端将收到所有返回的数据，调用 select 将返回 1 表示套接字可读，然后调用 read 将返回 0 表示 EOF /鳍。然后客户端就会退出。一切都很好。

然而，通过 SCTP 的相同应用程序会导致问题。唯一的更改是从 IPPROTO_TCP 更改为 IPPROTO_SCTP。服务器分叉，回显数据，子进程退出并由父进程收割。客户端接收到所有数据，但之后 select 不断返回 0 个描述符就绪（如果没有我添加的超时，它将永远挂起）。

世界上到底发生了什么事？

客户端代码如下所示：

#!/usr/bin/perl -w
use strict;
use Socket;

# forward declaration
sub logmsg;

my $remote = shift || "localhost";
my $port = 9877;

($port) = $port =~ /^(\d+)$/ or die "invalid port";

my $iaddr = inet_aton($remote) || die "no host: $remote";
my $paddr = sockaddr_in($port, $iaddr);
my $proto = getprotobyname('sctp');

my $sockfd;

socket($sockfd, PF_INET, SOCK_STREAM, $proto) || die "socket: $!";
connect($sockfd, $paddr) || die "connect: $!";

str_cli($sockfd);

exit(0);

#----- subs down here ------#

sub str_cli {
    my $sockfd = shift;

    my ($n, $buff, $stdineof, $s);
    my $rin = '';

    $stdineof = 0;
    while ( 1 ) {
        if ($stdineof == 0) {
            vec($rin, fileno(STDIN), 1) = 1;
        }
        vec($rin, fileno($sockfd), 1) = 1; 

        my $nfound = select($rin, undef, undef, 1.0);
        if ($nfound < 0) {
            next if $!{EINTR};
            die "select: $!";
        } else { print "\$nfound == $nfound\n"; }

        if (vec($rin, fileno($sockfd), 1) == 1) { # socket readable
            print "trying to read from sockfd\n";
            $n = sysread($sockfd, $buff, 1024);
            if (!defined($n) || $n < 0) {
                # resume if sysread() returned because a signal was received
                next if $!{EINTR};
                die "sysread: $!";
            } elsif($n == 0) {
                if ($stdineof == 1) { return; } # normal termination
                else { die "str_cli: server terminated prematurely"; }
            }
            writen(*STDOUT, $buff);
        }

        if (vec($rin, fileno(STDIN), 1) == 1) { # stdin readable
            $n = sysread(STDIN, $buff, 1024);
            if (!defined($n) || $n < 0) {
                # resume if sysread() returned because a signal was received
                next if $!{EINTR};
                die "sysread: $!";
            } elsif($n == 0) {
                $stdineof = 1;
                if (!defined($s = shutdown($sockfd, SHUT_WR)) 
                    || $s == 0) { die("shutdown: $!"); }
                vec($rin, fileno(STDIN), 1) = 0;
                next;
            }
            writen($sockfd, $buff);
        }
    }
}

sub writen {
    my ($connfd, $buff) = @_;
    my $nleft = length($buff);
    my $total = 0;
    my $nwritten = 0;
    while ($nleft) {
        if (($nwritten = syswrite($connfd, $buff, $nleft, $total)) <= 0) {
            # resume if syswrite() returned because a signal was received
            # 0 indicates an error in this context
            next if $!{EINTR};
            die "syswrite: $!";
        }
        $nleft -= $nwritten;
        $total += $nwritten;
    }
}

sub logmsg { print "$0 $$: @_ at ", scalar localtime, "\n" }

请记住，这在 TCP 上完美运行。我使用的是 Ubuntu 9.04，安装了所有需要的 sctp 软件包。

Answer 1

您依赖于 TCP 的半关闭状态，这在 SCTP 中不可用。

使用 TCP，shutdown($sockfd, SHUT_WR) 将发送一个设置了 FIN 位的数据包，关闭连接的发送端，但仍允许接收方向的新数据。 SCTP 没有这种半关闭状态，此调用将启动 SCTP 关闭序列，其中整个连接被关闭。更多详情请参见此处。