多个文档（Word 2003 或 2007）使用一个中央页眉/页脚

Question

在 Word（2003 或 2007）中，是否有一种方法可以让多个文档使用一个页眉/页脚？

我希望能够在一处更改页眉/页脚并使其影响多个文档。

即我有 50 个文档，它们都有相同的页眉/页脚。有没有办法将 50 个文档链接（OLE？）到一个主文档，而只需更改主文档，而不是打开所有 50 个文档进行更改？

如果没有内置的方法，有人用VBA做过这个吗？

Answer 1

我不确定这在实践中会如何运作，但您可以将其他文件作为链接插入到 Word 文档中。

首先创建包含页眉/页脚内容的文档，内容位于文档正文中。保存起来。

然后转到 50 个文档之一，进入页眉/页脚。转到插入|文件。找到第一个文件，然后单击“插入文件”对话框中“打开”按钮旁边的小下拉箭头。从下拉列表中选择“插入为链接”。内容现在应该显示在文档中。如果您单击内容，通常它会有灰色背景，表明它确实是一个 Word 字段。

现在，当您更改第一个文档时，您可以打开第二个文档，更新字段（单击其中的任意位置并按 F9），新内容将被拉入。您还可以非常简单地以编程方式更新字段，或者在“工具”|“工具”|“工具”下更新字段。选项 |打印，有一个框可以在每次打印文档时自动更新字段。

Answer 2

据我所知，（简单地）更改文档标题必须通过打开文档来完成。这就是说你有几个选择。首先，如果文档以 Office XML 格式保存，那么您可以使用 MSXML 库打开文件并更改标题中的数据。 （或者改变本质上是文本文件的数十种其他方法中的任何一种。）如果文件仍然是二进制格式，那么您实际上只有两个选择之一。第一种是通过 vba 打开文件并通过文档对象模型更改标头。第二个是找出二进制格式（已记录）并使用 VB6/VBA 本机二进制 IO 更改它（非常重要）。

除非我认为我可以获得更多时间，否则我会失去编写直接更改文档的代码的机会，否则我可能会循环遍历文件夹中的所有文件，打开它们并更改它们。至于将标题存储在某处......您可以将标题数据放入文本文件中并将其拉入。或者将文档模板保留在某处。

这是一个非常简单的例子：

Public Sub Example()
    Dim asFiles() As String
    Dim lFile As Long
    Dim docCrnt As Word.Document
    asFiles = GetFiles("C:\Test\", "*.doc")
    For lFile = 0& To UBound(asFiles)
        Set docCrnt = Word.Documents.Open(asFiles(lFile))
        docCrnt.Windows(1).View.SeekView = wdSeekCurrentPageHeader
        Selection.Text = "I am the header."
        docCrnt.Close True
    Next
End Sub

Public Function GetFiles( _
    ByVal folderPath As String, _
    Optional ByVal pattern As String = vbNullString _
    ) As String()

    Dim sFile As String
    Dim sFolder As String
    Dim asRtnVal() As String
    Dim lIndx As Long

    If Right$(folderPath, 1&) = "\" Then
        sFolder = folderPath
    Else
        sFolder = folderPath & "\"
    End If
    sFile = Dir(sFolder & pattern)
    Do While LenB(sFile)
        ReDim Preserve asRtnVal(lIndx) As String
        asRtnVal(lIndx) = sFolder & sFile
        lIndx = lIndx + 1&
        sFile = Dir
    Loop
    If lIndx = 0& Then
        ReDim asRtnVal(-1& To -1&) As String
    End If
    GetFiles = asRtnVal
    Erase asRtnVal
End Function