从抽象类继承属性，并根据抽象属性对集合进行排序

Question

我正在使用 Grails 创建发票管理应用程序，并且遇到继承问题。

如果我的意图是每张发票都应包含行/项目的集合，并且当发票格式化为打印时，项目按日期排序，按类别分为列表，然后以不同的方式计算每行的价格每种具体类型的方式（定时项目将在 rates 属性中查找每小时，定价项目在创建时分配价格）。

节点发票有一个属性“items”，它是 Item 对象的集合。

我的域类的来源：

class Invoice {
    static constraints = {
    }        
    String client

    Date dateCreated
    Date lastUpdated
    CostProfile rates

    def relatesToMany = [items : Item]
    Set items = new HashSet()
}

abstract class Item{
    static constraints = {
    }
    String description
    Date date
    enum category {SERVICE,GOODS,OTHER}
    def belongsTo = Invoice
    Invoice invoice
}

class TimedItem extends Item{

    static constraints = {
    }

    int minutes
}

class PricedItem extends Item{

    static constraints = {
    }

    BigDecimal cost
    BigDecimal taxrate
}

有问题的代码的来源：

invoiceInstance.items.add(new TimedItem(description:"waffle", minutes:60, date:new Date(),category:"OTHER"))
def firstList = []
def lastList = []
invoiceInstance.items.sort{it.date}
invoiceInstance.items.each(){
    switch(((Item)it).category){
        case "LETTER":
            firstList.add(it)
        break;
        default:
            lastList.add(it)
    }
}

错误消息：
groovy.lang.MissingPropertyException: No such property: Category for class: TimedItem

Stacktrace 表示上面示例的第 6 行。

Answer 1

您使用枚举错误。 enum 关键字与 class 关键字类似。因此，当您定义枚举类型时，您从未给您的类提供它的实例。虽然您可以将枚举的定义保留在抽象 Item 类中，但为了清楚起见，我将其移到了外部。

class Invoice {
    Set items = new HashSet()
}

enum ItemCategory {SERVICE,GOODS,OTHER}

abstract class Item{
    String description
    ItemCategory category
}

class TimedItem extends Item{
    int minutes
}


def invoice = new Invoice()
invoice.items.add(new TimedItem(description:"waffle", minutes:60, category: ItemCategory.OTHER))

invoice.items.each(){
    switch(it.category){
        case ItemCategory.OTHER:
            println("Other found")
        break
        default:
            println("Default")
    }
}