使用 Tor 作为代理

Question

我正在尝试使用 Tor-Server 作为 HttpWebRequest 中的代理，我的代码如下所示：

HttpWebRequest request;
HttpWebResponse response;

request = (HttpWebRequest)WebRequest.Create("http://www.google.com");
request.Proxy = new WebProxy("127.0.0.1:9051");

response = (HttpWebResponse)request.GetResponse();
response.Close();

它与“普通”代理完美配合，但使用 Tor 我在调用

GetResponse 时遇到异常() 且状态 = ServerProtocolViolation。该消息是（德语...）：Message =“Der Server hat eine Protokollverletzung ausgeführt..Section=ResponseStatusLine”

Answer 1

如果您安装并运行 privoxy 您可以执行

request.Proxy = new WebProxy("127.0.0.1:8118"); // default privoxy port

以下操作，这将使您能够使用 tor 发出请求

Answer 2

Tor 不是 HTTP 代理。这是一个 SOCKS 代理。您可以使用支持 SOCKS 转发的 HTTP 代理（如 Privoxy）并通过代码连接到该代理。

Answer 3

是的，就像另一位海报所说，需要一个袜子客户端。一些库是 Starksoft Proxy、ProxySocket 和 ComponentSpace Socks代理。 sockscap 是一个拦截和重新路由winsock调用的工具，并且privoxy 是一个本地代理，可以通过袜子传输您的请求。几个不同的解决方案。

Answer 4

使用库“SocksWebProxy”。您可以将它与 WebClient 和 WebClient 一起使用。 WebRequest（只需将新的 SocksWebProxy 分配给 *.Proxy 属性）。无需 Privoxy 或类似服务将 http 流量转换为 tor。

https://github.com/Ogglas/SocksWebProxy

我还通过启用控件对其进行了一些扩展港口。以下是如何在不启动 Tor Browser Bundle 的情况下让 Tor 在后台运行，并且为了控制 Tor，我们可以使用 Telnet 或通过 Socket 以编程方式发送命令。

Socket server = null;

//Authenticate using control password
IPEndPoint endPoint = new IPEndPoint(IPAddress.Parse("127.0.0.1"), 9151);
server = new Socket(AddressFamily.InterNetwork, SocketType.Stream, ProtocolType.Tcp);
server.Connect(endPoint);
server.Send(Encoding.ASCII.GetBytes("AUTHENTICATE \"your_password\"" + Environment.NewLine));
byte[] data = new byte[1024];
int receivedDataLength = server.Receive(data);
string stringData = Encoding.ASCII.GetString(data, 0, receivedDataLength);

//Request a new Identity
server.Send(Encoding.ASCII.GetBytes("SIGNAL NEWNYM" + Environment.NewLine));
data = new byte[1024];
receivedDataLength = server.Receive(data);
stringData = Encoding.ASCII.GetString(data, 0, receivedDataLength);
if (!stringData.Contains("250"))
{
    Console.WriteLine("Unable to signal new user to server.");
    server.Shutdown(SocketShutdown.Both);
    server.Close();
}
else
{
    Console.WriteLine("SIGNAL NEWNYM sent successfully");
}

配置 Tor 的步骤：

1. 将 torrc-defaults 复制到 tor.exe 所在的目录中。如果您使用 Tor 浏览器，默认目录为：“~\Tor Browser\Browser\TorBrowser\Data\Tor”
2. 打开 cmd 提示符窗口
3. chdir 到 tor.exe 所在目录。如果您使用 Tor 浏览器，默认目录为：“~\Tor Browser\Browser\TorBrowser\Tor\”
4. 生成 Tor 控制端口访问的密码。 tor.exe --哈希密码“your_password_without_hyphens”|更多
5. 将您的密码密码哈希添加到 ControlPort 9151 下的 torrc-defaults 中。它应如下所示：hashedControlPassword 16:3B7DA467B1C0D550602211995AE8D9352BF942AB04110B2552324B2507。如果您接受密码为“password”，您可以复制上面的字符串。
6. 现在，一旦启动，您就可以通过 Telnet 访问 Tor 控制。现在代码可以运行，只需编辑 Tor 文件在程序中所在的路径即可。
   测试通过 Telnet 修改 Tor：
7. 使用以下命令启动 tor：tor.exe -f .\torrc-defaults
8. 打开另一个 cmd 提示符并输入：telnet localhost 9151
9. 如果全部顺利的话你应该会看到一个全黑的屏幕。输入“autenticate “your_password_with_hyphens””如果一切顺利，您应该会看到“250 OK”。
10. 输入“SIGNAL NEWNYM”，您将获得一条新路由，即新的 IP。如果一切顺利，您应该会看到“250 OK”。
11. 输入“setevents circ”（电路事件）以启用控制台输出
12. 输入“getinfo Circuit-status”以查看当前电路

