如何在 Perl 中检查 Windows 上是否存在 Unicode 目录？

Question

我需要检查 Perl 中是否存在 Unicode 目录。我使用的是 Windows XP 和 Perl Camelbox 5.10.0。

如果我尝试创建一个目录（就像此处建议的 Sinan stackoverflow.com/questions/2184726）已经存在的程序会死掉。

不幸的是 if ( !-d $dir_name ) { # create directory $dir_name } 似乎无法识别 Unicode 目录，或者我正在做一些完全愚蠢的事情。我尝试在检查之前对目录名称进行编码，但结果是相同的。

如何检查 Unicode 目录是否存在？

Answer 1

在回答您之前的问题时，我忘记了 Win32.pm 提供了一个不错的界面。我会回去回答。但是，对于您眼前的问题，您需要做的不是当 CreateDirectory 调用失败时自动 die，而是检查 错误代码。如果错误代码是0xb7 (ERROR_ALREADY_EXISTS)，那么您就可以继续愉快的生活了。

问题是，当您有 Unicode 文件名时，很难继续使用 Perl 函数。解决方案是使用 Win32::GetANSIPath （只需关注路径的完整长度）：

#!/usr/bin/perl

use strict; use warnings;
use utf8;

use Encode qw( encode );
use File::Slurp;
use File::Spec::Functions qw( catfile );
use Win32;
use Win32::API;

use constant ERROR_ALREADY_EXISTS => 0xb7;

my $dir_name = 'Волгогра́д';

unless ( Win32::CreateDirectory($dir_name) ) {
    my $err = $^E;
    if ( $err == ERROR_ALREADY_EXISTS ) {
        warn "Directory exists, no problem\n";
    }
    else {
        die Win32::FormatMessage($^E);
    }
}

my $ansi_path = Win32::GetANSIPathName($dir_name);
warn "$ansi_path\n";

哦，还有，祝你删除该目录好运。

不过，严肃地说，整个 Windows Unicode 文件操作有点混乱。

据我了解，如果您希望能够使用 Perl 函数（例如 open）来处理包含 Unicode 字符的路径，则需要 ANSI 路径名。例如：

my $file = catfile($dir_name, 'test.txt');

open my $fh, '>', $file
    or die "cannot create '$file': $!";

会失败而

my $file = catfile($ansi_path, 'test.txt');

open my $fh, '>', $file
    or die "cannot create '$file': $!";

会成功（至少在我的系统上）。如果您只想使用 Win32 API 函数来处理文件，则不需要 ANSI 路径（这在您的情况下可能更容易）。 CPAN 上有很多模块可以帮助您完成后者。