如何在 Windows 中的命令提示符下删除特定目录中的文件/子文件夹

Question

比如说，有一个名为 %pathtofolder% 的变量，因为它清楚地表明它是文件夹的完整路径。

我想删除此目录中的每个文件和子文件夹，但不删除目录本身。

但是，可能会出现“此文件/文件夹已在使用中”之类的错误...发生这种情况时，它应该继续并跳过该文件/文件夹。

有一些命令吗？

Answer 1

rmdir 是我一直以来最喜欢的命令为了工作。它适用于删除大文件和带有子文件夹的文件夹。不会创建备份，因此请确保在运行此命令之前已安全复制文件。

RMDIR "FOLDERNAME" /S /Q

这会默默地删除该文件夹以及所有文件和子文件夹。

Answer 2

您可以使用此 shell 脚本清理 C:\Temp source 中的文件夹和文件：

del /q "C:\Temp\*"
FOR /D %%p IN ("C:\Temp\*.*") DO rmdir "%%p" /s /q

创建包含上述命令的批处理文件（例如，delete.bat）。进入delete.bat文件所在位置，然后运行命令：delete.bat

Answer 3

我能想到的最简单的解决方案是删除整个目录然后

RD /S /Q folderPath

再​​次创建此目录：

MD folderPath

Answer 4

这将删除文件夹和文件并留下文件夹。

pushd "%pathtofolder%" && (rd /s /q "%pathtofolder%" 2>nul & popd)

Answer 5

@ECHO OFF

SET THEDIR=path-to-folder

Echo Deleting all files from %THEDIR%
DEL "%THEDIR%\*" /F /Q /A

Echo Deleting all folders from %THEDIR%
FOR /F "eol=| delims=" %%I in ('dir "%THEDIR%\*" /AD /B 2^>nul') do rd /Q /S "%THEDIR%\%%I"
@ECHO Folder deleted.

EXIT

...删除给定目录下的所有文件和文件夹，但不删除目录本身。

Answer 6

CD [Your_Folder]
RMDIR /S /Q .

您将收到一条错误消息，告诉您 RMDIR 命令无法访问当前文件夹，因此无法删除它。

更新：

来自这条有用的评论（感谢Moritz Both），您可以在其间添加 &&，这样如果 CD 命令失败（例如输入错误的目录名称），RMDIR 将不会运行：

CD [Your_Folder] && RMDIR /S /Q .

来自 < a href="https://technet.microsoft.com/en-us/library/cc754993(v=ws.11).aspx" rel="noreferrer">Windows 命令行参考：

/S: 删除目录树（指定目录及其所有目录）
子目录，包括所有文件）。

/Q: 指定安静模式。不提示确认时
删除目录树。 （请注意，仅当 /s 为
指定。）

Answer 7

我使用 Powershell

Remove-Item c:\scripts\* -recurse

它将删除文件夹的内容，而不是文件夹本身。

Answer 8

2018 年 6 月 1 日发布的所有答案都没有，除了 foxidrive，真正删除%PathToFolder%中的所有文件和所有文件夹/目录。这就是使用非常简单的单个命令行发布另一个答案的原因，以删除文件夹的所有文件和子文件夹以及批处理文件，并使用更复杂的解决方案解释为什么 2018-06-01 上发布的所有其他答案都使用 <带有RD的strong>DEL和FOR未能完全清理文件夹。

---

简单的单命令行解决方案当然也可以在批处理文件中使用：

pushd "%PathToFolder%" 2>nul && ( rd /Q /S "%PathToFolder%" 2>nul & popd )

该命令行包含三个依次执行的命令。

第一个命令 PUSHD 将当前目录路径压入堆栈，接下来使 %PathToFolder% 成为运行命令进程的当前目录。

默认情况下，这也适用于 UNC 路径，因为默认情况下启用命令扩展，在本例中 < PUSHD 创建一个指向指定网络资源的临时驱动器号，然后使用新定义的驱动器号更改当前驱动器和目录。

如果指定的目录根本不存在，PUSHD 输出以下错误消息来处理 STDERR：

系统找不到指定的路径。

通过使用 2>nul 将其重定向到设备 NUL，可以抑制此错误消息。

仅当将当前命令进程的当前目录更改为指定目录成功，即指定目录完全存在时，才会执行下一个命令RD。

带有选项/Q和/S的命令RD会安静删除目录及其所有子目录< /strong> 即使指定的目录包含具有隐藏属性或设置了只读属性的文件或文件夹。系统属性永远不会阻止删除文件或文件夹。

未删除的有：

1. 用作任何正在运行的进程的当前目录的文件夹。如果某个文件夹用作任何正在运行的进程的当前目录，则无法删除该文件夹的整个文件夹树。

2. 当前由任何正在运行的进程打开的文件，并且在文件打开时设置了文件访问权限，以防止在由正在运行的应用程序/进程打开时删除文件。这样打开的文件还可以防止删除打开的文件的整个文件夹树。