Answer 5

您需要从袜子中“提取”流......

Imports System.IO
Imports System.Net
Imports System.Net.Sockets
Imports System.Text
Imports System.Runtime.CompilerServices

Public Class Form1

    Sub Form1_Load() Handles Me.Load

        Dim Host As String = "google.com"

        Dim P As New SocksProxy("localhost", 64129) 'Set your socks proxy here
        Dim Stream As NetworkStream = P.GetStream(Host, 80)
        Dim buffer As Byte() = Download(Stream, Host, "")

        My.Computer.FileSystem.WriteAllBytes("C:\webpage.html", buffer, False)

        MsgBox("ok")
    End Sub

    Function Download(Stream As NetworkStream, Host As String, Resource As String) As Byte()

        Using writer = New StreamWriter(Stream)
            writer.Write(String.Format("GET /{2} HTTP/1.1{0}Host: {1}{0}{0}", vbCrLf, Host, Resource))
            writer.Flush()

            Dim byteList As New List(Of Byte)
            Dim bufferSize As Integer = 4096
            Dim buffer(bufferSize - 1) As Byte

            Do
                Dim bytesRead As Integer = Stream.Read(buffer, 0, bufferSize)
                byteList.AddRange(buffer.Take(bytesRead))
            Loop While Stream.DataAvailable

            Return byteList.ToArray
        End Using

    End Function
End Class


Public Class SocksProxy

    Private _SocksHost As String
    Private _SocksPort As Integer

    Sub New(SocksHost As String, SocksPort As Integer)
        _SocksHost = SocksHost
        _SocksPort = SocksPort
    End Sub

    Function GetStream(HostDest As String, PortDest As Short) As NetworkStream

        Dim client As TcpClient = New TcpClient()
        client.Connect(_SocksHost, _SocksPort)

        Dim stream As NetworkStream = client.GetStream()
        'Auth
        Dim buf = New Byte(299) {}
        buf(0) = &H5
        buf(1) = &H1
        buf(2) = &H0
        stream.Write(buf, 0, 3)

        ReadExactSize(stream, buf, 0, 2)
        If buf(0) <> &H5 Then
            Throw New IOException("Invalid Socks Version")
        End If
        If buf(1) = &HFF Then
            Throw New IOException("Socks Server does not support no-auth")
        End If
        If buf(1) <> &H0 Then
            Throw New Exception("Socks Server did choose bogus auth")
        End If

        buf(0) = &H5
        buf(1) = &H1
        buf(2) = &H0
        buf(3) = &H3
        Dim domain = Encoding.ASCII.GetBytes(HostDest)
        buf(4) = CByte(domain.Length)
        Array.Copy(domain, 0, buf, 5, domain.Length)
        Dim port = BitConverter.GetBytes(IPAddress.HostToNetworkOrder(CShort(PortDest)))
        buf(5 + domain.Length) = port(0)
        buf(6 + domain.Length) = port(1)
        stream.Write(buf, 0, domain.Length + 7)


        ' Reply
        ReadExactSize(stream, buf, 0, 4)
        If buf(0) <> &H5 Then
            Throw New IOException("Invalid Socks Version")
        End If
        If buf(1) <> &H0 Then
            Throw New IOException(String.Format("Socks Error {0:X}", buf(1)))
        End If
        Dim rdest = String.Empty
        Select Case buf(3)
            Case &H1
                ' IPv4
                ReadExactSize(stream, buf, 0, 4)
                Dim v4 = BitConverter.ToUInt32(buf, 0)
                rdest = New IPAddress(v4).ToString()
                Exit Select
            Case &H3
                ' Domain name
                ReadExactSize(stream, buf, 0, 1)
                If buf(0) = &HFF Then
                    Throw New IOException("Invalid Domain Name")
                End If
                ReadExactSize(stream, buf, 1, buf(0))
                rdest = Encoding.ASCII.GetString(buf, 1, buf(0))
                Exit Select
            Case &H4
                ' IPv6
                Dim octets = New Byte(15) {}
                ReadExactSize(stream, octets, 0, 16)
                rdest = New IPAddress(octets).ToString()
                Exit Select
            Case Else
                Throw New IOException("Invalid Address type")
        End Select
        ReadExactSize(stream, buf, 0, 2)
        Dim rport = CUShort(IPAddress.NetworkToHostOrder(CShort(BitConverter.ToUInt16(buf, 0))))

        Return stream
    End Function

    Private Sub ReadExactSize(stream As NetworkStream, buffer As Byte(), offset As Integer, size As Integer)
        While size <> 0
            Dim read = stream.Read(buffer, offset, size)
            If read < 0 Then
                Throw New IOException("Premature end")
            End If
            size -= read
            offset += read
        End While
    End Sub

End Class