从右边填充一个HBox？ VBox 从底部开始？

Question

我真的只需要 HBox 答案，但我想如果我们在这里得到一个好的答案，它将帮助任何尝试使用 VBox 做类似事情的人。如果能在 ActionScript 和 MXML 中了解这一点就好了。

所以我有一个 HBox，我想要一些文本从左侧对齐，一些收音机从右侧对齐。像这样：

 ___________________________________________________
|                                                   |
|Text                                Yes ()  No()   |
|___________________________________________________|

我目前正在通过在文本和收音机之间设置一个宽度为 100% 的隐形框来做到这一点，就像这样，

 _____ __________________________________ ________________
|     |                                  |                |
|Text | invisible box  percentWidth=100; | Yes ()  No()   |
|_____|__________________________________|________________|

我更愿意将收音机放在自己的 HBox 中，这样右对齐：

 _____ ________________________________________________________
|     |                                                        |
|Text |                                         Yes ()  No()   |
|_____|________________________________________________________|

我已经看到一些帖子讨论了 Horizo​​ntalAlign 属性，但我在任何地方的文档中都没有看到它。

那么我怎样才能做到这一点呢？

谢谢 〜迈克

Answer 1

VBox 和 HBox 组件（继承自 Box）上有一个 horizo​​ntalAlign 属性和一个 verticalAlign 属性。它们确定组件子组件的水平和垂直对齐方式。

我通常使用 Spacer 对象，就像 Sam 提到的那样。但对于你想做的事情来说，这会很有用。

在 MXML 中，您可以执行以下操作：

<mx:RadioButtonGroup id="yesNoRadioGroup"/>

<mx:HBox id="containingHBox" width="100%">
    <mx:Text id="textElement" width="200" text="lakdfa lkadslkjraklnd kadflk lakdsjlkja lksdlkjdflk jalkdlkjdfslksajdf lkjasdflkjdsalkjds lksdjlkj"/>
    <mx:HBox id="rightAlignedHorizontalContent" width="100%" horizontalAlign="right">
        <mx:RadioButton id="yesRadio" label="Yes" groupName="yesNoRadioGroup"/>
        <mx:RadioButton id="noRadio" label="No" groupName ="yesNoRadioGroup"/>
    </mx:HBox>
</mx:HBox>

请注意，具有水平对齐设置的 HBox 必须具有宽度值，否则，它的宽度将仅足以容纳其子项的宽度，在这种情况下对齐毫无意义。

这是一个 AS 版本：

<mx:Script>
    <![CDATA[
        import mx.controls.RadioButton;
        import mx.controls.RadioButtonGroup;
        import mx.controls.Text;

        private var containingHBox:HBox;
        private var textElement:Text;
        private var rightAlignedHorizontalContent:HBox;
        private var yesNoRadioGroup:RadioButtonGroup; 
        private var yesRadio:RadioButton;
        private var noRadio:RadioButton;

        override protected function createChildren():void
        {
            super.createChildren();

            containingHBox = new HBox();
            containingHBox.percentWidth = 100;

            textElement = new Text();
            textElement.width = 200;
            textElement.text = "lakdfa lkadslkjraklnd kadflk lakdsjlkja lksdlkjdflk jalkdlkjdfslksajdf lkjasdflkjdsalkjds lksdjlkj";

            rightAlignedHorizontalContent = new HBox();
            rightAlignedHorizontalContent.percentWidth = 100;
            rightAlignedHorizontalContent.setStyle("horizontalAlign","right");

            yesNoRadioGroup = new RadioButtonGroup();

            yesRadio = new RadioButton();
            yesRadio.label = "Yes";
            yesRadio.groupName = "yesNoRadioGroup";

            noRadio = new RadioButton();
            noRadio.label = "No";
            noRadio.groupName = "yesNoRadioGroup";


            addChild(containingHBox);

            containingHBox.addChild(textElement);
            containingHBox.addChild(rightAlignedHorizontalContent);

            rightAlignedHorizontalContent.addChild(yesRadio);
            rightAlignedHorizontalContent.addChild(noRadio);
        }
    ]]>
</mx:Script>

Answer 2

如果您已经在布局中使用 HBox/VBox，那么使用 Spacer 是将某些项目一直移动到右侧/底部的正确方法。

另一种方法是基于约束的布局。当您想要将内容锚定到左侧时，这很好，您可以使用画布作为父级，并在子级上设置“right='0'”以将其一直定位到右侧。当您根据大小堆叠多个物品时，这不太理想。您可以使用绑定“right='{noComponent.width}”将 Yes 放在 No 的右侧。