如何将参数传递给处理每个文件的 File::Find 子例程？

Question

使用File::Find，如何我将参数传递给处理每个文件的函数？

我有一个 Perl 脚本，它遍历目录，以便将一些 3 通道 TIFF 文件转换为 JPEG 文件（每个 TIFF 文件 3 个 JPEG 文件）。这是可行的，但我想将一些参数传递给处理每个文件的函数（不使用全局变量）。

这是我尝试传递参数的脚本的相关部分：

use File::Find;

sub findFiles
{
    my $IsDryRun2 = ${$_[0]}{anInIsDryRun2};
}

find ( { wanted => \&findFiles, anInIsDryRun2 => $isDryRun }, $startDir);

$isDryRun 是一个标量。 $startDir 是一个字符串，目录的完整路径。

$IsDryRun2 未设置：

在串联 (.) 或字符串中使用未初始化值 $IsDryRun2 TIFFconvert.pl 第 197 行 (#1) (W uninitialized) 使用未定义的值，就好像它已经存在一样 定义的。它被解释为“”或 0，但也许这是一个错误。 要抑制此警告，请为您的变量分配一个定义的值。

（不带参数的旧调用是： find ( \&findFiles, $startDir); ）

---

测试平台（但生产环境将是 Linux 机器，Ubuntu 9.1，Perl 5.10，64 位）： ActiveState Perl 64 位。 Windows XP。来自 perl -v：为 ActiveState 提供的 MSWin32-x64-多线程二进制版本 1004 [287188] 构建的 v5.10.0。

Answer 1

您需要创建一个子引用，用所需的参数调用您想要的子引用：

find( 
  sub { 
    findFiles({ anInIsDryRun2 => $isDryRun });
  },
  $startDir
);

这或多或少是柯里化。它只是不太柯里化。 :)

Answer 2

您可以创建您喜欢的任何类型的代码参考。您不必使用对命名子例程的引用。有关如何执行此操作的许多示例，请参阅我的 File::Find::Closures 模块。我创建该模块来准确回答这个问题。

Answer 3

请参阅 PerlMonks 条目为什么我讨厌 File::Find 以及我（希望我）如何修复它 描述如何使用闭包来做到这一点。

Answer 4

#
# -----------------------------------------------------------------------------
# Read directory recursively and return only the files matching the regex
# for the file extension. Example: Get all the .pl or .pm files:
#     my $arrRefTxtFiles = $objFH->doReadDirGetFilesByExtension ($dir, 'pl|pm')
# -----------------------------------------------------------------------------
sub doReadDirGetFilesByExtension {
     my $self = shift;    # Remove this if you are not calling OO style
     my $dir  = shift;
     my $ext  = shift;

     my @arr_files = ();
     # File::find accepts ONLY single function call, without params, hence:
     find(wrapp_wanted_call(\&filter_file_with_ext, $ext, \@arr_files), $dir);
     return \@arr_files;
}

#
# -----------------------------------------------------------------------------
# Return only the file with the passed extensions
# -----------------------------------------------------------------------------
sub filter_file_with_ext {
    my $ext     = shift;
    my $arr_ref_files = shift;

    my $F = $File::Find::name;

    # Fill into the array behind the array reference any file matching
    # the ext regex.
    push @$arr_ref_files, $F if (-f $F and $F =~ /^.*\.$ext$/);
}

#
# -----------------------------------------------------------------------------
# The wrapper around the wanted function
# -----------------------------------------------------------------------------
sub wrapp_wanted_call {
    my ($function, $param1, $param2) = @_;

    sub {
      $function->($param1, $param2);
    }
}