Storageable 可以存储到 DATA 文件句柄吗？

Question

我很好奇使用 Storable 的 store_fd 和 fd_retrieve 是否允许我存储将数据结构放入程序自己的 DATA 文件句柄中。我意识到这不是最佳实践，我只是好奇它是否有效，我的快速尝试似乎不起作用。

Answer 1

我不确定你为什么要这样做，但你可以假装它。但你应该尽量避免这种情况。

只是为了咯咯笑，您可以打开一个文件句柄，从 $0 读取行并打印它们，直到到达 __DATA__，然后添加新的 __DATA__ 部分。然后，诀窍是将新文件重命名为 $0，如果您的系统在程序运行时锁定该文件，则可能通过 exec 重命名：

#!perl

my $mode = (stat($0))[2] & 07777;

open my($fh), '<', $0 or die "I can't open me! $!\n";
open my($new), '>', "$0.new" or die "I can't open you! $!\n";
eval { chmod( $mode, $new ) } or warn "Couldn't set permissions: $@\n";

while( <$fh> )
    {
    last if /^__DATA__$/;
    print { $new } $_;
    }

print "I am $\n";
print { $new } "__DATA__\n", join '|', $, time, (stat($0))[1];

rename( "$0.new", $0 )

__DATA__
64574|1265415126|8843292

Answer 2

DATA 是一个句柄，用于读取与脚本一起存储的数据。 Conway 的 Inline::Files 是我临时知道的唯一谈论可写虚拟文件。由于脚本文件通常是 ASCII，我不知道如果在 Storable 的输出中得到 MSDOS 上的二进制 26 字节或 UNIX 上的二进制 4 会发生什么。

但是，如果您谈论的是通过在其中键入来存储数据，只是为了从脚本中读取数据，那么二进制问题仍然存在面对你。

因此，最好使用 YAML 或 JSON 用于持久性。我知道 YAML 在从 DATA 检索数据时会处理祝福。

Answer 3

在正常情况下这是不可能的：

$ cat write-data
#! /usr/bin/perl

use warnings;
print DATA "bar!\n";

$ ./write-data
Name "main::DATA" used only once: possible typo at ./write-data line 6.
print() on unopened filehandle DATA at ./write-data line 6.

但您可以创建特殊的条件：

#! /usr/bin/perl

use warnings;
use strict;

use Data::Dumper;
use File::Temp qw/ tempfile /;
use Storable qw/ store_fd fd_retrieve /;

sub store_in_DATA {
  my($data) = @_;

  my($fh,$path) = tempfile;
  unlink $path           or warn "$0: unlink: $!";

  *DATA = $fh;
  store_fd $data, \*DATA or warn "$0: print: $!";

  seek DATA, 0, 0        or warn "$0: seek: $!";
}

store_in_DATA { foo => "There is no spoon.\n" };

undef $/;
my $ref = fd_retrieve \*DATA;
print Dumper $ref;

在 Windows 上，由于其默认的文件共享语义，您将收到有关 unlink 的警告。如果这是您的平台，您可以在END时间进行清理或使用Win32::SharedFileOpen。

Answer 4

我想出了自己的解决方案......并不是我特别推荐它或任何其他解决方案；就我而言，它是一个单元测试脚本，具有多维哈希结构中的参考值。我不会详细介绍这个东西的作用和原因，但最终结果是代码中的一个小修复或更改可能会导致许多值需要更新（在验证更改有效之后）。

因此，我使用 Data::Dumper 将哈希移至 __DATA__ 部分。将其写入文件句柄的代码如下所示：

use Data::Dumper;
$Data::Dumper::Terse = 1; # to Eval whole thing as a hash
$Data::Dumper::Indent = 1; # Looks better, just a preference
$Data::Dumper::Sortkeys = 1; # To keep changes minimal in source control
print $fh Dumper(\%HASH);

在脚本的开头，我在存储对初始句柄的位置和 mtime 的引用后从 DATA 加载哈希值（mtime 用于确保文件没有在脚本执行期间没有被修改）。

use vars qw(%HASH $FILEPOS $MTIME);

{
    $FILEPOS = tell(DATA);
    $MTIME = (stat(DATA))[9];
    local $/;
    my $data = <DATA>;
    %HASH = %{eval $data};
}

最后，为了更新 __DATA__ 部分，我在 $FILEPOS 打开 __FILE__，截断它并写入。我简化了此示例的错误处理。

open(my $fh, '>>', __FILE__) or die $!;
seek($fh, $FILEPOS, 0) or die $!;
die "File changed" if ((stat($fh))[9] != $MTIME);
truncate($fh, $FILEPOS) or die $!;

# Assumes Dumper is already loaded and configured as in first code snippet
print $fh Dumper(\%HASH);

请务必在开发时保留文件备份，因为一个错误可能会毁掉您的所有代码！

另请注意，这同样适用于 Storable；存储将更加高效、更快。唯一需要注意的是它是二进制的，这意味着文件差异可能不会显示在源代码管理中，并且它不像 Dumper 的输出那样容易编辑。