使用antlr解析|分离的文件

Question

所以我认为这应该很容易，但我遇到了困难。我正在尝试解析 |分隔文件以及任何不以 | 开头的行是一条评论。我想我不明白评论是如何运作的。它总是在注释行出错。这是旧文件，因此无需更改。这是我的语法。

grammar Route;

@header {
package org.benheath.codegeneration;
}

@lexer::header {
package org.benheath.codegeneration;
}

file: line+;
line: route+ '\n';
route: ('|' elt) {System.out.println("element: [" + $elt.text + "]");} ;
elt: (ELEMENT)*;

COMMENT: ~'|' .* '\n' ;
ELEMENT: ('a'..'z'|'A'..'Z'|'0'..'9'|'*'|'_'|'@'|'#') ;
WS: (' '|'\t') {$channel=HIDDEN;} ; // ignore whitespace

数据：

! a comment
Another comment
| a | abc | b | def | ...

Answer 1

其语法如下所示：

parse
  :  line* EOF   
  ;

line
  :  ( comment | values ) ( NL | EOF )
  ;

comment
  :  ELEMENT+
  ;

values
  :  PIPE ( ELEMENT PIPE )+
  ;

PIPE
  :  '|'    
  ;

ELEMENT
  :  ('a'..'z')+
  ;

NL
  :  '\r'? '\n' |  '\r' 
  ;

WS
  :  (' '|'\t') {$channel=HIDDEN;} 
  ;

要测试它，您只需在语法中添加一些代码，如下所示：

grammar Route;

@members {
  List<List<String>> values = new ArrayList<List<String>>();
}

parse
  :  line* EOF   
  ;

line
  :  ( comment | v=values {values.add($v.line);} ) ( NL | EOF )
  ;

comment
  :  ELEMENT+
  ;

values returns [List<String> line]
@init {line = new ArrayList<String>();}
  :  PIPE ( e=ELEMENT {line.add($e.text);} PIPE )*
  ;

PIPE
  :  '|'    
  ;

ELEMENT
  :  ('a'..'z')+
  ;

NL
  :  '\r'? '\n' |  '\r' 
  ;

WS
  :  (' '|'\t') {$channel=HIDDEN;} 
  ;

现在通过调用生成词法分析器/解析器：

java -cp antlr-3.2.jar org.antlr.Tool Route.g

创建一个类 RouteTest.java：

import org.antlr.runtime.*;
import java.util.List;

public class RouteTest {
  public static void main(String[] args) throws Exception {
    String data = 
        "a comment\n"+
        "| xxxxx | y |     zzz   |\n"+
        "another comment\n"+
        "| a | abc | b | def |";
    ANTLRStringStream in = new ANTLRStringStream(data);
    RouteLexer lexer = new RouteLexer(in);
    CommonTokenStream tokens = new CommonTokenStream(lexer);
    RouteParser parser = new RouteParser(tokens);
    parser.parse();
    for(List<String> line : parser.values) {
      System.out.println(line);
    }
  }
}

编译所有源文件：

javac -cp antlr-3.2.jar *.java

并运行类 RouteTest：

// Windows
java -cp .;antlr-3.2.jar RouteTest

// *nix/MacOS
java -cp .:antlr-3.2.jar RouteTest

如果一切顺利，您会看到打印到控制台：

[xxxxx, y, zzz]
[a, abc, b, def]

编辑：请注意，我通过只允许小写字母来简化它，您当然可以随时扩展集合。

Answer 2

使用 ANTLR 来完成这样的工作是一个好主意，尽管我确实认为这是多余的。例如，这将非常容易（在伪代码中）：

for each line in file:
if line begins with '|':
    fields = /|\s*([a-z]+)\s*/g

编辑：好吧，您无法词汇表达注释和行之间的区别，因为没有任何词汇可以区分它们。一个让你朝着一个可行的方向前进的提示。

line: comment | fields;
comment: NONBAR+ (BAR|NONBAR+) '\n';
fields = (BAR NONBAR)+;

Answer 3

这似乎有效，我发誓我尝试过。将注释更改为小写将其切换到解析器与词法分析器，我仍然不明白。

grammar Route;

@header {
    package org.benheath.codegeneration;
}

@lexer::header {
    package org.benheath.codegeneration;
}

file: (line|comment)+;
line: route+ '\n';
route: ('|' elt) {System.out.println("element: [" + $elt.text + "]");} ;
elt: (ELEMENT)*;

comment : ~'|' .* '\n';

ELEMENT: ('a'..'z'|'A'..'Z'|'0'..'9'|'*'|'_'|'@'|'#') ;
WS: (' '|'\t') {$channel=HIDDEN;} ; // ignore whitespace