带图像的自定义按钮

Question

您好，我正在尝试在 actionscript 3 中创建一个按钮，该按钮将由自定义图像（来自我的 HDD 的 car.jpg ）制作。是否可以使用 SimpleButton 类来做到这一点（我的意思是有没有办法加载图像并将其附加到按钮？）或者还有其他方法吗？ 如果我想在按钮中也有动画，当我从按钮上滚动鼠标指针时，我该怎么办？

ps：我只想使用actionscript 3（我的意思是所有项目都是作为链接到Document类的.as文件完成的）。

Answer 1

尽管 George Profenza 已经在评论下指出了最佳解决方案，但如果您好奇如何实现 SimpleButton 类，您可能需要查看 as3 文档参考示例：

adobe livedocs - SimpleButton 示例

我还编写了一个简单的示例，仅在一个“复杂的按钮”，但使用 SimpleButton 类，因此您可以了解如何扩展该类，并为每个状态提供自己的图形。代码如下：

// this goes in your app
var button:MySimpleButton = new MySimpleButton();
addChild(button);

MySimpleButton.as

package  
{
    import flash.display.DisplayObject;
    import flash.display.SimpleButton;
    import flash.display.Sprite;

    public class MySimpleButton extends SimpleButton 
    {
        private var upAlpha : Number = 1;
        private var overAlpha : Number = 0.5;

        public function MySimpleButton(upState : DisplayObject = null, overState : DisplayObject = null, downState : DisplayObject = null, hitTestState : DisplayObject = null)
        {
            upState = new ButtonImgDisplayState( upAlpha);
            overState = new ButtonImgDisplayState( overAlpha);
            downState = new ButtonImgDisplayState( upAlpha);
            hitTestState = new ButtonImgDisplayState( upAlpha);

            super(upState, overState, downState, hitTestState);
        }
    }
}

ButtonImgDisplayState.as

package  
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.net.URLRequest;

    public class ButtonImgDisplayState extends Sprite 
    {

        public function ButtonImgDisplayState(_alpha:Number)
        {
            var my_loader : Loader = new Loader();
            my_loader.load(new URLRequest("car.jpg"));
            addChild(my_loader);

            this.alpha = _alpha;
        }
    }
}

SimpleButton 的作用是让您无需设置侦听器，但您有义务绕过单独的 DisplayObjects 的状态，这使得您在处理状态之间的转换时按钮变得更加严格。

希望您觉得这很有用。