如何避免调用 Application.CreateForm 两次？

Question

我偶然发现了这个页面为什么我不应该调用Application.CreateForm。 现在我有一些这样的代码：

SplashForm := TSplashForm.Create(Application);
SplashForm.Show;
SplashForm.Update; // force update
Application.Initialize;
Application.CreateForm(TClientData, ClientData);
SplashForm.Update; // force update
Application.CreateForm(TClientMainForm, ClientMainForm);
Application.ShowHint := True;

Application.Run;
ClientMainForm.ServerConnected := false;
FreeAndNil(ClientMainForm);
FreeAndNil(ClientData);

首先创建一个启动表单，然后创建一个数据模块，最后创建主表单。该页面指出 Application.CreateForm 不应被调用两次。上面的代码应该修改吗？

Answer 1

多次使用Application.CreateForm并没有什么问题。但这会为每个表单引入全局变量，这可能会产生代码味道。
不幸的是，IDE 为每个表单创建一个。尽管您可以根据需要删除它们。

更好的方法是在需要时创建表单，并在准备好时释放它。所以你只使用Application.CreateForm作为主窗体。

主表单可以创建主数据模块。但它也可以是全球性的，只是品味问题。

因此，要回答这个问题，您可以通过在本地创建和释放表单来避免 Application.CreateForm 。

文章提到了Application.CreateForm的副作用（第一个完成的表单是主表单）。
因此，如果主窗体使用 Application.CreateForm 创建其他窗体，可能会产生意想不到的副作用。

因此，为了避免任何麻烦，您应该将自己限制为一次调用。这是仅使用一种全局形式来完成的。

Answer 2

如果 TClientData 是一个数据模块并且 TClientMainForm 是一个表单，那么就不需要（除了最后的两个 FreeAndNil 调用 - 并不是真正需要的）。但要小心。因为正如 Rob Kennedy 在他的文章中所说，Application.CreateForm 会在后面执行其他操作（它设置 MainForm 变量），所以我建议根据以下规则设置项目文件：

1. < p>使用对 Application.CreateForm 的单次调用来创建您想要在启动时创建的所有表单 - 通常这由 IDE 完成。

2. 从项目文件中删除您想要在程序中动态（按需）创建的表单。 （在项目 | 选项 | 表单...） - 将它们从“自动创建表单”移动到“可用表单”

3. 使用 TmyForm.Create( 在您的代码中创建表单所有者）（等等），并且不使用Application.CreateForm(...)。顺便说一句，如果您确定将释放表单，那么最好（为了加快速度）调用 TmyForm.Create(nil) - 没有任何所有者。

4. 如果您想在启动时进行某种初始化，您可以在项目文件中将一个过程/方法绑定到已创建的表单/数据模块，并在应用程序运行之前运行它。

例如：

begin 
  Application.Initialize; 
  Application.MainFormOnTaskbar := True; 
  Application.CreateForm(TdmoMain, dmoMain); //<--this is a data module
  Application.CreateForm(TfrmMain, frmMain); //<--this will became the main form
  Application.CreateForm(TfrmAbout, frmAbout);
  //... other forms created here...
  frmMain.InitEngine; //<--initialization code. You can put somewhere else, according with your app architecture
  Application.Run;
end.

通过这种方式，您将清理项目文件，并且您将确切地知道哪个是哪个。

华泰

Answer 3

当我写那篇文章时，我主要考虑的是 DPR 文件之外的代码。人们在 DPR 文件中看到 IDE 生成的表单创建代码，并认为这是创建表单的最佳方式，因此他们在程序的其他地方使用它。他们有时在主窗体的 OnCreate 事件处理程序中使用它来创建程序所需的其他窗体，然后他们会遇到问题，因为程序的主窗体不是他们想象的那样。

在您提供的代码中，只需调用一次 CreateForm 就很容易。将其用于主窗体，而不用于其他用途。数据模块不是主窗体，因此您不需要 CreateForm 的魔力。

SplashForm := TSplashForm.Create(Application);
SplashForm.Show;
SplashForm.Update; // force update
Application.Initialize;

// Change to this.
ClientData := TClientData.Create(Application);

SplashForm.Update; // force update
Application.CreateForm(TClientMainForm, ClientMainForm);
Application.ShowHint := True;

Application.Run;
ClientMainForm.ServerConnected := false;

// Remove these.
FreeAndNil(ClientMainForm);
FreeAndNil(ClientData);

您确实不应该释放您在此处创建的对象，因为您不拥有它们。它们由全局 Application 对象拥有，因此让它负责释放它们：删除对 FreeAndNil 的两个调用。

Answer 4

您引用的文章不正确。您希望多次调用 Application.CreateForm 的原因有很多。

1) 数据模块：您可能希望这些模块始终可用。最好的方法是Application.CreateForm。我知道有一些应用程序具有多个主题数据模块，例如客户、发票、地址，用于处理数据库和数据库的不同区域。整齐地封装功能。所有这些都是在 .dpr 中创建的

2) 大的、加载缓慢的东西（这本身就是一个坏主意，但这些事情发生并且经常被支持程序员继承......）。将加载时间移至应用程序启动中，就像示例代码以及闪屏更新一样。用户期望应用程序需要一段时间才能运行，这要归功于我们从事 Microsoft Office 工作的同事们做出的巨大努力，以降低我们其他人的期望标准:)

因此，总而言之，不要'不用担心你的代码没问题 - 但你可能会丢失“FreeAndNil”的东西。然而，小型快速点击对话框类型的内容最好通过以下方式调用：

with TMyform.Create(nil) do
try
  //Setup
  case ShowModal of
    // Whatever return values you care about (if any)
  end;
finally
  Free;
end;

简短、甜蜜、切中要点和内容。最大限度地减少内存使用...