3. 当前用户没有删除文件/文件夹所需的 (NTFS) 权限的文件/文件夹，这也阻止了删除此文件/文件夹的文件夹树。

不删除文件夹的第一个原因是该命令行使用删除指定文件夹的所有文件和子文件夹，但不删除文件夹本身。该文件夹临时成为运行命令进程的当前目录，以防止删除文件夹本身。当然，这会导致命令 RD 输出错误消息：

该进程无法访问该文件，因为该文件正在被另一个进程使用。

文件在这里是错误的术语，因为实际上该文件夹正在被另一个进程使用，即执行命令RD的当前命令进程。嗯，实际上，文件夹对于文件系统来说是一个具有文件属性目录的特殊文件，它解释了此错误消息。但我不想太深入地了解文件系统管理。

与所有其他错误消息一样，由于上述三个原因可能会出现此错误消息，可以通过使用 2>nul 将其从句柄 STDERR 重定向到设备 <强>NUL。

第三个命令POPD 的执行与命令RD 的退出值无关。

POPD将PUSHD推送的目录路径从堆栈中弹出，并将运行命令进程的当前目录更改为该目录，即恢复初始当前目录。如果是 UNC 文件夹路径，POPD 会删除 PUSHD 创建的临时驱动器号。

注意： POPD 如果初始当前目录是要清理的目录的子目录且不再存在，则可能无法恢复初始当前目录。在这种特殊情况下，%PathToFolder% 保留当前目录。因此，建议不要从 %PathToFolder% 的子目录运行上面的命令行。

还有一个有趣事实：
我尝试使用 UNC 路径使用命令行，方法是使用共享名 Temp 共享本地目录 C:\Temp 并使用 UNC 路径 \\%COMPUTERNAME%\Temp \CleanTest 分配给 Windows 7 上的环境变量 PathToFolder。如果运行命令行时的当前目录是使用 UNC 路径访问的共享本地文件夹的子目录，即 C: \Temp\CleanTest\Subfolder1、Subfolder1 被 RD 删除，并且下一个 POPD 在创建 C 时默默失败： \Temp\CleanTest\Subfolder1 再次当前目录，导致 Z:\CleanTest 保留为运行命令进程的当前目录。因此，在这种非常非常特殊的情况下，临时驱动器号将保留，直到当前目录更改为例如使用 cd /D %SystemRoot% 更改为实际存在的本地目录。不幸的是，如果 POPD 无法恢复初始当前目录，则它不会以大于 0 的值退出，因此无法仅使用 POPD 的退出代码来检测这种非常特殊的错误情况。 。但是，可以假设没有人会遇到这种非常特殊的错误情况，因为 UNC 路径通常不用于访问本地文件和文件夹。

为了更好地理解所使用的命令，请打开命令提示符窗口，执行以下命令，并仔细阅读每个命令显示的帮助。

• pushd /?
• popd /?
• rd /?

使用 Windows 批处理文件的单行多个命令 解释了此处使用的运算符 && 和 &。

---

接下来我们看看使用DEL命令删除%PathToFolder%和FOR和RD 删除 %PathToFolder% 中的子文件夹。

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Clean the folder for temporary files if environment variable
rem PathToFolder is not defined already outside this batch file.
if not defined PathToFolder set "PathToFolder=%TEMP%"

rem Remove all double quotes from folder path.
set "PathToFolder=%PathToFolder:"=%"

rem Did the folder path consist only of double quotes?
if not defined PathToFolder goto EndCleanFolder

rem Remove a backslash at end of folder path.
if "%PathToFolder:~-1%" == "\" set "PathToFolder=%PathToFolder:~0,-1%"

rem Did the folder path consist only of a backslash (with one or more double quotes)?
if not defined PathToFolder goto EndCleanFolder

rem Delete all files in specified folder including files with hidden
rem or read-only attribute set, except the files currently opened by
rem a running process which prevents deletion of the file while being
rem opened by the application, or on which the current user has not
rem the required permissions to delete the file.
del /A /F /Q "%PathToFolder%\*" >nul 2>nul

rem Delete all subfolders in specified folder including those with hidden
rem attribute set recursive with all files and subfolders, except folders
rem being the current directory of any running process which prevents the
rem deletion of the folder and all folders above, folders containing a file
rem opened by the application which prevents deletion of the file and the
rem entire folder structure to this file, or on which the current user has
rem not the required permissions to delete a folder or file in folder tree
rem to delete.
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

:EndCleanFolder
endlocal

批处理文件首先确保环境变量 PathToFolder 确实定义为不带双引号且末尾不带反斜杠的文件夹路径。末尾的反斜杠不会有问题，但文件夹路径中的双引号可能会出现问题，因为 PathToFolder 的值在批处理文件执行期间与其他字符串连接。

重要的是两行：

del /A /F /Q "%PathToFolder%\*" >nul 2>nul
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

命令DEL用于删除指定目录中的所有文件。

