如何在 F# 中枚举枚举/类型

Question

我有一个像这样定义的枚举类型：

type tags = 
    | ART  = 0
    | N    = 1
    | V    = 2 
    | P    = 3
    | NULL = 4

有没有办法在标签中执行 for ... ？

这是我收到的错误：

值、构造函数、命名空间或 类型标签未定义

Answer 1

怎么样：

let enumToList<'a> = (Enum.GetValues(typeof<'a>) :?> ('a [])) |> Array.toList

这具有提供强类型列表的优点，

使用时只需执行以下操作：

let tagList = enumToList<tags>

Answer 2

使用 Enum.GetValues：

let allTags = Enum.GetValues(typeof<tags>)

Answer 3

这是一个完整的示例，打印有关任何受歧视工会的信息。它展示了如何获取受歧视联合的案例以及如何获取字段（如果您需要它们）。该函数打印给定可区分联合的类型声明：

open System
open Microsoft.FSharp.Reflection

let printUnionInfo (typ:Type) = 
  printfn "type %s =" typ.Name
  // For all discriminated union cases
  for case in FSharpType.GetUnionCases(typ) do
    printf "  | %s" case.Name
    let flds = case.GetFields()
    // If there are any fields, print field infos
    if flds.Length > 0 then 
      // Concatenate names of types of the fields
      let args = String.concat " * " [ for fld in flds -> fld.PropertyType.Name ] 
      printf " of %s" args
    printfn ""    

// Example
printUnionInfo(typeof<option<int>>)

Answer 4

要使其成为枚举，您需要显式地为每种情况赋予值，否则它是联合类型：

type tags = 
    | ART = 0
    | N = 1
    | V = 2
    | P = 3
    | NULL= 4
let allTags = System.Enum.GetValues(typeof<tags>)

Answer 5

罗伯特关于如何生成实际枚举并获取其案例的说法是正确的。如果您有真正的联合类型，则可以通过 Microsoft.FSharp.Reflection.FSharpType.GetUnionCases 函数获取案例。

Answer 6

您可以使用 Enum.GetValues，它返回一个对象的Array，然后您必须将其向下转换为整数值。 （注意：我使用的是 Mono 的 F# 实现；也许 .NET 的情况有所不同。）

以下是我编写的一些函数，用于获取所有枚举值的列表并获取最小值和最大值：

open System

module EnumUtil =

    /// Return all values for an enumeration type
    let EnumValues (enumType : Type) : int list =
        let values = Enum.GetValues enumType
        let lb = values.GetLowerBound 0
        let ub = values.GetUpperBound 0
        [lb .. ub] |> List.map (fun i -> values.GetValue i :?> int) 

    /// Return minimum and maximum values for an enumeration type
    let EnumValueRange (enumType : Type) : int * int =
        let values = EnumValues enumType
        (List.min values), (List.max values)

Answer 7

在 .Net 5 中，有一个 Enum.GetValues 的通用重载，它消除了强制转换的需要。

Enum.GetValues<T>()

Answer 8

type Options = 
    | Exit          = 0
    | CreateAccount = 1

Console.WriteLine()
Console.WriteLine("Choose an option:")
let allOptions = Enum.GetValues(typeof<Options>)
for option in allOptions do
    if (option <> null) then
        Console.WriteLine(sprintf "%d: %s" (option :?> int) (option.ToString()))
let optionChosen = System.Console.ReadLine()