如何防止 RemoteObject 将 AMF 消息批量处理在一起？

Question

我正在使用 Google AppEngine 与 PyAMF 结合来提供 RemoteObject 支持。在我的 Flex 代码中，我同时调用多个 RemoteObject 方法，这往往会将 AMF 消息批处理为单个 HTTP 请求。

大多数时候这很好，但 AppEngine 对每个请求应用一些严格的限制（在这种情况下，我遇到了 DeadlineExceededError - 最多 30 秒）。许多服务方法预计需要 10 秒以上，如果这些方法由 RemoteObject 批处理为 1 个 HTTP .. 您就会看到这是怎么回事。

现在您可以说重构您的服务调用，这也正在发生，但实际上并不是这里提出的问题。有没有办法防止 Flex RemoteObject 在这种情况下批量处理 AMF 请求？

我对这个主题进行了大量的谷歌搜索，并得出了一些结论。在我看来，我需要实现 mx.messaging.channels.AMFChannel 的自定义版本或类似性质的东西，这对于这样的功能来说似乎太核心了..

任何人都有任何指示/洞察力？

Answer 1

查看并发属性远程对象。

Answer 2

将 AMF 请求批处理为 HTTP 发生在 NetConnection 级别。因此，不幸的是，阻止 AMF 请求批处理的最佳方法是实现 mx.messaging.channels.AMFChannel。然而，这很容易做到，并且可能比排队请求并稍后调用它们更容易。

不要使用默认的 AMFChannel，而是使用以下方法：

package services
{
    import flash.events.AsyncErrorEvent;
    import flash.events.IOErrorEvent;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.net.NetConnection;

    import mx.messaging.MessageResponder;
    import mx.messaging.channels.AMFChannel;

    public class NonBatchingAMFChannel extends mx.messaging.channels.AMFChannel
    {
        public function NonBatchingAMFChannel(id:String = null, uri:String = null)
        {
            super(id, uri);
        }

        override protected function internalSend(msgResp:MessageResponder):void
        {
            // AMFChannel internalSend
            super.internalSend(msgResp);
            // Reset the net connection.
            _nc = new NetConnection();
            _nc.addEventListener(NetStatusEvent.NET_STATUS, statusHandler); 
            _nc.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler); 
            _nc.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler); 
            _nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler); 
            _nc.connect(this.url);
        }
    }
}

神奇的事情是通过重写internalSend 方法来实现的。运行超级internalSend方法（它将消息响应程序排队）后，我们将重置NetConnection及其所有事件处理程序。这将为下一个远程处理消息准备好新的 NetConnection。

笔记：
需要注意的是，这是一个自定义的非批处理 AMFChannel，如果您想安全地发送 AMF 消息，您需要复制此类并扩展 mx.messaging.channels.SecureAMFChannel 类。

信用：
感谢尼克·乔伊斯（Nick Joyce）在另一个论坛上回答了他的问题。

Answer 3

您可以创建一个连接池，并创建另一个触发连接的类。您的应用程序不建立连接，仅向池提供数据。

Answer 4

好吧，一种方法显然是推出自己的不使用 NetConnection 的 AMFChannel...我还没有尝试过，所以我不知道它的效果如何。
http://blogs.adobe.com/pfarland/2008/06/using_amf_with_flashneturlload.html

Answer 5

我认为 njoyce 喜欢做的就是阻止 AMF 批处理。这个即。对于多个小型调用很有用，但如果您有服务器密集型调用，则应阻止 AMF 批处理。为什么？

• 一次 AMF 调用 =>服务器端的一个线程
• 多个 AMF 调用 =>所有请求都通过多个线程处理

伪代码：

    private static var _collectionFillIndex:int;
    private static var _collectionsToFill:Array = [];

    public function doFillCollections():void {
        _collectionFillIndex = _collectionsToFill.length;
        Application.application.addEventListener( Event.ENTER_FRAME, onFrameEventHandler );
    }

    private function onFrameEventHandler( event:Event ):void {
        --_collectionFillIndex;
        if( _collectionFillIndex < 0 ) {
            Application.application.removeEventListener( Event.ENTER_FRAME, onFrameEventHandler );
            return;
        }
        _collectionsToFill[ _managerFillIndex ].fill();
    }