Perl 的触发器运算符有问题吗？它具有全局状态，我如何重置它？

Question

我很沮丧。好吧，这可能是最有趣 Perl 我发现过的错误。即使今天我仍在学习有关 Perl 的新知识。本质上，触发器运算符 .. 返回 false，直到左侧返回 true，然后返回 true< /em> 直到右侧返回 false 保持全局状态（或者这就是我的假设。）

我可以重置它吗（也许这对 Perl 4-esque 来说是一个很好的补充曾经使用过reset())？或者说，没有办法安全地使用这个算子吗？

我也没有在 perldoc perlop 中的任何地方看到这个（全局上下文位）记录，这是一个错误吗？

代码

use feature ':5.10';
use strict;
use warnings;

sub search {
    my $arr = shift;
    grep { !( /start/ .. /never_exist/ ) } @$arr;
}

my @foo = qw/foo bar start baz end quz quz/;
my @bar = qw/foo bar start baz end quz quz/;

say 'first shot - foo';
say for search \@foo;

say 'second shot - bar';
say for search \@bar;

---

剧透

$ perl test.pl
first shot
foo
bar
second shot

Answer 1

有人可以澄清文档的问题是什么吗？它清楚地表明：

Each ".." operator maintains its own boolean state.

“每个”的含义有些模糊，但我认为复杂的解释不会很好地服务于文档。

请注意，Perl 的其他迭代器（each 或标量上下文 glob）可能会导致相同的问题。由于 each 的状态绑定到特定的哈希值，而不是特定的代码位，因此可以通过调用（即使在 void 上下文中）keys< 来重置 each /code> 上的哈希值。但对于 glob 或 .. 来说，除了调用迭代器直到重置之外，没有可用的重置机制。示例 glob bug：

sub globme {
    print "globbing $_[0]:\n";
    print "got: ".glob("{$_[0]}")."\n" for 1..2;
}
globme("a,b,c");
globme("d,e,f");
__END__
globbing a,b,c:
got: a
got: b
globbing d,e,f:
got: c
Use of uninitialized value in concatenation (.) or string at - line 3.
got: 

对于过于好奇的人，这里有一些示例，其中源中的相同 .. 是不同 .. 运算符：

单独的闭包：

sub make_closure {
    my $x;
    return sub {
        $x if 0;  # Look, ma, I'm a closure
        scalar( $^O..!$^O ); # handy values of true..false that don't trigger ..'s implicit comparison to $.
    }
}
print make_closure()->(), make_closure()->();
__END__
11

注释掉 < code>$x if 0 行可以看到非闭包有一个由所有“副本”共享的单个 .. 操作，输出为 12。

线程：

use threads;
sub coderef { sub { scalar( $^O..!$^O ) } }
coderef()->();
print threads->create( coderef() )->join(), threads->create( coderef() )->join();
__END__
22

线程代码以线程创建之前的任何状态开始，但线程中对其状态的更改不会影响其他任何内容。

递归：

sub flopme {
    my $recurse = $_[0];
    flopme($recurse-1) if $recurse;
    print " "x$recurse, scalar( $^O..!$^O ), "\n";
    flopme($recurse-1) if $recurse;
}
flopme(2)
__END__
1
 1
2
  1
3
 2
4

每个递归深度都是一个单独的 .. 运算符。

Answer 2

诀窍是不使用相同的 触发器 所以你没有状态担心。只需创建一个生成器函数即可为您提供一个带有新触发器的新子例程，您只需使用一次：

sub make_search {
    my( $left, $right ) = @_;
    sub {
        grep { !( /\Q$left\E/ .. /\Q$right\E/ ) } @{$_[0]};
        }
}

my $search_sub1 = make_search( 'start', 'never_existed' );
my $search_sub2 = make_search( 'start', 'never_existed' );


my @foo = qw/foo bar start baz end quz quz/;

my $count1 = $search_sub1->( \@foo );
my $count2 = $search_sub2->( \@foo );

print "count1 $count1 and count2 $count2\n";

我也在 制作独占触发器运算符。

Answer 3

“范围运算符”.. 记录在 perlop 下的“范围运算符”。查看文档，似乎没有任何方法可以重置 .. 运算符的状态。 .. 运算符的每个实例都保持其自己 状态，这意味着没有任何方法可以引用任何特定 .. 的状态> 运算符。

看起来它是为非常小的脚本设计的，例如：

if (101 .. 200) { print; }

文档指出这是 的缩写 不知

if ($. == 101 .. $. == 200) { print; }

怎的，其中隐含了 $. 的使用（toolic 在注释中指出这也已记录在案）。这个想法似乎是这个循环在 Perl 解释器的给定实例中运行一次（直到$.== 200），因此您无需担心关于重置 .. 触发器的状态。

由于您已经确定的原因，此运算符在更一般的可重用上下文中似乎不太有用。

Answer 4

针对您的特定情况的解决方法/黑客/作弊是将最终值附加到数组中：

sub search { 
  my $arr = shift;
  grep { !( /start/ .. /never_exist/ ) } @$arr, 'never_exist';
} 

这将保证范围运算符的 RHS 最终为真。

当然，这绝不是一个通用的解决方案。

在我看来，这种行为没有明确记录。如果您可以构建清晰的解释，则可以通过 perlbug 对 perlop.pod 应用补丁。

Answer 5

我发现了这个问题，据我所知没有办法解决它。结果是 - 不要在函数中使用 .. 运算符，除非您确定在离开函数时将其保留在 false 状态，否则该函数可能会为相同的内容返回不同的输出输入（或对同一输入表现出不同的行为）。

Answer 6

每次使用 .. 运算符都会维护自己的状态。就像 Alex Brown 所说，当你离开该函数时，你需要将其保留在 false 状态。也许你可以这样做：

sub search {
  my $arr = shift;
  grep { !( /start/ || $_ eq "my magic reset string" ..
            /never_exist/ || $_ eq "my magic reset string" ) } 
      (@$arr, "my magic reset string");
}