如何从 Perl 文件句柄中读取数组元素？

Question

我很快写下了一个 Perl 脚本，该脚本可以仅用数字列对几个文件进行平均。它涉及从文件句柄数组中读取。这是脚本：

#!/usr/local/bin/perl

use strict;
use warnings;

use Symbol;

die "Usage: $0 file1 [file2 ...]\n" unless scalar(@ARGV);

my @fhs;

foreach(@ARGV){
    my $fh = gensym;
    open $fh, $_ or die "Unable to open \"$_\"";
    push(@fhs, $fh);
}

while (scalar(@fhs)){
    my ($result, $n, $a, $i) = (0,0,0,0);
    while ($i <= $#fhs){
        if ($a = <$fhs[$i]>){
            $result += $a;
            $n++;
            $i++;
        }
        else{
            $fhs[$i]->close;
            splice(@fhs,$i,1);
        }
    }
    if ($n){ print $result/$n . "\n"; }
}

这不起作用。如果我调试脚本，在初始化 @fhs 后，它看起来像这样：

  DB<1> x @fhs
0  GLOB(0x10443d80)
   -> *Symbol::GEN0
         FileHandle({*Symbol::GEN0}) => fileno(6)
1  GLOB(0x10443e60)
   -> *Symbol::GEN1
         FileHandle({*Symbol::GEN1}) => fileno(7)

到目前为止，一切都很好。但它在我尝试从文件中读取的部分失败：

  DB<3> x $fhs[$i]
0  GLOB(0x10443d80)
   -> *Symbol::GEN0
         FileHandle({*Symbol::GEN0}) => fileno(6)
  DB<4> x $a
0  'GLOB(0x10443d80)'

$a 填充了这个字符串，而不是从 glob 中读取的内容。我做错了什么？

Answer 1

您只能在 <> 中使用简单的标量变量来读取文件句柄。 <$foo> 有效。 <$foo[0]> 不从文件句柄读取；它实际上相当于glob($foo[0])。您必须使用内置的 readline 临时变量，或使用 IO::File 和 OO 表示法。

$text = readline($foo[0]);
# or
my $fh = $foo[0];  $text = <$fh>;
# or
$text = $foo[0]->getline;  # If using IO::File

如果您没有从循环内的数组中删除元素，则可以通过将 while 循环更改为 foreach 循环来轻松使用临时变量。

就我个人而言，我认为使用 gensym 来创建文件句柄是一个丑陋的黑客行为。您应该使用 IO::File，或者将未定义的变量传递给 open （这至少需要 Perl 5.6.0，但现在已经有近 10 年历史了）。 （只需说 my $fh; 而不是 my $fh = gensym;，Perl 就会自动创建一个新的文件句柄并将其存储在 $fh 中> 当你调用open时。）

Answer 2

如果您愿意使用一点魔法，您可以非常简单地做到这一点：

use strict;
use warnings;

die "Usage: $0 file1 [file2 ...]\n" unless @ARGV;

my $sum   = 0;

# The current filehandle is aliased to ARGV
while (<>) {
    $sum += $_;
} 
continue {
    # We have finished a file:
    if( eof ARGV ) {
        # $. is the current line number.
        print $sum/$. , "\n" if $.;
        $sum = 0;

        # Closing ARGV resets $. because ARGV is 
        # implicitly reopened for the next file.
        close ARGV;  
    }
}

除非您使用的是非常旧的 Perl，否则没有必要使用 gensym 。 IIRC、perl 5.6 及更新版本对正常的词法句柄感到满意：open my $fh, '<', 'foo';

Answer 3

我很难理解你的逻辑。您想读取多个仅包含数字（每行一个数字）的文件并打印其平均值吗？

use strict;
use warnings;

my @fh;
foreach my $f (@ARGV) {
    open(my $fh, '<', $f) or die "Cannot open $f: $!";
    push @fh, $fh;
}

foreach my $fh (@fh) {
    my ($sum, $n) = (0, 0);
    while (<$fh>) {
        $sum += $_;
        $n++;
    }
    print "$sum / $n: ", $sum / $n, "\n" if $n;
}

Answer 4

似乎 for 循环更适合您，您实际上可以在其中使用标准读取（迭代）运算符。

for my $fh ( @fhs ) { 
    while ( defined( my $line = <$fh> )) {
        # since we're reading integers we test for *defined*
        # so we don't close the file on '0'
        #...
    }
    close $fh;
}

看起来您根本不想缩短循环。因此，while 似乎是错误的循环习惯用法。