Groovy 中静态闭包的访问值

Question

我想将一些属性存储在静态闭包中，然后在方法调用期间访问它们：

class Person {  
static someMap = { key1: "value1", key2: "value2" }  
}

那么如何在 Person 中编写一个方法来检索此存储的数据呢？

Answer 1

对于简单的情况，您最好使用地图。

如果您确实想将其作为闭包进行评估（可能是为了创建您自己的 DSL），那么您需要像 John 指出的那样稍微更改您的语法。这是一种使用 Builder 类来评估传递给构建器的内容中的“某物”闭包的方法。

它使用常规元编程来拦截缺少方法/属性的调用并将其保存下来：

class SomethingBuilder {
    Map valueMap = [:]

    SomethingBuilder(object) {
        def callable = object.something
        callable.delegate = this
        callable.resolveStrategy = Closure.DELEGATE_FIRST
        callable()
    }

    def propertyMissing(String name) {
        return valueMap[name]
    }

    def propertyMissing(String name, value) {
        valueMap[name] = value
    }

    def methodMissing(String name, args) {
        if (args.size() == 1) {
            valueMap[name] = args[0]
        } else {
            valueMap[name] = args
        }
    }
}

class Person {
    static something = {
        key1 "value1"              // calls methodMissing("key1", ["value1"])
        key2("value2")             // calls methodMissing("key2", ["value2"])
        key3 = "value3"            // calls propertyMissing("key3", "value3")
        key4 "foo", "bar", "baz"   // calls methodMissing("key4", ["foo","bar","baz"])
    }
}

def builder = new SomethingBuilder(new Person())

assert "value1" == builder."key1"  // calls propertyMissing("key1")
assert "value2" == builder."key2"  // calls propertyMissing("key2")
assert "value3" == builder."key3"  // calls propertyMissing("key3")
assert ["foo", "bar", "baz"] == builder."key4"  // calls propertyMissing("key4")

Answer 2

如果它们需要通过闭包而不是映射来初始化，那么就必须有人运行闭包才能拾取并记录设置的值。

你的语法无效。请记住，闭包只是匿名方法。您的语法看起来像是在尝试定义一个映射，但闭包需要调用方法、设置变量或返回映射。例如，

static someClosure = { key1 = "value1"; key2 = "value2" } // set variables
static someClosure = { key1 "value1"; key2 = "value2" } // call methods
static someClosure = { [key1: "value1", key2: "value2"] } // return a map

当然，无论是谁运行闭包，都需要有正确的元编程来记录结果。

听起来您真正想要的只是定义一张地图。

static someMap = [key1: "value1", key2: "value2"]

Answer 3

这是我想出的来提取静态闭包属性的方法：

class ClosureProps {

       Map props = [:]  
       ClosureProps(Closure c) {  
           c.delegate = this  
           c.each{"$it"()}  
       }  
       def methodMissing(String name, args) {  
           props[name] = args.collect{it}  
       }  
       def propertyMissing(String name) {  
           name  
       }  
}  

// Example  
class Team {

        static schema = {  
            table team  
            id teamID  
            roster column:playerID, cascade:[update,delete]  
        }  
}  
def c = new ClosureProps(Team.schema)  
println c.props.table