Tcl：设置类中拥有的实例的私有变量

Question

假设有以下代码声明：

itcl::class ObjectA {
    private variable m_ownedObject
    private variable m_someVariable

   constructor {} \
   {
        set m_ownedObject [ObjectA #auto]
   }

   protected method SetSomeVariable {newVal} {
       set m_someVariable $newVal
   }

   public method SomeMethod{} {
       $m_ownedObject SetSomeVariable 5
   }
}

这是我知道如何从 m_ownedObject 上的 SomeMethod 内修改 m_someVariable 的唯一方法。在其他语言中（例如 C/C++/C#/Java 等），我很确定我可以这样说：

m_ownedObject.m_someVariable = 5

有没有办法在 tcl 中做这样的事情，或者我总是需要创建 protected getter 和 setter？希望这是相当清楚的。

Answer 1

您不能直接执行您在 itcl 中要求的操作。然而，这是 Tcl，您可以解决这个问题，并直接从任何地方设置成员变量。我使用一个名为 memv 的辅助例程，您可以传递一个实例和一个变量名，然后它返回对该变量的“引用”。

这显然绕过了 Itcl 设置的私有/受保护机制，因此使用它们违反了抽象。是否要使用它是您的决定。我发现它对于调试非常有用，但在生产代码中却不然。

示例用法是：

set [memv m_ownedObject m_someVariable] 5

memv 的代码是：

proc memv {obj varname} {
  # have to look up the variable, which might be in a base class
  # so do 'info variable' to get that, and the full name is the 3rd element

  # next two lines handle pulling apart an array
  set aindex ""
  regexp -- {^(.+)\((.+)\)$} $varname ignore varname aindex

  set var [lindex [$obj info variable $varname] 2]

  if {$aindex == ""} {
    return [list @itcl $obj $var]
  } else {
    return [list @itcl $obj $var\($aindex\)]
  }
}

同样，我有一个名为 memv 的辅助例程，它允许您调用任何方法（包括私有方法和受保护方法）。它的用法类似

[memf m_ownedObject SetSomeVariable] 5

，它的代码是：

proc memf {obj fcnname} {
  set f [$obj info function $fcnname]
  if {[llength $f] != 5} {
    error "expected '$obj info function $fcnname' to return something like 'private proc ::namespace::name args {...}' but got: $f"
  }
  set fullname [lindex [$obj info function $fcnname] 2]
  set namespace [namespace qualifiers $fullname]
  set function [namespace tail $fullname]
  return [itcl::code -namespace $namespace $obj $function]
}

Answer 2

$m_ownedObject configure -m_someVariable 5

Answer 3

如果您将变量声明为私有，则意味着只能从类内部访问该变量。这对于 C/C++/Java 也有效......所以我不确定你在期待什么。

无论如何，Tcl 是一种动态语言，所以你可以做类似的事情。

  itcl::class tclass {
      foreach v {time distance} {
        method get$v {} [subst -nocommands { return [subst $v] }]
        method set$v nuval [subst -nocommands { set $v \$nuval } ]
        protected variable $v "Var $v"
      }
  }

它将创建您需要的所有 getters 和 setters ;)

您可以在此处找到更多信息：http://wiki.tcl.tk/17667