如何让 TStringList 在 Delphi 中以不同方式排序

Question

我有一个简单的 TStringList。我对其进行了 TStringList.Sort 操作。

然后我注意到下划线“_”排在大写字母“A”之前。这与对相同文本进行排序并在 A 之后排序 _ 的第三方包形成鲜明对比。

根据 ANSI 字符集，AZ 是字符 65 - 90，而 _ 是 95。所以看起来第 3 方包正在使用它order 而 TStringList.Sort 不是。

我深入研究了 TStringList.Sort 的内部结构，它使用 AnsiCompareStr（区分大小写）或 AnsiCompareText（不区分大小写）进行排序。我尝试了两种方法，将 StringList 的 CaseSensitive 值设置为 true，然后设置为 false。但在这两种情况下，“_”都会先排序。

我只是无法想象这是 TStringList 中的错误。所以这里一定还有其他我没有看到的东西。那可能是什么？

我真正需要知道的是如何让我的 TStringList 进行排序，以便它与其他包的顺序相同。

作为参考，我正在使用 Delphi 2009，并且在程序中使用 Unicode 字符串。

---

因此，这里的最终答案是用您想要的任何内容（例如非 ansi 比较）覆盖 Ansi 比较，如下所示：

type
  TMyStringList = class(TStringList)
  protected
    function CompareStrings(const S1, S2: string): Integer; override;
  end;

function TMyStringList.CompareStrings(const S1, S2: string): Integer;
begin
  if CaseSensitive then
    Result := CompareStr(S1, S2)
  else
    Result := CompareText(S1, S2);
end;

Answer 1

定义“正确”。
i18n 排序完全取决于您的区域设置。
所以我完全同意 PA 这不是一个错误：默认的 Sort 行为的工作方式如下旨在让 i18n 正常工作。

就像 Gerry 提到的那样，TStringList.Sort 使用 AnsiCompareStr 和 >AnsiCompareText（我将用几行解释它是如何做到这一点的）。

但是：TStringList很灵活，它包含Sort、CustomSort和CompareStrings，它们都是虚拟的（因此您可以在后代类中重写它们）
此外，当您调用CustomSort时，您可以插入自己的Compare函数。

在这个答案的最后是一个 Compare 函数，可以执行您想要的操作：

• 区分大小写
• 不使用任何区域
• 设置只需比较字符串字符的序数值

CustomSort 定义为this：

procedure TStringList.CustomSort(Compare: TStringListSortCompare);
begin
  if not Sorted and (FCount > 1) then
  begin
    Changing;
    QuickSort(0, FCount - 1, Compare);
    Changed;
  end;
end;

默认情况下，Sort方法有一个非常简单的实现，传递一个名为StringListCompareStrings的默认Compare函数：

procedure TStringList.Sort;
begin
  CustomSort(StringListCompareStrings);
end;

因此，如果您定义自己的TStringListSortCompare 兼容 Compare 方法，然后您可以定义自己的排序。
TStringListSortCompare 被定义为一个全局函数，采用 TStringList 和两个索引来引用您想要比较的项目：

type
  TStringListSortCompare = function(List: TStringList; Index1, Index2: Integer): Integer;

您可以使用 StringListCompareStrings 作为实现您自己的指南：

function StringListCompareStrings(List: TStringList; Index1, Index2: Integer): Integer;
begin
  Result := List.CompareStrings(List.FList^[Index1].FString,
                                List.FList^[Index2].FString);
end;

因此，默认情况下 TStringList.Sort 遵循TList.CompareStrings：

function TStringList.CompareStrings(const S1, S2: string): Integer;
begin
  if CaseSensitive then
    Result := AnsiCompareStr(S1, S2)
  else
    Result := AnsiCompareText(S1, S2);
end;

然后使用底层 Windows API 函数 CompareString 使用默认用户区域设置 LOCALE_USER_DEFAULT ：

function AnsiCompareStr(const S1, S2: string): Integer;
begin
  Result := CompareString(LOCALE_USER_DEFAULT, 0, PChar(S1), Length(S1),
    PChar(S2), Length(S2)) - 2;
end;

function AnsiCompareText(const S1, S2: string): Integer;
begin
  Result := CompareString(LOCALE_USER_DEFAULT, NORM_IGNORECASE, PChar(S1),
    Length(S1), PChar(S2), Length(S2)) - 2;
end;

终于有了你需要的比较功能。再次强调限制：

• 区分大小写
• 不使用任何语言环境
• 只需比较字符串字符的序数值

这是代码：

function StringListCompareStringsByOrdinalCharacterValue(List: TStringList; Index1, Index2: Integer): Integer;
var
  First: string;
  Second: string;
begin
  First := List[Index1];
  Second := List[Index2];
  if List.CaseSensitive then
    Result := CompareStr(First, Second)
  else
    Result := CompareText(First, Second);
end;

Delphi 不是封闭的，恰恰相反：通常它是一个非常灵活的体系结构。
通常只需进行一些挖掘即可了解可以在哪里发挥这种灵活性。

——杰罗恩

Answer 2

AnsiCompareStr / AnsiCompareText 考虑的不仅仅是字符数。他们考虑了用户的区域设置，因此“e”将与“é”、“ê”等一起排序。

要使其按 Ascii 顺序排序，请使用自定义比较函数 如此处所述

Answer 3

AnsiCompareStr（与 LOCALE_USER_DEFAULT 比较字符串）有错误，因为它获取标点符号相等的字符：

e1
é1
e2
é2

正确的顺序是（例如捷克语）：

e1
e2
é1
é2

有谁知道如何避免订购时出现此错误？

---

11.2.2010：我必须道歉，所描述的行为完全符合语言规则。虽然我认为这是愚蠢和“糟糕”的，但这并不是 API 函数中的错误。

Windows XP 中的资源管理器使用所谓的直观文件名排序，可以提供更好的结果，但不能以编程方式使用。