使用VBA查找Windows中安装的MySQL ODBC驱动程序的版本

Question

使用 Visual Basic for Applications，如何查明用户计算机上的 Windows 中安装了哪个版本的 MySQL ODBC 驱动程序？

我有一个 Microsoft Access 应用程序，它使用 MySQL ODBC 驱动程序进行连接。连接字符串如下所示：

ODBC;DATABASE=mydatabase;DRIVER={MySQL ODBC 3.51 Driver};
    OPTION=3;PWD=password;PORT=3306;SERVER=server-db;UID=db-user;

这是工作查找，直到 IT 经理在用户 PC 上安装了 5.1 版 MySQL ODBC 驱动程序，这破坏了我的连接字符串。

如果我知道用户的 Windows XP 安装上安装的驱动程序版本，我可以在运行时将其插入到连接字符串中。 如何使用 VBA 查明用户计算机上的 Windows 中安装了哪个版本的 MySQL ODBC 驱动程序？

Answer 1

您可以在注册表中

HKEY_LOCAL_MACHINE\SOFTWARE\
    ODBC\ODBCINST.INI\
    ODBC Drivers\MySQL ODBC 3.51 Driver


 HKEY_LOCAL_MACHINE\SOFTWARE\
    ODBC\ODBCINST.INI\
    ODBC Drivers\MySQL ODBC 5.1 Driver

使用此处找到的信息找到它，您可以获取它使用下面的代码（我在Access 97中测试过）

Private Sub Command0_Click()    
    If RegKeyExists("HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBCINST.INI\
                                 ODBC Drivers\MySQL ODBC 3.51 Driver") Then
        MsgBox "3.51"
    ElseIf RegKeyExists("HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBCINST.INI\
                                 ODBC Drivers\MySQL ODBC 5.1 Driver") Then
        MsgBox "5.1"
    Else
        MsgBox "None"
    End If
End Sub


'returns True if the registry key i_RegKey was found
'and False if not
Function RegKeyExists(i_RegKey As String) As Boolean
    Dim myWS As Object

    On Error GoTo ErrorHandler
    'access Windows scripting
    Set myWS = CreateObject("WScript.Shell")
    'try to read the registry key
    myWS.RegRead i_RegKey
    'key was found
    RegKeyExists = True
    Exit Function

ErrorHandler:
  'key was not found
  RegKeyExists = False
End Function

Answer 2

以下是一些可能的想法：

1 您可以检查注册表并查找特定键，例如： [HKEY_LOCAL_MACHINE\SOFTWARE\ODBC\ODBCINST.INI\MySQL ODBC 3.51 Driver]

2.您可以检查他们的 c :\windows\system32文件夹下找到myodbc.dll，然后查看版本信息。这是有关如何检查版本的链接：
http://www.vb-helper.com/howto_file_version_info.html

Answer 3

如果您想避免根据具体情况处理版本，您可以迭代键值，例如..

此函数旨在枚举 ODBC 驱动程序的注册表键，并仅检查某处是否存在 mysql，如果不存在，它将警告用户，然后将他们带到下载页面，并提醒他们获取适合其架构的正确版本 (32/64)

Public Function CheckMySQL()

    Dim arrEntryNames()
    Dim arrValueTypes()
    Dim rPath As String
    rPath = "SOFTWARE\ODBC\ODBCINST.INI\ODBC Drivers"

    Call EnumerateRegEntries(rPath, arrEntryNames, arrValueTypes)

    If Not IsEmpty(arrEntryNames) Then
        For Each strAsk In arrEntryNames
            If (InStr(strAsk, "MySQL")) Then
                strFound = strFound & strAsk & ", "
            End If
        Next
    End If

    If (Len(strFound) = 0) Then
        #If Win64 Then
            MsgBox "You need MySQL Driver *64 bit* - Press OK to get it!"
        #Else
            MsgBox "You need MySQL Driver *32 bit* - Press OK to get it!"
        #End If

        ActiveWorkbook.FollowHyperlink Address:="http://goo.gl/vbm6g", NewWindow:=True

        CheckMySQL = False
    Else
        CheckMySQL = True
    End If

End Function

并且您将需要它来枚举注册表项（有关更多信息，请参阅 http://technet.microsoft.com/en-us/library/ee176771.aspx）：

Public Sub EnumerateRegEntries(strKeyPath, arrEntryNames, arrValueTypes)
    Const HKEY_CLASSES_ROOT = &H80000000&
    Const HKEY_CURRENT_USER = &H80000001&
    Const HKEY_LOCAL_MACHINE = &H80000002&
    Const HKEY_USERS = &H80000003&
    Const HKEY_CURRENT_CONFIG = &H80000005&

    Dim objReg As Object
    Dim strComputer As String

    strComputer = "."
    Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
    strComputer & "\root\default:StdRegProv")

    objReg.EnumValues HKEY_LOCAL_MACHINE, strKeyPath, arrEntryNames, arrValueTypes


End Sub