VB6 从 IP 查找主机名，指定 DNS 服务器

Question

我知道如何使用 GetHostByAddr Windows API 调用从 VB 中的 IPv4 查找主机名 (这效果很好）。然而，该功能不允许指定要使用的 DNS 服务器。有时默认的公司 DNS 服务器没问题，但有时我需要指定外部 DNS 服务器进行查找，而且我不认为在这里执行 shell nslookup 并解析输出是最好的方法。

注意：这实际上将用作 Excel 工作簿中的 VBA 代码来帮助其他人完成他的工作，并且当他只需要一些简单的功能时，不值得编写大型应用程序。

我认为我可能在 API 调用 getnameinfo 但仔细阅读似乎表明它不提供 servername 参数。

经过一番激烈的搜索，我发现 对 DNSQuery 函数的 pExtra 参数的引用。但我什至不知道如何开始在 VB6 中使用它。

谁能以任何方式帮助我从 VB6 进行 DNS 查找，指定要使用的服务器名称？

一个完整的工作解决方案当然很好，但我愿意工作：只要为我指明正确的方向即可。

更新：出于某种奇怪的原因，它没有认为 DNSQuery 是 Windows API 调用。听起来根本不像。如果我收集了这一微小的细节，我当然能够在这个问题上取得更大的进展。

Answer 1

试试这个：

Option Explicit

Private Declare Function DnsQuery Lib "dnsapi" Alias "DnsQuery_A" (ByVal strname As String, ByVal wType As Integer, ByVal fOptions As Long, ByVal pServers As Long, ppQueryResultsSet As Long, ByVal pReserved As Long) As Long
Private Declare Function DnsRecordListFree Lib "dnsapi" (ByVal pDnsRecord As Long, ByVal FreeType As Long) As Long
Private Declare Function lstrlen Lib "kernel32" (ByVal straddress As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, ByVal Source As Long, ByVal Length As Long)
Private Declare Function inet_ntoa Lib "ws2_32.dll" (ByVal pIP As Long) As Long
Private Declare Function inet_addr Lib "ws2_32.dll" (ByVal sAddr As String) As Long

Private Const DnsFreeRecordList         As Long = 1
Private Const DNS_TYPE_A                As Long = &H1
Private Const DNS_QUERY_BYPASS_CACHE    As Long = &H8

Private Type VBDnsRecord
    pNext           As Long
    pName           As Long
    wType           As Integer
    wDataLength     As Integer
    flags           As Long
    dwTel           As Long
    dwReserved      As Long
    prt             As Long
    others(35)      As Byte
End Type

Private Sub Command1_Click()
    MsgBox Resolve("google.com", "208.67.222.222")
End Sub

Private Function Resolve(sAddr As String, Optional sDnsServers As String) As String
    Dim pRecord     As Long
    Dim pNext       As Long
    Dim uRecord     As VBDnsRecord
    Dim lPtr        As Long
    Dim vSplit      As Variant
    Dim laServers() As Long
    Dim pServers    As Long
    Dim sName       As String

    If LenB(sDnsServers) <> 0 Then
        vSplit = Split(sDnsServers)
        ReDim laServers(0 To UBound(vSplit) + 1)
        laServers(0) = UBound(laServers)
        For lPtr = 0 To UBound(vSplit)
            laServers(lPtr + 1) = inet_addr(vSplit(lPtr))
        Next
        pServers = VarPtr(laServers(0))
    End If
    If DnsQuery(sAddr, DNS_TYPE_A, DNS_QUERY_BYPASS_CACHE, pServers, pRecord, 0) = 0 Then
        pNext = pRecord
        Do While pNext <> 0
            Call CopyMemory(uRecord, pNext, Len(uRecord))
            If uRecord.wType = DNS_TYPE_A Then
                lPtr = inet_ntoa(uRecord.prt)
                sName = String(lstrlen(lPtr), 0)
                Call CopyMemory(ByVal sName, lPtr, Len(sName))
                If LenB(Resolve) <> 0 Then
                    Resolve = Resolve & " "
                End If
                Resolve = Resolve & sName
            End If
            pNext = uRecord.pNext
        Loop
        Call DnsRecordListFree(pRecord, DnsFreeRecordList)
    End If
End Function

Answer 2

这不是一个答案，但对 wqw 帖子非常重要：

lstrlen 上的安全警告 函数（第 5 行和第 55 行）：

错误地使用此功能可能会危及您的安全
应用程序。 lstrlen 假定 lpString 是一个以 null 结尾的字符串
字符串，或 NULL。如果不是，这可能会导致缓冲区溢出或
针对您的应用程序的拒绝服务攻击。

考虑使用以下替代方案之一：StringCbLength 或
StringCchLength。

Answer 3

您可以使用 DNS WMI 提供程序设置系统的 DNS，然后使用 GetHostByAddr