• 选项 /A 对于处理所有文件（包括具有隐藏属性的文件）是必需的，如果不使用选项 /A，DEL 将忽略这些文件。
• 要强制删除设置了只读属性的文件，需要使用 /F 选项。
• 选项/Q对于运行多个文件的安静删除是必需的，而不提示用户是否应该真正删除多个文件。
• >nul 是将用于处理 STDOUT 的文件名的输出重定向到设备 NUL 所必需的，该设备由于以下原因而无法删除文件当前已打开或用户无权删除该文件。
• 2>nul 是将每个无法从句柄 STDERR 删除的文件的错误消息输出重定向到设备 NUL 所必需的。

命令FOR和RD用于删除指定目录中的所有子目录。但不使用 for /D ，因为 FOR 在这种情况下忽略具有隐藏属性集的子目录。因此，for /F 用于在使用 %ComSpec% /c 在后台启动的单独命令进程中运行以下命令行：

dir "%PathToFolder%\*" /AD /B 2>nul

DIR 以裸格式输出，因为 /B 目录条目具有属性 D，即指定目录中的所有子目录的名称独立于其他属性（如隐藏属性），而没有一条路径。 2>nul 用于将 DIR 在没有从句柄 STDERR 找到目录时输出的错误消息重定向到设备 NUL。

重定向运算符 > 必须在 FOR 命令行上使用插入符 ^ 进行转义，以便在以下情况下将其解释为文字字符： Windows 命令解释器在执行命令 FOR 之前处理此命令行，该命令在后台启动的单独命令进程中执行嵌入的 dir 命令行。

FOR 处理捕获的输出，这些输出写入到处理已启动命令进程的 STDOUT 中，这些输出是不带路径且从不用双引号引起来的子目录的名称。

带有选项 /F 的 FOR 会忽略此处未出现的空行，因为带有选项 /B 的 DIR 不会出现输出空行。

FOR 也会忽略以分号开头的行，分号是默认的行结束符。目录名称可以以分号开头。因此，eol=| 用于将竖线字符定义为行尾字符，任何目录或文件的名称中都不能包含该字符。

FOR 会使用空格和水平制表符作为分隔符将行拆分为子字符串，并且仅将第一个空格/制表符分隔的字符串分配给指定的循环变量 I。此处不需要这种拆分行为，因为目录名称可以包含一个或多个空格。因此，delims= 用于定义一个空的分隔符列表，以禁用行分割行为，并分配给循环变量 I，始终是完整的目录名称。

命令 FOR 对每个不带路径的目录名称运行命令 RD，这就是为什么在 RD 命令行上必须指定文件夹路径的原因再次与子文件夹名称连接。

为了了解所使用的命令及其工作原理，请打开命令提示符窗口，执行以下命令，并仔细阅读为每个命令显示的所有帮助页面。

• del /?
• dir /
• ? echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• rd /?
• rem /?
• set /?
• 设置本地/？

Answer 9

RD 代表删除目录。

/S ：删除所有文件和子文件夹
除了文件夹本身。
使用它可以删除整个文件夹树。

/Q：安静 - 不显示 YN 确认

示例：

RD /S /Q C:/folder_path/here

Answer 10

使用记事本创建文本文档并复制/粘贴此文档：

rmdir /s/q "%temp%"
mkdir "%temp%"

选择另存为和文件名：

删除_temp.bat

保存类型：所有文件，然后单击保存按钮。

它适用于任何类型的帐户（管理员或标准用户）。运行吧！

我在此示例中使用临时变量，但您可以使用任何其他变量！ PS：仅适用于Windows操作系统！

Answer 11

删除文件：

del PATH_TO_FILE

删除包含所有文件的文件夹：

rmdir /s /q PATH_TO_FOLDER

要删除特定文件夹中的所有文件（而不是删除文件夹本身）有点复杂。 del /s *.* 无法删除文件夹，但会删除所有子文件夹中的文件。所以需要两条命令：

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

Answer 12

我有以下适合我的解决方案：

for /R /D %A in (*node_modules*) do rmdir "%A" /S /Q

它从当前目录及其中删除所有节点模块文件夹子文件夹。

这与上面发布的解决方案类似，但我仍然将其发布在这里，以防万一有人发现它有用

Answer 13

您可以使用以下命令删除所有内容和父文件夹本身：

RMDIR [/S] [/Q] [drive:]path            

Answer 14

@ECHO OFF
rem next line removes all files in temp folder
DEL /A /F /Q /S "%temp%\*.*"
rem next line cleans up the folder's content
FOR /D %%p IN ("%temp%\*.*") DO RD "%%p" /S /Q

Answer 15

我尝试了其中几种方法，但没有一个能正常工作。

我在网站 Windows 命令上找到了这种两步方法Line：

forfiles /P %pathtofolder% /M * /C "cmd /c if @isdir==FALSE del @file"

forfiles /P %pathtofolder%  /M * /C "cmd /c if @isdir==TRUE rmdir /S /Q @file"

它完全按照我的需要和OP的指定工作。

Answer 16

使用：

del %pathtofolder%\*.*   /s /f  /q

这会删除%pathtofolder%中的所有文件和子文件夹，包括只读文件，并且不提示确认。